development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif(COMMAND cmake_policy)
  15
  16 project(lyx)
  17
  18 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  19
  20 # where to look first for cmake modules,
  21 # before ${CMAKE_ROOT}/Modules is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 include(LyXMacros)
  24
  25 message(STATUS)
  26 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  27
  28 # Usage LYX_OPTION
  29 # 1. parameter: option name without prefix 'LYX_'
  30 # 2. parameter: description
  31 # 3. parameter: default value, ON or OFF
  32 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  33 LYX_OPTION(NLS "Use nls" OFF ALL)
  34 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  35 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  36 LYX_OPTION(RELEASE "Build release version" ON ALL)
  37 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  38 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  39 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  40 LYX_OPTION(INSTALL "Build install projects/rules" ON ALL)
  41 LYX_OPTION(USE_VERSION_SUFFIX "Use version suffix for packaging" OFF ALL)
  42 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  43 LYX_OPTION(VLD "Use VLD on with MSVC" OFF MSVC)
  44 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  45 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  46 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  47 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  48 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  49 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  50 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  51 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  52
  53 message(STATUS)
  54
  55 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  56 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  57
  58
  59
  60 if(UNIX OR MINGW)
  61     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  62     message(STATUS "Using GCC version ${GCC_VERSION}")
  63     if(NOT GCC_VERSION VERSION_LESS 4.4)
  64         set(LYX_USE_TR1 1)
  65         # GCC <= 4.5 does not support regex: there are linker errors
  66         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  67         set(LYX_USE_TR1_REGEX 0)
  68     endif()
  69 else()
  70     if(MSVC10)
  71         set(LYX_USE_TR1 1)
  72         set(LYX_USE_TR1_REGEX 1)
  73     endif()
  74 endif()
  75
  76
  77
  78
  79
  80 # Supress regeneration
  81 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  82
  83 set(VERSION_INFO "CMake Build")
  84
  85 # Try to get some informations from configure.ac
  86
  87 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  88 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  89
  90 if(WIN32)
  91   set(USE_WINDOWS_PACKAGING 1)
  92 elseif(APPLE)
  93   set(USE_MACOSX_PACKAGING 1)
  94 else()
  95   set(USE_POSIX_PACKAGING 1)
  96 endif()
  97
  98 macro(setstripped _varname _value)
  99   string(STRIP ${_value} _v)
 100   if(USE_POSIX_PACKAGING)
 101     string(TOLOWER ${_v} ${_varname})
 102   else()
 103     set(${_varname} ${_v})
 104   endif()
 105 endmacro(setstripped)
 106
 107 foreach(_c_l ${_config_lines} )
 108   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 109     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 110     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 111     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 112     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 113       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 114       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 115       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 116       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 117       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 118     endif()
 119   endif()
 120   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 121     set(LYX_DATE "${CMAKE_MATCH_1}")
 122   endif()
 123 endforeach(_c_l)
 124
 125 if(LYX_USE_VERSION_SUFFIX)
 126   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 127   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 128 else()
 129   set(PACKAGE ${PACKAGE_BASE})
 130   set(PROGRAM_SUFFIX "")
 131 endif()
 132
 133
 134 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 135   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 136   if (UNIX)
 137     # don't use the default "/usr/local"
 138     # but respect the user-choice on the command-line
 139     SET(CMAKE_INSTALL_PREFIX
 140       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 141   endif()
 142   if(WIN32)
 143     SET(CMAKE_INSTALL_PREFIX
 144       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
 145   endif()
 146 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 147
 148 if (WIN32)
 149   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 150 else()
 151   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 152 endif()
 153
 154 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 155 set(LYX_LOCALEDIR "locale")
 156 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 157 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 158
 159
 160 if(NOT GROUP_CODE)
 161         #set(GROUP_CODE "The Golden Code")
 162         set(GROUP_CODE flat)
 163 endif()
 164
 165 # lyx's source files
 166 set(LYX_CPP_FILES *.cpp)
 167 set(LYX_HPP_FILES *.h)
 168 set(LYX_MOC_FILES moc_*.cpp)
 169
 170
 171 include(ProjectSourceGroup)
 172
 173 if(LYX_MERGE_FILES)
 174         add_definitions(-DLYX_MERGED_BUILD)
 175 endif()
 176
 177
 178 set(CMAKE_BUILD_TYPE Release)
 179
 180 if(LYX_PROFILE)
 181         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 182         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 183             CACHE TYPE STRING FORCE)
 184 endif()
 185
 186 if(LYX_RELEASE)
 187         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 188 endif()
 189
 190 if(LYX_DEBUG)
 191         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 192 endif()
 193
 194
 195
 196 if(LYX_SHARED_LIBRARIES)
 197         set(library_type SHARED)
 198 else()
 199         set(library_type STATIC)
 200 endif()
 201
 202 if(NOT MSVC)
 203         if(NOT LYX_QUIET)
 204                 set(CMAKE_VERBOSE_MAKEFILE ON)
 205         endif()
 206         set(LYX_CXX_FLAGS -Wall)
 207         if(LYX_STDLIB_DEBUG)
 208                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 209         endif()
 210         if(LYX_CONCEPT_CHECKS)
 211                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 212         endif()
 213         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 214         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 215         if(MINGW)
 216                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 217         else()
 218                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 219         endif()
 220         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 221 endif()
 222
 223
 224 find_package(Qt4 REQUIRED)
 225 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 226
 227 find_package(ZLIB REQUIRED)
 228
 229 if(LYX_ASPELL)
 230         find_package(ASPELL REQUIRED)
 231 else()
 232         find_package(ASPELL)
 233 endif()
 234
 235
 236 if(LYX_USE_EXTERNAL_LIBINTL)
 237         find_package(Libintl REQUIRED)
 238         add_definitions(-DHAVE_GETTEXT)
 239 endif()
 240
 241
 242 if(WIN32)
 243   find_library(HUNSPELL_LIBRARY "libhunspell")
 244 else()
 245   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 246   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 247 endif()
 248 if (HUNSPELL_LIBRARY)
 249   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 250 endif()
 251
 252 if (HUNSPELL_FOUND)
 253   add_definitions(-DUSE_HUNSPELL=1)
 254   message(STATUS "Building with USE_HUNSPELL")
 255 else()
 256   message(STATUS "Hunspell not found, building without hunspell support")
 257 endif()
 258
 259 if(WIN32)
 260   find_library(ENCHANT_LIBRARY "libenchant")
 261   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 262 else()
 263   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 264   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 265 endif()
 266 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 267   set(ENCHANT_FOUND TRUE)
 268   add_definitions(-DUSE_ENCHANT=1)
 269   message(STATUS "Building with USE_ENCHANT")
 270 else()
 271   message(STATUS "Enchant not found, building without enchant support")
 272 endif()
 273
 274
 275 if(LYX_NLS)
 276         add_definitions(-DENABLE_NLS=1)
 277 endif()
 278
 279 if(ASPELL_FOUND)
 280         add_definitions(-DUSE_ASPELL=1)
 281 endif()
 282
 283 if(WIN32)
 284         if(LYX_NO_CONSOLE)
 285                 set(WIN32_CONSOLE WIN32)
 286                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 287         endif()
 288         if(MSVC)
 289                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 290                 # disable checked iterators for msvc release builds to get maximum speed
 291                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 292         else()
 293                 add_definitions(-DWINVER=0x0500)
 294         endif()
 295 endif()
 296
 297 message(STATUS "")
 298 foreach(_v PACKAGE PACKAGE_VERSION
 299     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 300     LYX_ABS_TOP_SRCDIR
 301     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 302   if(NOT DEFINED ${_v})
 303     message(FATAL_ERROR "${_v} not defined")
 304   endif()
 305   string(SUBSTRING "${_v}                            " 0 28 _v1)
 306   message(STATUS "----- ${_v1}: ${${_v}}")
 307 endforeach(_v)
 308 message(STATUS "")
 309
 310
 311 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 312 # Not sure if it works for all non-msvc compilers
 313 include(PCHSupport_26)
 314
 315 if(NOT LYX_DISABLE_PCH)
 316
 317         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 318         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 319         add_definitions(-DLYX_ENABLE_PCH)
 320
 321         if(MSVC AND NOT MERGE_FILES)
 322                 macro(lyx_add_msvc_pch name_)
 323                         set_source_files_properties(${${name_}_sources} PROPERTIES
 324                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 325                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 326                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 327                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 328                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 329                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 330                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 331                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 332                 endmacro(lyx_add_msvc_pch)
 333                 macro(lyx_add_gcc_pch name_)
 334                 endmacro()
 335         else()
 336                 macro(lyx_add_msvc_pch name_)
 337                 endmacro()
 338                 macro(lyx_add_gcc_pch name_)
 339                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 340                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 341                 endmacro()
 342         endif()
 343 else()
 344         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 345         macro(lyx_add_msvc_pch)
 346         endmacro(lyx_add_msvc_pch)
 347         macro(lyx_add_gcc_pch name_)
 348         endmacro()
 349 endif()
 350
 351 if(MSVC)
 352        if(LYX_VLD)
 353                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 354                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 355                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 356                include(${vld_path}/tools/cmake/vld.cmake)
 357        endif()
 358
 359         # TODO options
 360         if(WALL)
 361                 set(WALL 1 CACHE TYPE STRING FORCE)
 362
 363                 # Use the highest warning level
 364                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 365                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 366
 367                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 368                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 369                 else()
 370                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 371                 endif()
 372
 373                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 374                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 375                 else()
 376                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 377                 endif()
 378
 379                 # add here warnings which should produce an error /weXXXX
 380                 set(MSVC_W_ERROR   "/we4101 /we4189")
 381                 # add here warnings which should be disabled /wdXXXX
 382                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 383
 384                 set(CMAKE_CXX_FLAGS_DEBUG
 385                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 386                 set(CMAKE_CXX_FLAGS_RELEASE
 387                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 388                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 389                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 390
 391         else()
 392                 set(WALL 0 CACHE TYPE STRING FORCE)
 393
 394                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 395                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 396
 397                 # add here warnings which should produce an error /weXXXX
 398                 set(MSVC_W_ERROR   "/we4101 /we4189")
 399                 # add here warnings which should be disabled /wdXXXX
 400                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 401
 402                 set(CMAKE_CXX_FLAGS_DEBUG
 403                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 404                 set(CMAKE_CXX_FLAGS_RELEASE
 405                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 406                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 407                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 408
 409         endif()
 410         set(CMAKE_CXX_FLAGS_DEBUG
 411                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 412         set(CMAKE_CXX_FLAGS_RELEASE
 413                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 414         set(CMAKE_CXX_FLAGS_MINSIZEREL
 415                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 416
 417         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 418         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 419         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 420         message(STATUS "")
 421
 422 endif()
 423
 424
 425 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 426 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 427     if(LYX_NLS)
 428       find_package(LyXGettext REQUIRED)
 429       include_directories(${TOP_SRC_DIR}/po)
 430       add_subdirectory(po)
 431     endif()
 432 endif()
 433
 434
 435
 436 if(LYX_DEBUG_GLIBC)
 437   set(_GLIBCXX_DEBUG 1)
 438 endif()
 439
 440 if(LYX_DEBUG_GLIBC_PEDANTIC)
 441   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 442 endif()
 443
 444 # compiler tests, config.h generation
 445 if(MSVC AND NOT CONFIGURECHECKS)
 446         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 447 else()
 448         include(ConfigureChecks.cmake)
 449         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 450 endif()
 451
 452 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 453
 454 find_package(ICONV REQUIRED)
 455 add_definitions(-DHAVE_ICONV=1)
 456
 457
 458 include_directories(
 459   ${CMAKE_BINARY_DIR}
 460   ${TOP_SRC_DIR}/src)
 461
 462
 463 if(LYX_USE_EXTERNAL_BOOST)
 464   message(STATUS "Searching for boost")
 465   find_package(Boost COMPONENTS signals regex)
 466   if(Boost_FOUND)
 467     message(STATUS "Boost found")
 468     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 469     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 470   else()
 471     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 472   endif()
 473 else()
 474   if(LYX_USE_TR1_REGEX)
 475     set(Lyx_Boost_Libraries boost_signals)
 476   else()
 477     set(Lyx_Boost_Libraries boost_signals boost_regex)
 478   endif()
 479   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 480   include_directories(${TOP_SRC_DIR}/boost)
 481   add_subdirectory(boost)
 482 endif()
 483
 484
 485 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 486   add_subdirectory(intl)
 487 endif()
 488 add_subdirectory(src)
 489
 490 if(LYX_INSTALL)
 491         add_subdirectory(man)
 492         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 493                 add_subdirectory(doc)
 494         endif()
 495 endif()
 496 add_subdirectory(lyx2lyx)
 497 add_subdirectory(scripts)
 498
 499 if(LYX_INSTALL)
 500         include(../Install)
 501 endif()
 502
 503 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 504 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 505 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 506
 507 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 508 #
 509 # needed by rpm
 510 SET(CPACK_SET_DESTDIR "ON")
 511 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 512 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 513 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 514 #
 515 # the next ones are needed by deb
 516 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 517 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 518
 519 # This is experimental, valid on _my_ system (Kornel)
 520 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 521 IF(ASPELL_FOUND)
 522   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 523 ENDIF()
 524 #
 525 # for the next ones, cpack insists on data with values in some file
 526 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 527 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 528
 529 # Find the revision number and use it as the release in rpm-package-build.
 530 # This way we may omit the otherwise needed "--force" parameter when
 531 # installing from that rpm package.
 532 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 533 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 534 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 535   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 536   # We use this value also to set the package-patch-value
 537   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 538     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 539   endif()
 540 endif()
 541
 542 # we do not have a readme or welcome data,
 543 # so we do not provide infofiles for
 544 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 545
 546 if(LYX_INSTALL)
 547         include(CPack)
 548 endif()
 549
 550 #Now it is possible to create some packages
 551 # cd <BuildDir>
 552 # make package
 553 #############################################################################################
 554 # So, e.g. for variables
 555 #    CMAKE_PROJECT_NAME                     : lyx
 556 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 557 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 558 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 559 #    CMAKE_SYSTEM_NAME                      : Linux
 560 #    CPACK_BINARY_DEB:BOOL                  : ON
 561 #
 562 # the package name builds as "lyx-2.0.1-Linux.deb"
 563 #
 564 ############################## rpm ################################### deb ##################
 565 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 566 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 567 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 568 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 569 #
 570 message(STATUS)