development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26 message(STATUS)
  27 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  28
  29 # Usage LYX_OPTION
  30 # 1. parameter: option name without prefix 'LYX_'
  31 # 2. parameter: description
  32 # 3. parameter: default value, ON or OFF
  33 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  34 message(STATUS)
  35 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  36 message(STATUS)
  37 LYX_OPTION(NLS "Use nls" OFF ALL)
  38 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  39 LYX_OPTION(AIKSAURUS "Require Aiksaurus" OFF ALL)
  40 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  41 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  42 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  43 LYX_OPTION(RELEASE "Build release version" ON ALL)
  44 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  45 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  46 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  47 LYX_OPTION(INSTALL "Build install projects/rules" OFF ALL)
  48 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  49 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  50 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  51 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  52 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  53 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  54 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  55 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  56 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  57 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  58 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  59 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  60 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  61
  62 message(STATUS)
  63
  64 if(LYX_INSTALL)
  65         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  66         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  67         set(LYX_AIKSAURUS ON CACHE BOOL "Aiksaurus option" FORCE)
  68         if (WIN32)
  69                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  70         endif()
  71         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  72         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  73         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  74         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  75         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  76         set(LYX_MERGE_FILES ON CACHE BOOL "Merge option" FORCE)
  77 endif()
  78
  79
  80 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  81 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  82
  83
  84
  85 if(UNIX OR MINGW)
  86     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  87     message(STATUS "Using GCC version ${GCC_VERSION}")
  88     if(NOT GCC_VERSION VERSION_LESS 4.4)
  89         set(LYX_USE_TR1 1)
  90         # GCC <= 4.5 does not support regex: there are linker errors
  91         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  92         set(LYX_USE_TR1_REGEX 0)
  93     endif()
  94 else()
  95     if(MSVC10)
  96         set(LYX_USE_TR1 1)
  97         set(LYX_USE_TR1_REGEX 1)
  98     endif()
  99 endif()
 100
 101
 102
 103 # Supress regeneration
 104 set(CMAKE_SUPPRESS_REGENERATION TRUE)
 105
 106 set(VERSION_INFO "CMake Build")
 107
 108 # Try to get some informations from configure.ac
 109
 110 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
 111 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 112
 113 if(WIN32)
 114   set(USE_WINDOWS_PACKAGING 1)
 115 elseif(APPLE)
 116   set(USE_MACOSX_PACKAGING 1)
 117 else()
 118   set(USE_POSIX_PACKAGING 1)
 119 endif()
 120
 121 macro(setstripped _varname _value)
 122   string(STRIP ${_value} _v)
 123   if(USE_POSIX_PACKAGING)
 124     string(TOLOWER ${_v} ${_varname})
 125   else()
 126     set(${_varname} ${_v})
 127   endif()
 128 endmacro(setstripped)
 129
 130 foreach(_c_l ${_config_lines} )
 131   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 132     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 133     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 134     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 135     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 136       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 137       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 138       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 139       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 140       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 141     endif()
 142   endif()
 143   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 144     set(LYX_DATE "${CMAKE_MATCH_1}")
 145   endif()
 146 endforeach(_c_l)
 147
 148
 149 if(LYX_PACKAGE_SUFFIX)
 150   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 151 else()
 152   set(PACKAGE ${PACKAGE_BASE})
 153 endif()
 154
 155 if(LYX_PROGRAM_SUFFIX)
 156   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 157 else()
 158   set(PROGRAM_SUFFIX "")
 159 endif()
 160
 161
 162 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 163   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 164   if (UNIX)
 165     # don't use the default "/usr/local"
 166     # but respect the user-choice on the command-line
 167     if(LYX_INSTALL_SUFFIX)
 168         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 169     else()
 170         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 171     endif()
 172   endif()
 173   if(WIN32)
 174     SET(CMAKE_INSTALL_PREFIX
 175       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 176   endif()
 177 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 178
 179 if (WIN32)
 180   set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 181 else()
 182   set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 183 endif()
 184
 185 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 186 set(LYX_LOCALEDIR "locale")
 187 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 188 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 189
 190
 191 if(NOT GROUP_CODE)
 192         #set(GROUP_CODE "The Golden Code")
 193         set(GROUP_CODE flat)
 194 endif()
 195
 196 # lyx's source files
 197 set(LYX_CPP_FILES *.cpp)
 198 set(LYX_HPP_FILES *.h)
 199 set(LYX_MOC_FILES moc_*.cpp)
 200
 201
 202 include(ProjectSourceGroup)
 203
 204
 205 if(LYX_PROFILE)
 206         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 207         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 208 endif()
 209
 210 if(LYX_RELEASE)
 211         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 212 endif()
 213
 214 if(LYX_DEBUG)
 215         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 216 endif()
 217
 218
 219
 220 if(LYX_SHARED_LIBRARIES)
 221         set(library_type SHARED)
 222 else()
 223         set(library_type STATIC)
 224 endif()
 225
 226 if(NOT MSVC)
 227         if(NOT LYX_QUIET)
 228                 set(CMAKE_VERBOSE_MAKEFILE ON)
 229         endif()
 230         set(LYX_CXX_FLAGS -Wall)
 231         if(LYX_STDLIB_DEBUG)
 232                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 233         endif()
 234         if(LYX_CONCEPT_CHECKS)
 235                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 236         endif()
 237         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 238         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 239         if(MINGW)
 240                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 241         else()
 242                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 243         endif()
 244         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 245 endif()
 246
 247
 248 find_package(Qt4 REQUIRED)
 249 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 250
 251 find_package(ZLIB REQUIRED)
 252
 253 if(LYX_ASPELL)
 254         find_package(ASPELL)
 255         include_directories(${ASPELL_INCLUDE_DIR})
 256 endif()
 257
 258 if(LYX_AIKSAURUS)
 259         find_package(AiksaurusLIB REQUIRED)
 260         include_directories(${AIKSAURUSLIB_INCLUDE_DIR})
 261 endif()
 262
 263 if(LYX_ENCHANT)
 264         find_package(Enchant REQUIRED)
 265         include_directories(${ENCHANT_INCLUDE_DIR})
 266 endif()
 267
 268 if(LYX_HUNSPELL)
 269         find_package(Hunspell REQUIRED)
 270         include_directories(${HUNSPELL_INCLUDE_DIR})
 271 endif()
 272
 273 if(LYX_USE_EXTERNAL_LIBINTL)
 274         find_package(Libintl REQUIRED)
 275         add_definitions(-DHAVE_GETTEXT)
 276 endif()
 277
 278
 279
 280
 281 if(LYX_NLS)
 282         add_definitions(-DENABLE_NLS=1)
 283 endif()
 284
 285
 286 if(WIN32)
 287         if(LYX_NO_CONSOLE)
 288                 set(WIN32_CONSOLE WIN32)
 289                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 290         endif()
 291         if(MSVC)
 292                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 293                 # disable checked iterators for msvc release builds to get maximum speed
 294                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 295         else()
 296                 add_definitions(-DWINVER=0x0500)
 297         endif()
 298 endif()
 299
 300 message(STATUS "")
 301 foreach(_v PACKAGE PACKAGE_VERSION
 302     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 303     LYX_ABS_TOP_SRCDIR
 304     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 305   if(NOT DEFINED ${_v})
 306     message(FATAL_ERROR "${_v} not defined")
 307   endif()
 308   string(SUBSTRING "${_v}                            " 0 28 _v1)
 309   message(STATUS "----- ${_v1}: ${${_v}}")
 310 endforeach(_v)
 311 message(STATUS "")
 312
 313
 314 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 315 # Not sure if it works for all non-msvc compilers
 316 include(PCHSupport_26)
 317
 318 if(NOT LYX_DISABLE_PCH)
 319
 320         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 321         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 322         add_definitions(-DLYX_ENABLE_PCH)
 323
 324         if(MSVC AND NOT MERGE_FILES)
 325                 macro(lyx_add_msvc_pch name_)
 326                         set_source_files_properties(${${name_}_sources} PROPERTIES
 327                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 328                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 329                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 330                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 331                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 332                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 333                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 334                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 335                 endmacro(lyx_add_msvc_pch)
 336                 macro(lyx_add_gcc_pch name_)
 337                 endmacro()
 338         else()
 339                 macro(lyx_add_msvc_pch name_)
 340                 endmacro()
 341                 macro(lyx_add_gcc_pch name_)
 342                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 343                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 344                 endmacro()
 345         endif()
 346 else()
 347         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 348         macro(lyx_add_msvc_pch)
 349         endmacro(lyx_add_msvc_pch)
 350         macro(lyx_add_gcc_pch name_)
 351         endmacro()
 352 endif()
 353
 354 if(MSVC)
 355         if(LYX_VLD)
 356            set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 357            set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 358            set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 359            include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 360         endif()
 361
 362         # TODO options
 363         if(LYX_WALL)
 364                 # Use the highest warning level
 365                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 366
 367                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 368                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 369                 else()
 370                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 371                 endif()
 372
 373                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 374                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 375                 else()
 376                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 377                 endif()
 378
 379                 # add here warnings which should produce an error /weXXXX
 380                 set(MSVC_W_ERROR   "/we4101 /we4189")
 381                 # add here warnings which should be disabled /wdXXXX
 382                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 383
 384                 set(CMAKE_CXX_FLAGS_DEBUG
 385                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 386                 set(CMAKE_CXX_FLAGS_RELEASE
 387                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 388                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 389                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 390
 391         else()
 392                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 393
 394                 # add here warnings which should produce an error /weXXXX
 395                 set(MSVC_W_ERROR   "/we4101 /we4189")
 396                 # add here warnings which should be disabled /wdXXXX
 397                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 398
 399                 set(CMAKE_CXX_FLAGS_DEBUG
 400                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 401                 set(CMAKE_CXX_FLAGS_RELEASE
 402                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 403                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 404                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 405
 406         endif()
 407         set(CMAKE_CXX_FLAGS_DEBUG
 408                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 409         set(CMAKE_CXX_FLAGS_RELEASE
 410                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 411         set(CMAKE_CXX_FLAGS_MINSIZEREL
 412                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 413
 414         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 415         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 416         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 417         message(STATUS "")
 418
 419 endif()
 420
 421 FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 422 if( NOT ${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 423     if(LYX_NLS)
 424       find_package(LyXGettext REQUIRED)
 425       include_directories(${TOP_SRC_DIR}/po)
 426       add_subdirectory(po)
 427     endif()
 428 endif()
 429
 430 if(LYX_DEBUG_GLIBC)
 431   set(_GLIBCXX_DEBUG 1)
 432 endif()
 433
 434 if(LYX_DEBUG_GLIBC_PEDANTIC)
 435   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 436 endif()
 437
 438 # compiler tests, config.h generation
 439 if(MSVC AND NOT CONFIGURECHECKS)
 440         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 441 else()
 442         include(ConfigureChecks.cmake)
 443         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 444 endif()
 445
 446 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 447
 448 find_package(ICONV REQUIRED)
 449 add_definitions(-DHAVE_ICONV=1)
 450
 451
 452 include_directories(
 453   ${CMAKE_BINARY_DIR}
 454   ${TOP_SRC_DIR}/src)
 455
 456
 457 if(LYX_USE_EXTERNAL_BOOST)
 458   message(STATUS "Searching for boost")
 459   find_package(Boost COMPONENTS signals regex)
 460   if(Boost_FOUND)
 461     message(STATUS "Boost found")
 462     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 463     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 464   else()
 465     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 466   endif()
 467 else()
 468   if(LYX_USE_TR1_REGEX)
 469     set(Lyx_Boost_Libraries boost_signals)
 470   else()
 471     set(Lyx_Boost_Libraries boost_signals boost_regex)
 472   endif()
 473   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 474   include_directories(${TOP_SRC_DIR}/boost)
 475   add_subdirectory(boost)
 476 endif()
 477
 478
 479 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 480   add_subdirectory(intl)
 481 endif()
 482 add_subdirectory(src)
 483
 484 if(LYX_INSTALL)
 485         add_subdirectory(man)
 486         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 487         if(NOT ${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 488                 add_subdirectory(doc)
 489         endif()
 490 endif()
 491 add_subdirectory(lyx2lyx)
 492 add_subdirectory(scripts)
 493
 494 if(LYX_INSTALL)
 495         include(../Install)
 496 endif()
 497
 498 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 499 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 500 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 501
 502 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 503 #
 504 # needed by rpm
 505 SET(CPACK_SET_DESTDIR "ON")
 506 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 507 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 508 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 509 #
 510 # the next ones are needed by deb
 511 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 512 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 513
 514 # This is experimental, valid on _my_ system (Kornel)
 515 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 516 IF(ASPELL_FOUND)
 517   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 518 ENDIF()
 519 #
 520 # for the next ones, cpack insists on data with values in some file
 521 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 522 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 523
 524 # Find the revision number and use it as the release in rpm-package-build.
 525 # This way we may omit the otherwise needed "--force" parameter when
 526 # installing from that rpm package.
 527 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 528 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 529 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 530   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 531   # We use this value also to set the package-patch-value
 532   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 533     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 534   endif()
 535 endif()
 536
 537 # we do not have a readme or welcome data,
 538 # so we do not provide infofiles for
 539 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 540
 541 include(CPack)
 542
 543 #Now it is possible to create some packages
 544 # cd <BuildDir>
 545 # make package
 546 #############################################################################################
 547 # So, e.g. for variables
 548 #    CMAKE_PROJECT_NAME                     : lyx
 549 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 550 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 551 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 552 #    CMAKE_SYSTEM_NAME                      : Linux
 553 #    CPACK_BINARY_DEB:BOOL                  : ON
 554 #
 555 # the package name builds as "lyx-2.0.1-Linux.deb"
 556 #
 557 ############################## rpm ################################### deb ##################
 558 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 559 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 560 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 561 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 562 #
 563 message(STATUS)