development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26 message(STATUS)
  27 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  28
  29 # Usage LYX_OPTION
  30 # 1. parameter: option name without prefix 'LYX_'
  31 # 2. parameter: description
  32 # 3. parameter: default value, ON or OFF
  33 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  34 message(STATUS)
  35 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  36 message(STATUS)
  37 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  38 LYX_OPTION(NLS "Use nls" OFF ALL)
  39 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  40 LYX_OPTION(AIKSAURUS "Require Aiksaurus" OFF ALL)
  41 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  42 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  43 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  44 LYX_OPTION(RELEASE "Build release version" ON ALL)
  45 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  46 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  47 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  48 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  49 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  50 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  51 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  52 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  53 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  54 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  55 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  56 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  57 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  58 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  59 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  60 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  61 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  62
  63 message(STATUS)
  64
  65 if(LYX_CPACK)
  66         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  67 endif()
  68 if(LYX_INSTALL)
  69         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  70         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  71         set(LYX_AIKSAURUS ON CACHE BOOL "Aiksaurus option" FORCE)
  72         if (WIN32)
  73                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  74         endif()
  75         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  76         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  77         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  78         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  79         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  80 endif()
  81
  82
  83 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  84 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  85
  86
  87
  88 if(UNIX OR MINGW)
  89     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  90     message(STATUS "Using GCC version ${GCC_VERSION}")
  91     if(NOT GCC_VERSION VERSION_LESS 4.4)
  92         set(LYX_USE_TR1 1)
  93         # GCC <= 4.5 does not support regex: there are linker errors
  94         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  95         set(LYX_USE_TR1_REGEX 0)
  96     endif()
  97 else()
  98     if(MSVC10)
  99         set(LYX_USE_TR1 1)
 100         set(LYX_USE_TR1_REGEX 1)
 101     endif()
 102 endif()
 103
 104
 105
 106 # Supress regeneration
 107 set(CMAKE_SUPPRESS_REGENERATION TRUE)
 108
 109 set(VERSION_INFO "CMake Build")
 110
 111 # Try to get some informations from configure.ac
 112
 113 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
 114 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 115
 116 if(WIN32)
 117   set(USE_WINDOWS_PACKAGING 1)
 118 elseif(APPLE)
 119   set(USE_MACOSX_PACKAGING 1)
 120 else()
 121   set(USE_POSIX_PACKAGING 1)
 122 endif()
 123
 124 macro(setstripped _varname _value)
 125   string(STRIP ${_value} _v)
 126   if(USE_POSIX_PACKAGING)
 127     string(TOLOWER ${_v} ${_varname})
 128   else()
 129     set(${_varname} ${_v})
 130   endif()
 131 endmacro(setstripped)
 132
 133 foreach(_c_l ${_config_lines} )
 134   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 135     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 136     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 137     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 138     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 139       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 140       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 141       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 142       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 143       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 144     endif()
 145   endif()
 146   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 147     set(LYX_DATE "${CMAKE_MATCH_1}")
 148   endif()
 149 endforeach(_c_l)
 150
 151
 152 if(LYX_PACKAGE_SUFFIX)
 153   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 154 else()
 155   set(PACKAGE ${PACKAGE_BASE})
 156 endif()
 157
 158 if(LYX_PROGRAM_SUFFIX)
 159   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 160 else()
 161   set(PROGRAM_SUFFIX "")
 162 endif()
 163
 164
 165 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 166   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 167   if (UNIX)
 168     # don't use the default "/usr/local"
 169     # but respect the user-choice on the command-line
 170     if(LYX_INSTALL_SUFFIX)
 171         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 172     else()
 173         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 174     endif()
 175   endif()
 176   if(WIN32)
 177     SET(CMAKE_INSTALL_PREFIX
 178       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 179   endif()
 180 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 181
 182 if (WIN32)
 183   set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 184 else()
 185   set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 186 endif()
 187
 188 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 189 set(LYX_LOCALEDIR "locale")
 190 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 191 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 192
 193
 194 if(NOT GROUP_CODE)
 195         #set(GROUP_CODE "The Golden Code")
 196         set(GROUP_CODE flat)
 197 endif()
 198
 199 # lyx's source files
 200 set(LYX_CPP_FILES *.cpp)
 201 set(LYX_HPP_FILES *.h)
 202 set(LYX_MOC_FILES moc_*.cpp)
 203
 204
 205 include(ProjectSourceGroup)
 206
 207
 208 if(LYX_PROFILE)
 209         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 210         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 211 endif()
 212
 213 if(LYX_RELEASE)
 214         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 215 endif()
 216
 217 if(LYX_DEBUG)
 218         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 219 endif()
 220
 221
 222
 223 if(LYX_SHARED_LIBRARIES)
 224         set(library_type SHARED)
 225 else()
 226         set(library_type STATIC)
 227 endif()
 228
 229 if(NOT MSVC)
 230         if(NOT LYX_QUIET)
 231                 set(CMAKE_VERBOSE_MAKEFILE ON)
 232         endif()
 233         set(LYX_CXX_FLAGS -Wall)
 234         if(LYX_STDLIB_DEBUG)
 235                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 236         endif()
 237         if(LYX_CONCEPT_CHECKS)
 238                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 239         endif()
 240         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 241         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 242         if(MINGW)
 243                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 244         else()
 245                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 246         endif()
 247         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 248 endif()
 249
 250
 251 find_package(Qt4 REQUIRED)
 252 find_package(ICONV REQUIRED)
 253 find_package(ZLIB REQUIRED)
 254
 255 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 256
 257 if(LYX_ASPELL)
 258         find_package(ASPELL)
 259         include_directories(${ASPELL_INCLUDE_DIR})
 260 endif()
 261
 262 if(LYX_AIKSAURUS)
 263         find_package(AiksaurusLIB REQUIRED)
 264         include_directories(${AIKSAURUSLIB_INCLUDE_DIR})
 265 endif()
 266
 267 if(LYX_ENCHANT)
 268         find_package(Enchant REQUIRED)
 269         include_directories(${ENCHANT_INCLUDE_DIR})
 270 endif()
 271
 272 if(LYX_HUNSPELL)
 273         find_package(Hunspell REQUIRED)
 274         include_directories(${HUNSPELL_INCLUDE_DIR})
 275 endif()
 276
 277 if(LYX_NLS)
 278         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 279         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 280                 message(FATAL_ERROR "Python 2.6 needed!")
 281         endif()
 282         find_package(LyXGettext REQUIRED)
 283         include_directories(${TOP_SRC_DIR}/po)
 284         add_subdirectory(po)
 285 endif()
 286
 287 if(LYX_USE_EXTERNAL_LIBINTL)
 288         find_package(Libintl REQUIRED)
 289         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 290 else()
 291         add_subdirectory(intl)
 292 endif()
 293
 294 if(LYX_USE_EXTERNAL_BOOST)
 295         message(STATUS "Searching for boost")
 296         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 297         if(Boost_FOUND)
 298                 message(STATUS "Boost found")
 299                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 300                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 301         else()
 302                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 303         endif()
 304 else()
 305         if(LYX_USE_TR1_REGEX)
 306                 set(Lyx_Boost_Libraries boost_signals)
 307         else()
 308                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 309         endif()
 310         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 311         include_directories(${TOP_SRC_DIR}/boost)
 312         add_subdirectory(boost)
 313 endif()
 314
 315
 316
 317
 318 if(WIN32)
 319         if(LYX_NO_CONSOLE)
 320                 set(WIN32_CONSOLE WIN32)
 321                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 322         endif()
 323         if(MSVC)
 324                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 325                 # disable checked iterators for msvc release builds to get maximum speed
 326                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 327         else()
 328                 add_definitions(-DWINVER=0x0500)
 329         endif()
 330 endif()
 331
 332 message(STATUS "")
 333 foreach(_v PACKAGE PACKAGE_VERSION
 334     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 335     LYX_ABS_TOP_SRCDIR
 336     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 337   if(NOT DEFINED ${_v})
 338     message(FATAL_ERROR "${_v} not defined")
 339   endif()
 340   string(SUBSTRING "${_v}                            " 0 28 _v1)
 341   message(STATUS "----- ${_v1}: ${${_v}}")
 342 endforeach(_v)
 343 message(STATUS "")
 344
 345
 346 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 347 # Not sure if it works for all non-msvc compilers
 348 include(PCHSupport_26)
 349
 350 if(NOT LYX_DISABLE_PCH)
 351
 352         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 353         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 354         add_definitions(-DLYX_ENABLE_PCH)
 355
 356         if(MSVC AND NOT MERGE_FILES)
 357                 macro(lyx_add_msvc_pch name_)
 358                         set_source_files_properties(${${name_}_sources} PROPERTIES
 359                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 360                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 361                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 362                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 363                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 364                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 365                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 366                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 367                 endmacro(lyx_add_msvc_pch)
 368                 macro(lyx_add_gcc_pch name_)
 369                 endmacro()
 370         else()
 371                 macro(lyx_add_msvc_pch name_)
 372                 endmacro()
 373                 macro(lyx_add_gcc_pch name_)
 374                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 375                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 376                 endmacro()
 377         endif()
 378 else()
 379         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 380         macro(lyx_add_msvc_pch)
 381         endmacro(lyx_add_msvc_pch)
 382         macro(lyx_add_gcc_pch name_)
 383         endmacro()
 384 endif()
 385
 386 if(MSVC)
 387         if(LYX_VLD)
 388            set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 389            set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 390            set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 391            include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 392         endif()
 393
 394         # TODO options
 395         if(LYX_WALL)
 396                 # Use the highest warning level
 397                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 398
 399                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 400                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 401                 else()
 402                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 403                 endif()
 404
 405                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 406                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 407                 else()
 408                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 409                 endif()
 410
 411                 # add here warnings which should produce an error /weXXXX
 412                 set(MSVC_W_ERROR   "/we4101 /we4189")
 413                 # add here warnings which should be disabled /wdXXXX
 414                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 415
 416                 set(CMAKE_CXX_FLAGS_DEBUG
 417                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 418                 set(CMAKE_CXX_FLAGS_RELEASE
 419                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 420                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 421                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 422
 423         else()
 424                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 425
 426                 # add here warnings which should produce an error /weXXXX
 427                 set(MSVC_W_ERROR   "/we4101 /we4189")
 428                 # add here warnings which should be disabled /wdXXXX
 429                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 430
 431                 set(CMAKE_CXX_FLAGS_DEBUG
 432                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 433                 set(CMAKE_CXX_FLAGS_RELEASE
 434                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 435                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 436                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 437
 438         endif()
 439         set(CMAKE_CXX_FLAGS_DEBUG
 440                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 441         set(CMAKE_CXX_FLAGS_RELEASE
 442                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 443         set(CMAKE_CXX_FLAGS_MINSIZEREL
 444                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 445
 446         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 447         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 448         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 449         message(STATUS "")
 450
 451 endif()
 452
 453
 454 if(LYX_DEBUG_GLIBC)
 455   set(_GLIBCXX_DEBUG 1)
 456 endif()
 457
 458 if(LYX_DEBUG_GLIBC_PEDANTIC)
 459   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 460 endif()
 461
 462 # compiler tests, config.h generation
 463 if(MSVC AND NOT CONFIGURECHECKS)
 464         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 465 else()
 466         include(ConfigureChecks.cmake)
 467         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 468 endif()
 469
 470 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 471
 472
 473 add_subdirectory(src)
 474 add_subdirectory(lyx2lyx)
 475 add_subdirectory(scripts)
 476
 477
 478 if(LYX_INSTALL)
 479         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 480         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 481                 message(FATAL_ERROR "Perl required!")
 482         endif()
 483         add_subdirectory(man)
 484         add_subdirectory(doc)
 485         include(../Install)
 486 endif()
 487
 488
 489 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 490 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 491 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 492
 493 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 494 #
 495 # needed by rpm
 496 SET(CPACK_SET_DESTDIR "ON")
 497 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 498 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 499 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 500 #
 501 # the next ones are needed by deb
 502 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 503 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 504
 505 # This is experimental, valid on _my_ system (Kornel)
 506 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 507 IF(ASPELL_FOUND)
 508   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 509 ENDIF()
 510 #
 511 # for the next ones, cpack insists on data with values in some file
 512 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 513 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 514
 515 # Find the revision number and use it as the release in rpm-package-build.
 516 # This way we may omit the otherwise needed "--force" parameter when
 517 # installing from that rpm package.
 518 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 519 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 520 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 521   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 522   # We use this value also to set the package-patch-value
 523   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 524     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 525   endif()
 526 endif()
 527
 528 # we do not have a readme or welcome data,
 529 # so we do not provide infofiles for
 530 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 531
 532 include(CPack)
 533
 534 #Now it is possible to create some packages
 535 # cd <BuildDir>
 536 # make package
 537 #############################################################################################
 538 # So, e.g. for variables
 539 #    CMAKE_PROJECT_NAME                     : lyx
 540 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 541 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 542 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 543 #    CMAKE_SYSTEM_NAME                      : Linux
 544 #    CPACK_BINARY_DEB:BOOL                  : ON
 545 #
 546 # the package name builds as "lyx-2.0.1-Linux.deb"
 547 #
 548 ############################## rpm ################################### deb ##################
 549 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 550 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 551 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 552 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 553 #
 554 message(STATUS)