development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  10
  11 project(lyx)
  12
  13 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  14 # is checked
  15 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  16 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  17
  18 # Supress regeneration
  19 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  20
  21 set(PACKAGE lyx)
  22 set(PACKAGE_VERSION 1.6svn)
  23 set(LYX_DATE "2007/2008")
  24 #TODO
  25 set(VERSION_INFO "CMake Build")
  26
  27 set(PROGRAM_SUFFIX "")
  28 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
  29 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
  30 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
  31
  32
  33 if(WIN32)
  34         set(USE_WINDOWS_PACKAGING 1)
  35 elseif(APPLE)
  36         set(USE_MACOSX_PACKAGING 1)
  37 else()
  38         set(USE_POSIX_PACKAGING 1)
  39 endif()
  40
  41 if(NOT GROUP_CODE)
  42         #set(GROUP_CODE "The Golden Code")
  43         set(GROUP_CODE flat)
  44 endif()
  45
  46 # lyx's source files
  47 set(LYX_CPP_FILES *.cpp)
  48 set(LYX_HPP_FILES *.h)
  49
  50 include(LyXPaths)
  51 include(LyXMacros)
  52 include(ProjectSourceGroup)
  53
  54 if(merge OR merge_rebuild)
  55         set(merge 1 CACHE TYPE STRING FORCE)
  56         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  57         message(STATUS "")
  58         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  59         message(STATUS "")
  60 else()
  61         set(merge 0 CACHE TYPE STRING FORCE)
  62         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
  63         message(STATUS "Enable merging files with -Dmerge=1")
  64 endif()
  65
  66
  67 set(CMAKE_BUILD_TYPE Release)
  68
  69 if(profile)
  70         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
  71         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
  72             CACHE TYPE STRING FORCE)
  73         set(profile)
  74 endif()
  75
  76 if(release)
  77         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
  78         set(release)
  79 endif()
  80
  81 if(debug)
  82         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
  83 endif()
  84
  85 if(shared)
  86         set(library_type SHARED)
  87         message(STATUS "building shared libraries")
  88 else()
  89         set(library_type STATIC)
  90 endif()
  91
  92 if(UNIX)
  93         if(NOT quiet)
  94                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
  95                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
  96                 message(STATUS "")
  97         endif()
  98         set(LYX_CXX_FLAGS -Wall)
  99         if(stdlib-debug)
 100                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 101         endif()
 102         if(concept-checks)
 103                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 104         endif()
 105         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 106         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 107         set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 108         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 109 endif()
 110
 111
 112 find_package(Qt4 REQUIRED)
 113 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 114
 115 find_package(ZLIB REQUIRED)
 116
 117 if(all OR aspell)
 118         set(aspell TRUE CACHE TYPE STRING)
 119         find_package(ASPELL REQUIRED)
 120 else()
 121         find_package(ASPELL)
 122 endif()
 123 set(aspell)
 124
 125 message("")
 126 if(nls OR all)
 127         set(nls TRUE CACHE TYPE STRING)
 128         add_definitions(-DENABLE_NLS=1)
 129         message("----- Building with ENABLE_NLS")
 130 else()
 131         message("----- No nls, to enable use -Dnls=1")
 132 endif()
 133 set(nls)
 134 if(ASPELL_FOUND)
 135         add_definitions(-DUSE_ASPELL=1)
 136         message("----- Building with USE_ASPELL")
 137 else()
 138         message("----- No aspell, to get more information use -Daspell=1")
 139 endif()
 140 set(all)
 141
 142 if(WIN32)
 143         if(noconsole)
 144                 set(noconsole TRUE CACHE TYPE STRING)
 145                 set(WIN32_CONSOLE WIN32)
 146                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 147                 message("----- Console disabled")
 148         else()
 149                 message("----- Console enabled, disable it with -Dnoconsole=1")
 150         endif()
 151 endif()
 152
 153 set(PROGRAM_SUFFIX "\"\"")
 154 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
 155 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
 156 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
 157
 158 message("")
 159 message("----- PROGRAM_SUFFIX              : ${PROGRAM_SUFFIX}")
 160 message("----- LYX_ABS_TOP_SRCDIR          : ${LYX_ABS_TOP_SRCDIR}")
 161 message("----- LYX_ABS_INSTALLED_DATADIR   : ${LYX_ABS_INSTALLED_DATADIR}")
 162 message("----- LYX_ABS_INSTALLED_LOCALEDIR : ${LYX_ABS_INSTALLED_LOCALEDIR}")
 163 message("")
 164
 165 if(MSVC)
 166         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 167         # disable checked iterators for msvc release builds to get maximum speed
 168         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 169 endif()
 170
 171 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 172
 173 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 174         message("-----")
 175         message("----- using precompiled headers, disable with -Ddisable-pch=1")
 176         message("-----")
 177         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 178                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 179         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 180                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 181         macro(lyx_add_msvc_pch name_)
 182                 set_source_files_properties(${${name_}_sources} PROPERTIES
 183                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 184                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 185                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 186                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 187                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 188                 add_definitions(/DLYX_ENABLE_PCH)
 189         endmacro(lyx_add_msvc_pch)
 190         set(CMAKE_CXX_FLAGS_DEBUG
 191                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 192         set(CMAKE_CXX_FLAGS_RELEASE
 193                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 194         set(CMAKE_CXX_FLAGS_MINSIZEREL
 195                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 196 else()
 197         if(MSVC)
 198                 message("-----")
 199                 message("----- precompiled headers disabled, enable with -Ddisable-pch=0")
 200                 message("-----")
 201         endif()
 202         set(disable-pch TRUE CACHE TYPE STRING)
 203         macro(lyx_add_msvc_pch)
 204         endmacro(lyx_add_msvc_pch)
 205 endif()
 206
 207 if(MSVC)
 208        if(vld)
 209                set(vld 1 CACHE TYPE STRING FORCE)
 210                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 211                message(STATUS "")
 212                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 213                message(STATUS "")
 214                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 215                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 216                include(${vld_path}/tools/cmake/vld.cmake)
 217        else()
 218                set(vld 0 CACHE TYPE STRING FORCE)
 219                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 220                message(STATUS "")
 221                message(STATUS "Enable leak detection with -Dvld=1")
 222                message(STATUS "")
 223        endif()
 224
 225         if(WALL)
 226                 set(WALL 1 CACHE TYPE STRING FORCE)
 227
 228                 # Use the highest warning level
 229                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 230                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 231
 232                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 233                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 234                 else()
 235                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 236                 endif()
 237
 238                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 239                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 240                 else()
 241                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 242                 endif()
 243
 244                 # add here warnings which should produce an error /weXXXX
 245                 set(MSVC_W_ERROR   "/we4101 /we4189")
 246                 # add here warnings which should be disabled /wdXXXX
 247                 set(MSVC_W_DISABLE "/wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 248
 249                 set(CMAKE_CXX_FLAGS_DEBUG
 250                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 251                 set(CMAKE_CXX_FLAGS_RELEASEs
 252                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 253                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 254                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 255
 256         else()
 257                 set(WALL 0 CACHE TYPE STRING FORCE)
 258
 259                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 260                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 261
 262                 # add here warnings which should produce an error /weXXXX
 263                 set(MSVC_W_ERROR   "/we4101 /we4189")
 264                 # add here warnings which should be disabled /wdXXXX
 265                 set(MSVC_W_DISABLE "/wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 266
 267                 set(CMAKE_CXX_FLAGS_DEBUG
 268                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 269                 set(CMAKE_CXX_FLAGS_RELEASE
 270                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 271                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 272                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 273
 274         endif()
 275
 276         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 277         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 278         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 279         message("")
 280
 281 endif()
 282
 283 # compiler tests, config.h generation
 284 if(UNIX)
 285         include(ConfigureChecks.cmake)
 286         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 287 else()
 288         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 289 endif()
 290 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 291
 292
 293 find_package(ICONV REQUIRED)
 294 add_definitions(-DHAVE_ICONV=1)
 295
 296
 297 #TODO: insource is not the best place
 298 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 299                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 300
 301 include_directories(
 302         ${CMAKE_BINARY_DIR}
 303         ${TOP_SRC_DIR}/src
 304         ${TOP_SRC_DIR}/boost)
 305
 306 add_subdirectory(boost)
 307 add_subdirectory(intl)
 308 add_subdirectory(src)
 309
 310 include(../Install)
 311