development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26 message(STATUS)
  27 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  28
  29 # Usage LYX_OPTION
  30 # 1. parameter: option name without prefix 'LYX_'
  31 # 2. parameter: description
  32 # 3. parameter: default value, ON or OFF
  33 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  34 message(STATUS)
  35 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  36 message(STATUS)
  37 LYX_OPTION(NLS "Use nls" OFF ALL)
  38 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  39 LYX_OPTION(AIKSAURUS "Require Aiksaurus" OFF ALL)
  40 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  41 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  42 LYX_OPTION(RELEASE "Build release version" ON ALL)
  43 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  44 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  45 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  46 LYX_OPTION(INSTALL "Build install projects/rules" OFF ALL)
  47 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  48 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  49 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  50 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  51 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  52 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  53 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  54 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  55 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  56 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  57 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  58 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  59 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  60
  61 message(STATUS)
  62
  63 if(LYX_INSTALL)
  64         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  65         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  66         set(LYX_AIKSAURUS ON CACHE BOOL "Aiksaurus option" FORCE)
  67         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  68         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  69         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  70         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  71         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  72         set(LYX_MERGE_FILES ON CACHE BOOL "Merge option" FORCE)
  73 endif()
  74
  75
  76 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  77 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  78
  79
  80
  81 if(UNIX OR MINGW)
  82     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  83     message(STATUS "Using GCC version ${GCC_VERSION}")
  84     if(NOT GCC_VERSION VERSION_LESS 4.4)
  85         set(LYX_USE_TR1 1)
  86         # GCC <= 4.5 does not support regex: there are linker errors
  87         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  88         set(LYX_USE_TR1_REGEX 0)
  89     endif()
  90 else()
  91     if(MSVC10)
  92         set(LYX_USE_TR1 1)
  93         set(LYX_USE_TR1_REGEX 1)
  94     endif()
  95 endif()
  96
  97
  98
  99 # Supress regeneration
 100 set(CMAKE_SUPPRESS_REGENERATION TRUE)
 101
 102 set(VERSION_INFO "CMake Build")
 103
 104 # Try to get some informations from configure.ac
 105
 106 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
 107 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 108
 109 if(WIN32)
 110   set(USE_WINDOWS_PACKAGING 1)
 111 elseif(APPLE)
 112   set(USE_MACOSX_PACKAGING 1)
 113 else()
 114   set(USE_POSIX_PACKAGING 1)
 115 endif()
 116
 117 macro(setstripped _varname _value)
 118   string(STRIP ${_value} _v)
 119   if(USE_POSIX_PACKAGING)
 120     string(TOLOWER ${_v} ${_varname})
 121   else()
 122     set(${_varname} ${_v})
 123   endif()
 124 endmacro(setstripped)
 125
 126 foreach(_c_l ${_config_lines} )
 127   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 128     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 129     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 130     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 131     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 132       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 133       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 134       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 135       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 136       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 137     endif()
 138   endif()
 139   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 140     set(LYX_DATE "${CMAKE_MATCH_1}")
 141   endif()
 142 endforeach(_c_l)
 143
 144
 145 if(LYX_PACKAGE_SUFFIX)
 146   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 147 else()
 148   set(PACKAGE ${PACKAGE_BASE})
 149 endif()
 150
 151 if(LYX_PROGRAM_SUFFIX)
 152   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 153 else()
 154   set(PROGRAM_SUFFIX "")
 155 endif()
 156
 157
 158 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 159   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 160   if (UNIX)
 161     # don't use the default "/usr/local"
 162     # but respect the user-choice on the command-line
 163     if(LYX_INSTALL_SUFFIX)
 164         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 165     else()
 166         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 167     endif()
 168   endif()
 169   if(WIN32)
 170     SET(CMAKE_INSTALL_PREFIX
 171       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 172   endif()
 173 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 174
 175 if (WIN32)
 176   set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 177 else()
 178   set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 179 endif()
 180
 181 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 182 set(LYX_LOCALEDIR "locale")
 183 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 184 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 185
 186
 187 if(NOT GROUP_CODE)
 188         #set(GROUP_CODE "The Golden Code")
 189         set(GROUP_CODE flat)
 190 endif()
 191
 192 # lyx's source files
 193 set(LYX_CPP_FILES *.cpp)
 194 set(LYX_HPP_FILES *.h)
 195 set(LYX_MOC_FILES moc_*.cpp)
 196
 197
 198 include(ProjectSourceGroup)
 199
 200
 201 if(LYX_PROFILE)
 202         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 203         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 204 endif()
 205
 206 if(LYX_RELEASE)
 207         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 208 endif()
 209
 210 if(LYX_DEBUG)
 211         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 212 endif()
 213
 214
 215
 216 if(LYX_SHARED_LIBRARIES)
 217         set(library_type SHARED)
 218 else()
 219         set(library_type STATIC)
 220 endif()
 221
 222 if(NOT MSVC)
 223         if(NOT LYX_QUIET)
 224                 set(CMAKE_VERBOSE_MAKEFILE ON)
 225         endif()
 226         set(LYX_CXX_FLAGS -Wall)
 227         if(LYX_STDLIB_DEBUG)
 228                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 229         endif()
 230         if(LYX_CONCEPT_CHECKS)
 231                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 232         endif()
 233         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 234         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 235         if(MINGW)
 236                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 237         else()
 238                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 239         endif()
 240         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 241 endif()
 242
 243
 244 find_package(Qt4 REQUIRED)
 245 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 246
 247 find_package(ZLIB REQUIRED)
 248
 249 if(LYX_ASPELL)
 250         find_package(ASPELL)
 251         include_directories(${ASPELL_INCLUDE_DIR})
 252 endif()
 253
 254 if(LYX_AIKSAURUS)
 255         find_package(AiksaurusLIB REQUIRED)
 256         include_directories(${AIKSAURUSLIB_INCLUDE_DIR})
 257 endif()
 258
 259 if(LYX_ENCHANT)
 260         find_package(Enchant REQUIRED)
 261         include_directories(${ENCHANT_INCLUDE_DIR})
 262 endif()
 263
 264
 265 if(LYX_USE_EXTERNAL_LIBINTL)
 266         find_package(Libintl REQUIRED)
 267         add_definitions(-DHAVE_GETTEXT)
 268 endif()
 269
 270
 271 #TODO move to FindHunstall.cmake
 272 if(WIN32)
 273   find_library(HUNSPELL_LIBRARY "libhunspell")
 274 else()
 275   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 276   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 277 endif()
 278 if (HUNSPELL_LIBRARY)
 279   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 280 endif()
 281 if (HUNSPELL_FOUND)
 282   add_definitions(-DUSE_HUNSPELL=1)
 283   message(STATUS "Building with USE_HUNSPELL")
 284 else()
 285   message(STATUS "Hunspell not found, building without hunspell support")
 286 endif()
 287
 288
 289
 290 if(LYX_NLS)
 291         add_definitions(-DENABLE_NLS=1)
 292 endif()
 293
 294
 295 if(WIN32)
 296         if(LYX_NO_CONSOLE)
 297                 set(WIN32_CONSOLE WIN32)
 298                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 299         endif()
 300         if(MSVC)
 301                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 302                 # disable checked iterators for msvc release builds to get maximum speed
 303                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 304         else()
 305                 add_definitions(-DWINVER=0x0500)
 306         endif()
 307 endif()
 308
 309 message(STATUS "")
 310 foreach(_v PACKAGE PACKAGE_VERSION
 311     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 312     LYX_ABS_TOP_SRCDIR
 313     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 314   if(NOT DEFINED ${_v})
 315     message(FATAL_ERROR "${_v} not defined")
 316   endif()
 317   string(SUBSTRING "${_v}                            " 0 28 _v1)
 318   message(STATUS "----- ${_v1}: ${${_v}}")
 319 endforeach(_v)
 320 message(STATUS "")
 321
 322
 323 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 324 # Not sure if it works for all non-msvc compilers
 325 include(PCHSupport_26)
 326
 327 if(NOT LYX_DISABLE_PCH)
 328
 329         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 330         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 331         add_definitions(-DLYX_ENABLE_PCH)
 332
 333         if(MSVC AND NOT MERGE_FILES)
 334                 macro(lyx_add_msvc_pch name_)
 335                         set_source_files_properties(${${name_}_sources} PROPERTIES
 336                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 337                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 338                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 339                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 340                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 341                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 342                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 343                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 344                 endmacro(lyx_add_msvc_pch)
 345                 macro(lyx_add_gcc_pch name_)
 346                 endmacro()
 347         else()
 348                 macro(lyx_add_msvc_pch name_)
 349                 endmacro()
 350                 macro(lyx_add_gcc_pch name_)
 351                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 352                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 353                 endmacro()
 354         endif()
 355 else()
 356         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 357         macro(lyx_add_msvc_pch)
 358         endmacro(lyx_add_msvc_pch)
 359         macro(lyx_add_gcc_pch name_)
 360         endmacro()
 361 endif()
 362
 363 if(MSVC)
 364         if(LYX_VLD)
 365            set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 366            set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 367            set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 368            include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 369         endif()
 370
 371         # TODO options
 372         if(LYX_WALL)
 373                 # Use the highest warning level
 374                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 375
 376                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 377                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 378                 else()
 379                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 380                 endif()
 381
 382                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 383                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 384                 else()
 385                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 386                 endif()
 387
 388                 # add here warnings which should produce an error /weXXXX
 389                 set(MSVC_W_ERROR   "/we4101 /we4189")
 390                 # add here warnings which should be disabled /wdXXXX
 391                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 392
 393                 set(CMAKE_CXX_FLAGS_DEBUG
 394                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 395                 set(CMAKE_CXX_FLAGS_RELEASE
 396                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 397                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 398                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 399
 400         else()
 401                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 402
 403                 # add here warnings which should produce an error /weXXXX
 404                 set(MSVC_W_ERROR   "/we4101 /we4189")
 405                 # add here warnings which should be disabled /wdXXXX
 406                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 407
 408                 set(CMAKE_CXX_FLAGS_DEBUG
 409                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 410                 set(CMAKE_CXX_FLAGS_RELEASE
 411                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 412                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 413                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 414
 415         endif()
 416         set(CMAKE_CXX_FLAGS_DEBUG
 417                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 418         set(CMAKE_CXX_FLAGS_RELEASE
 419                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 420         set(CMAKE_CXX_FLAGS_MINSIZEREL
 421                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 422
 423         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 424         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 425         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 426         message(STATUS "")
 427
 428 endif()
 429
 430 FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 431 if( NOT ${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 432     if(LYX_NLS)
 433       find_package(LyXGettext REQUIRED)
 434       include_directories(${TOP_SRC_DIR}/po)
 435       add_subdirectory(po)
 436     endif()
 437 endif()
 438
 439 if(LYX_DEBUG_GLIBC)
 440   set(_GLIBCXX_DEBUG 1)
 441 endif()
 442
 443 if(LYX_DEBUG_GLIBC_PEDANTIC)
 444   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 445 endif()
 446
 447 # compiler tests, config.h generation
 448 if(MSVC AND NOT CONFIGURECHECKS)
 449         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 450 else()
 451         include(ConfigureChecks.cmake)
 452         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 453 endif()
 454
 455 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 456
 457 find_package(ICONV REQUIRED)
 458 add_definitions(-DHAVE_ICONV=1)
 459
 460
 461 include_directories(
 462   ${CMAKE_BINARY_DIR}
 463   ${TOP_SRC_DIR}/src)
 464
 465
 466 if(LYX_USE_EXTERNAL_BOOST)
 467   message(STATUS "Searching for boost")
 468   find_package(Boost COMPONENTS signals regex)
 469   if(Boost_FOUND)
 470     message(STATUS "Boost found")
 471     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 472     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 473   else()
 474     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 475   endif()
 476 else()
 477   if(LYX_USE_TR1_REGEX)
 478     set(Lyx_Boost_Libraries boost_signals)
 479   else()
 480     set(Lyx_Boost_Libraries boost_signals boost_regex)
 481   endif()
 482   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 483   include_directories(${TOP_SRC_DIR}/boost)
 484   add_subdirectory(boost)
 485 endif()
 486
 487
 488 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 489   add_subdirectory(intl)
 490 endif()
 491 add_subdirectory(src)
 492
 493 if(LYX_INSTALL)
 494         add_subdirectory(man)
 495         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 496         if(NOT ${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 497                 add_subdirectory(doc)
 498         endif()
 499 endif()
 500 add_subdirectory(lyx2lyx)
 501 add_subdirectory(scripts)
 502
 503 if(LYX_INSTALL)
 504         include(../Install)
 505 endif()
 506
 507 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 508 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 509 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 510
 511 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 512 #
 513 # needed by rpm
 514 SET(CPACK_SET_DESTDIR "ON")
 515 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 516 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 517 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 518 #
 519 # the next ones are needed by deb
 520 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 521 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 522
 523 # This is experimental, valid on _my_ system (Kornel)
 524 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 525 IF(ASPELL_FOUND)
 526   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 527 ENDIF()
 528 #
 529 # for the next ones, cpack insists on data with values in some file
 530 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 531 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 532
 533 # Find the revision number and use it as the release in rpm-package-build.
 534 # This way we may omit the otherwise needed "--force" parameter when
 535 # installing from that rpm package.
 536 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 537 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 538 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 539   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 540   # We use this value also to set the package-patch-value
 541   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 542     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 543   endif()
 544 endif()
 545
 546 # we do not have a readme or welcome data,
 547 # so we do not provide infofiles for
 548 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 549
 550 include(CPack)
 551
 552 #Now it is possible to create some packages
 553 # cd <BuildDir>
 554 # make package
 555 #############################################################################################
 556 # So, e.g. for variables
 557 #    CMAKE_PROJECT_NAME                     : lyx
 558 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 559 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 560 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 561 #    CMAKE_SYSTEM_NAME                      : Linux
 562 #    CPACK_BINARY_DEB:BOOL                  : ON
 563 #
 564 # the package name builds as "lyx-2.0.1-Linux.deb"
 565 #
 566 ############################## rpm ################################### deb ##################
 567 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 568 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 569 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 570 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 571 #
 572 message(STATUS)