development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.4 FATAL_ERROR)
   8
   9
  10 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  11 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  12
  13 set (EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  14
  15 set(PACKAGE lyx)
  16 set(PACKAGE_VERSION 1.5.0svn)
  17 set(LYX_DATE "not released yet")
  18 #TODO
  19 set(VERSION_INFO "CMake Build")
  20
  21 if(WIN32)
  22         set(USE_WINDOWS_PACKAGING 1)
  23 else(WIN32)
  24         set(USE_POSIX_PACKAGING 1)
  25 endif(WIN32)
  26
  27 if(NOT GROUP_CODE)
  28         #set(GROUP_CODE "The Golden Code")
  29         set(GROUP_CODE flat)
  30 endif(NOT GROUP_CODE)
  31
  32 include(LyXPaths)
  33 include(LyXMacros)
  34 include(ProjectSourceGroup)
  35
  36 if(merge OR MERGE_FILES)
  37         if(NOT MERGE_FILES)
  38                 set(MERGE_FILES TRUE CACHE TYPE STRING FORCE)
  39         endif(NOT MERGE_FILES)
  40         message(STATUS "")
  41         message(STATUS "will merge all *.C files of a project into two files")
  42         message(STATUS "")
  43 endif(merge OR MERGE_FILES)
  44
  45
  46 set(CMAKE_BUILD_TYPE)
  47 if(profile)
  48         set(CMAKE_BUILD_TYPE Profile)
  49         set(profile)
  50 endif(profile)
  51 if(release)
  52         set(CMAKE_BUILD_TYPE Release)
  53         set(release)
  54 endif(release)
  55 if(debug)
  56         set(CMAKE_BUILD_TYPE Debug)
  57 endif(debug)
  58
  59
  60 if(UNIX)
  61         set(LYX_CXX_FLAGS -Wall)
  62         if(stdlib-debug)
  63                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
  64         endif(stdlib-debug)
  65         if(concept-checks)
  66                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
  67         endif(concept-checks)
  68         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
  69         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
  70         set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
  71         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
  72 endif(UNIX)
  73
  74
  75 set(qt_postfix qt4)
  76 project(lyx-${qt_postfix})
  77 find_package(Qt4 REQUIRED)
  78 # maybe anyway
  79 if(MERGE_FILES)
  80         add_definitions(-DQT_CLEAN_NAMESPACE -DQT_NO_STL -DQT_NO_KEYWORDS)
  81 endif(MERGE_FILES)
  82
  83 find_package(ZLIB REQUIRED)
  84
  85 if(all OR aspell)
  86         set(aspell TRUE CACHE TYPE STRING)
  87         find_package(ASPELL REQUIRED)
  88 else(all OR aspell)
  89         find_package(ASPELL)
  90 endif(all OR aspell)
  91 set(aspell)
  92
  93 message("")
  94 if(nls OR all)
  95         set(nls TRUE CACHE TYPE STRING)
  96         add_definitions(-DENABLE_NLS=1)
  97         message("----- Building with ENABLE_NLS")
  98 else(nls OR all)
  99         message("----- No nls, to enable use -Dnls=1")
 100 endif(nls OR all)
 101 set(nls)
 102 if(ASPELL_FOUND)
 103         add_definitions(-DUSE_ASPELL=1)
 104         message("----- Building with USE_ASPELL")
 105 else(ASPELL_FOUND)
 106         message("----- No aspell, to get more information use -Daspell=1")
 107 endif(ASPELL_FOUND)
 108 set(all)
 109
 110 if(WIN32)
 111         if(noconsole)
 112                 set(noconsole TRUE CACHE TYPE STRING)
 113                 set(WIN32_CONSOLE WIN32)
 114                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 115                 message("----- Console disabled")
 116         else(noconsole)
 117                 message("----- Console enabled, disable it with -Dnoconsole=1")
 118         endif(noconsole)
 119 endif(WIN32)
 120
 121 set(LYX_DIR         "")
 122 set(TOP_SRCDIR      "${TOP_SRC_DIR}")
 123 set(PROGRAM_SUFFIX  "")
 124 set(LOCALEDIR       "")
 125
 126 message("")
 127 message("----- LYX_DIR       : ${LYX_DIR}")
 128 message("----- TOP_SRCDIR    : ${TOP_SRCDIR}")
 129 message("----- PROGRAM_SUFFIX: ${PROGRAM_SUFFIX}")
 130 message("----- LOCALEDIR     : ${LOCALEDIR}")
 131 message("")
 132
 133 if(MSVC)
 134         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 135         # disable checked iterators for msvc release builds to get maximum speed
 136         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 137 endif(MSVC)
 138
 139 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 140
 141 if(MSVC AND NOT disable-pch)
 142         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h    ${CMAKE_BINARY_DIR}/pcheaders.h)
 143         configure_file(${CMAKE_SOURCE_DIR}/config.C.cmake ${CMAKE_BINARY_DIR}/config_pch.C)
 144         macro(lyx_add_msvc_pch name_)
 145                 SET_SOURCE_FILES_PROPERTIES(${${name_}_sources} PROPERTIES COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 146                 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/config_pch.C PROPERTIES COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 147                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.C ${CMAKE_BINARY_DIR}/pcheaders.h)
 148                 add_definitions(/DLYX_ENABLE_PCH)
 149         endmacro(lyx_add_msvc_pch)
 150         set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 151         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 152         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 153 else(MSVC AND NOT disable-pch)
 154         set(disable-pch TRUE CACHE TYPE STRING)
 155         macro(lyx_add_msvc_pch)
 156         endmacro(lyx_add_msvc_pch)
 157 endif(MSVC AND NOT disable-pch)
 158
 159 if(MSVC)
 160         if(WALL)
 161                 set(WALL 1 CACHE TYPE STRING FORCE)
 162                 set(DISABLEWALL 0 CACHE TYPE STRING FORCE)
 163         else(WALL)
 164                 set(DISABLEWALL 1 CACHE TYPE STRING FORCE)
 165         endif(WALL)
 166
 167         if(NOT DISABLEWALL)
 168
 169                 # Use the highest warning level
 170                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 171
 172                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 173                         STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 174                 else(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 175                         SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 176                 endif(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 177
 178                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 179                         STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 180                 else(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 181                         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 182                 endif(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 183
 184                 # add here warnings which should produce an error /weXXXX
 185                 SET(MSVC_W_ERROR   "/we4101 /we4189")
 186                 # add here warnings which should be disabled /wdXXXX
 187                 SET(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127")
 188
 189                 set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 190                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 191                 set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 192
 193         else(NOT DISABLEWALL)
 194
 195                 set(DISABLEWALL 1 CACHE TYPE STRING FORCE)
 196                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 197                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 198
 199                 # add here warnings which should produce an error /weXXXX
 200                 SET(MSVC_W_ERROR   "/we4101 /we4189")
 201                 # add here warnings which should be disabled /wdXXXX
 202                 SET(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4267")
 203
 204                 set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 205                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 206                 set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 207
 208         endif(NOT DISABLEWALL)
 209
 210         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 211         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 212         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 213         message("")
 214
 215 endif(MSVC)
 216
 217 # create config.h
 218 include(ConfigureChecks.cmake)
 219 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 220
 221 find_package(ICONV REQUIRED)
 222 add_definitions(-DHAVE_ICONV=1)
 223
 224
 225 #TODO: insource is not the best place
 226 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 227                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 228
 229 include_directories(
 230         ${CMAKE_BINARY_DIR}
 231         ${TOP_SRC_DIR}/src
 232         ${TOP_SRC_DIR}/boost
 233         ${QT_INCLUDES}
 234 )
 235
 236 add_subdirectory(boost)
 237 add_subdirectory(intl)
 238 add_subdirectory(src)