development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif(COMMAND cmake_policy)
  15
  16 project(lyx)
  17
  18 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  19
  20 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  21 # is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  24 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  25
  26
  27 option(lyxinstall "Build install projects/rules" ON)
  28
  29
  30 if(UNIX)
  31     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  32     if(GCC_VERSION VERSION_GREATER 4.4)
  33         set(LYX_USE_TR1 1)
  34         # GCC <= 4.5 does not support regex: there are linker errors
  35         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  36         set(LYX_USE_TR1_REGEX 0)
  37     endif()
  38 else()
  39     if(MSVC10)
  40         set(LYX_USE_TR1 1)
  41         set(LYX_USE_TR1_REGEX 1)
  42     endif()
  43 endif()
  44
  45
  46
  47
  48
  49 # Supress regeneration
  50 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  51
  52 set(VERSION_INFO "CMake Build")
  53
  54 # Try to get some informations from configure.ac
  55
  56 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  57 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  58
  59 if(WIN32)
  60   set(USE_WINDOWS_PACKAGING 1)
  61 elseif(APPLE)
  62   set(USE_MACOSX_PACKAGING 1)
  63 else()
  64   set(USE_POSIX_PACKAGING 1)
  65 endif()
  66
  67 macro(setstripped _varname _value)
  68   string(STRIP ${_value} _v)
  69   if(USE_POSIX_PACKAGING)
  70     string(TOLOWER ${_v} ${_varname})
  71   else()
  72     set(${_varname} ${_v})
  73   endif()
  74 endmacro(setstripped)
  75
  76 foreach(_c_l ${_config_lines} )
  77   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  78     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  79     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  80     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  81     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  82       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  83       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  84       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  85       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  86       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  87     endif()
  88   endif()
  89   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  90     set(LYX_DATE "${CMAKE_MATCH_1}")
  91   endif()
  92 endforeach(_c_l)
  93
  94 if(UseVersionSuffix)
  95   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  96   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  97   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  98 else()
  99   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
 100   set(PACKAGE ${PACKAGE_BASE})
 101   set(PROGRAM_SUFFIX "")
 102 endif()
 103
 104 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 105   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 106   if (UNIX)
 107     # don't use the default "/usr/local"
 108     # but respect the user-choice on the command-line
 109     SET(CMAKE_INSTALL_PREFIX
 110       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 111   endif()
 112   if(WIN32)
 113     SET(CMAKE_INSTALL_PREFIX
 114       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
 115   endif()
 116 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 117
 118 if (WIN32)
 119   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 120 else()
 121   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 122 endif()
 123
 124 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 125 set(LYX_LOCALEDIR "locale")
 126 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 127 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 128
 129
 130 if(NOT GROUP_CODE)
 131         #set(GROUP_CODE "The Golden Code")
 132         set(GROUP_CODE flat)
 133 endif()
 134
 135 # lyx's source files
 136 set(LYX_CPP_FILES *.cpp)
 137 set(LYX_HPP_FILES *.h)
 138 set(LYX_MOC_FILES moc_*.cpp)
 139
 140 include(LyXMacros)
 141 include(ProjectSourceGroup)
 142
 143 if(merge OR merge_rebuild)
 144         set(merge 1 CACHE TYPE STRING FORCE)
 145         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 146         message(STATUS "")
 147         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 148         message(STATUS "")
 149         add_definitions(-DLYX_MERGED_BUILD)
 150 else()
 151         set(merge 0 CACHE TYPE STRING FORCE)
 152         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 153         message(STATUS "Enable merging files with -Dmerge=1")
 154 endif()
 155
 156
 157 set(CMAKE_BUILD_TYPE Release)
 158
 159 if(profile)
 160         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 161         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 162             CACHE TYPE STRING FORCE)
 163         set(profile)
 164 endif()
 165
 166 if(release)
 167         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 168         set(release TRUE CACHE TYPE STRING FORCE)
 169         set(release)
 170 endif()
 171
 172 if(debug)
 173         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 174         set(debug TRUE CACHE TYPE STRING FORCE)
 175         set(debug)
 176 endif()
 177
 178 if(shared)
 179         set(library_type SHARED)
 180         message(STATUS "building shared libraries")
 181 else()
 182         set(library_type STATIC)
 183 endif()
 184
 185 if(NOT MSVC)
 186         if(NOT quiet)
 187                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 188                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 189                 message(STATUS "")
 190         else()
 191                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 192         endif()
 193         set(LYX_CXX_FLAGS -Wall)
 194         if(stdlib-debug)
 195                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 196         endif()
 197         if(concept-checks)
 198                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 199         endif()
 200         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 201         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 202         if(MINGW)
 203                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 204         else()
 205                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 206         endif()
 207         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 208 endif()
 209
 210
 211 find_package(Qt4 REQUIRED)
 212 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 213
 214 find_package(ZLIB REQUIRED)
 215
 216 if(all OR aspell)
 217         set(aspell TRUE CACHE TYPE STRING)
 218         find_package(ASPELL REQUIRED)
 219 else()
 220         find_package(ASPELL)
 221 endif()
 222 set(aspell)
 223
 224 set(use_external_libintl TRUE)
 225
 226 if(use_external_libintl)
 227         find_package(Libintl REQUIRED)
 228         add_definitions(-DHAVE_GETTEXT)
 229 endif()
 230
 231 if(WIN32)
 232   find_library(HUNSPELL_LIBRARY "libhunspell")
 233 else()
 234   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 235   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 236 endif()
 237 if (HUNSPELL_LIBRARY)
 238   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 239 endif()
 240
 241 if (HUNSPELL_FOUND)
 242   add_definitions(-DUSE_HUNSPELL=1)
 243   message(STATUS "----- Building with USE_HUNSPELL")
 244 else()
 245   message(STATUS "----- Hunspell not found, building without hunspell support")
 246 endif()
 247
 248 if(WIN32)
 249   find_library(ENCHANT_LIBRARY "libenchant")
 250   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 251 else()
 252   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 253   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 254 endif()
 255 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 256   set(ENCHANT_FOUND TRUE)
 257   add_definitions(-DUSE_ENCHANT=1)
 258   message(STATUS "----- Building with USE_ENCHANT")
 259 else()
 260   message(STATUS "----- Enchant not found, building without enchant support")
 261 endif()
 262
 263 message(STATUS "")
 264 if(nls OR all)
 265         set(nls TRUE CACHE TYPE STRING)
 266         add_definitions(-DENABLE_NLS=1)
 267         message(STATUS "----- Building with ENABLE_NLS")
 268 else()
 269         message(STATUS "----- No nls, to enable use -Dnls=1")
 270 endif()
 271 set(nls)
 272 if(ASPELL_FOUND)
 273         add_definitions(-DUSE_ASPELL=1)
 274         message(STATUS "----- Building with USE_ASPELL")
 275 else()
 276         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 277 endif()
 278 set(all)
 279
 280 if(WIN32)
 281         if(noconsole)
 282                 set(noconsole TRUE CACHE TYPE STRING)
 283                 set(WIN32_CONSOLE WIN32)
 284                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 285                 message(STATUS "----- Console disabled")
 286         else()
 287                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 288         endif()
 289         if(MSVC)
 290                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 291                 # disable checked iterators for msvc release builds to get maximum speed
 292                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 293         else()
 294                 add_definitions(-DWINVER=0x0500)
 295         endif()
 296 endif()
 297
 298 message(STATUS "")
 299 foreach(_v PACKAGE PACKAGE_VERSION
 300     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 301     LYX_ABS_TOP_SRCDIR
 302     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 303   if(NOT DEFINED ${_v})
 304     message(FATAL_ERROR "${_v} not defined")
 305   endif()
 306   string(SUBSTRING "${_v}                            " 0 28 _v1)
 307   message(STATUS "----- ${_v1}: ${${_v}}")
 308 endforeach(_v)
 309 message(STATUS "")
 310
 311
 312 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 313 # Not sure if it works for all non-msvc compilers
 314 include(PCHSupport_26)
 315 if (MSVC)
 316         option(disable-pch "Disable precompiled headers" ON)
 317 else()
 318         option(disable-pch "Disable precompiled headers" ON)
 319 endif()
 320
 321 if(NOT disable-pch)
 322
 323         message(STATUS "-----")
 324         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 325         message(STATUS "-----")
 326         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 327         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 328         add_definitions(-DLYX_ENABLE_PCH)
 329
 330         if(MSVC AND NOT MERGE_FILES)
 331                 macro(lyx_add_msvc_pch name_)
 332                         set_source_files_properties(${${name_}_sources} PROPERTIES
 333                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 334                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 335                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 336                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 337                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 338                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 339                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 340                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 341                 endmacro(lyx_add_msvc_pch)
 342                 macro(lyx_add_gcc_pch name_)
 343                 endmacro()
 344         else()
 345                 macro(lyx_add_msvc_pch name_)
 346                 endmacro()
 347                 macro(lyx_add_gcc_pch name_)
 348                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 349                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 350                 endmacro()
 351         endif()
 352 else()
 353         if(MSVC)
 354                 message(STATUS "-----")
 355                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 356                 message(STATUS "-----")
 357         endif()
 358         set(disable-pch TRUE CACHE TYPE STRING)
 359         macro(lyx_add_msvc_pch)
 360         endmacro(lyx_add_msvc_pch)
 361         macro(lyx_add_gcc_pch name_)
 362         endmacro()
 363 endif()
 364
 365 if(MSVC)
 366        if(vld)
 367                set(vld 1 CACHE TYPE STRING FORCE)
 368                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 369                message(STATUS "")
 370                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 371                message(STATUS "")
 372                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 373                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 374                include(${vld_path}/tools/cmake/vld.cmake)
 375        else()
 376                set(vld 0 CACHE TYPE STRING FORCE)
 377                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 378                message(STATUS "")
 379                message(STATUS "Enable leak detection with -Dvld=1")
 380                message(STATUS "")
 381        endif()
 382
 383         if(WALL)
 384                 set(WALL 1 CACHE TYPE STRING FORCE)
 385
 386                 # Use the highest warning level
 387                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 388                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 389
 390                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 391                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 392                 else()
 393                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 394                 endif()
 395
 396                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 397                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 398                 else()
 399                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 400                 endif()
 401
 402                 # add here warnings which should produce an error /weXXXX
 403                 set(MSVC_W_ERROR   "/we4101 /we4189")
 404                 # add here warnings which should be disabled /wdXXXX
 405                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 406
 407                 set(CMAKE_CXX_FLAGS_DEBUG
 408                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 409                 set(CMAKE_CXX_FLAGS_RELEASE
 410                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 411                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 412                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 413
 414         else()
 415                 set(WALL 0 CACHE TYPE STRING FORCE)
 416
 417                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 418                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 419
 420                 # add here warnings which should produce an error /weXXXX
 421                 set(MSVC_W_ERROR   "/we4101 /we4189")
 422                 # add here warnings which should be disabled /wdXXXX
 423                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 424
 425                 set(CMAKE_CXX_FLAGS_DEBUG
 426                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 427                 set(CMAKE_CXX_FLAGS_RELEASE
 428                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 429                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 430                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 431
 432         endif()
 433         set(CMAKE_CXX_FLAGS_DEBUG
 434                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 435         set(CMAKE_CXX_FLAGS_RELEASE
 436                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 437         set(CMAKE_CXX_FLAGS_MINSIZEREL
 438                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 439
 440         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 441         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 442         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 443         message(STATUS "")
 444
 445 endif()
 446
 447
 448 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 449 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 450     if(nls OR all)
 451       find_package(LyXGettext REQUIRED)
 452       include_directories(${TOP_SRC_DIR}/po)
 453       add_subdirectory(po)
 454     endif()
 455 endif()
 456
 457 option(debug_glibc "Enable libstdc++ debug mode" OFF)
 458 option(debug_glibc_pedantic "Enable libstdc++pedantic debug mode" OFF)
 459
 460 if(debug_glibc)
 461   set(_GLIBCXX_DEBUG 1)
 462 endif()
 463
 464 if(debug_glibc_pedantic)
 465   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 466 endif()
 467
 468 # compiler tests, config.h generation
 469 if(MSVC AND NOT CONFIGURECHECKS)
 470         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 471 else()
 472         include(ConfigureChecks.cmake)
 473         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 474 endif()
 475
 476 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 477
 478 find_package(ICONV REQUIRED)
 479 add_definitions(-DHAVE_ICONV=1)
 480
 481
 482 include_directories(
 483   ${CMAKE_BINARY_DIR}
 484   ${TOP_SRC_DIR}/src)
 485
 486 option(UseExternalBoost "Use external boost" OFF)
 487 if(UseExternalBoost)
 488   message(STATUS "Searching for boost")
 489   find_package(Boost COMPONENTS signals regex)
 490   if(Boost_FOUND)
 491     message(STATUS "Boost found")
 492     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 493     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 494   else()
 495     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 496   endif()
 497 else()
 498   message(STATUS "----- Using internal boost. To build with installed version use -DUseExternalBoost:BOOL=ON")
 499   if(LYX_USE_TR1_REGEX)
 500     set(Lyx_Boost_Libraries boost_signals)
 501   else()
 502     set(Lyx_Boost_Libraries boost_signals boost_regex)
 503   endif()
 504   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 505   include_directories(${TOP_SRC_DIR}/boost)
 506   add_subdirectory(boost)
 507 endif()
 508
 509
 510 if(NOT use_external_libintl)
 511   add_subdirectory(intl)
 512 endif()
 513 add_subdirectory(src)
 514
 515 if(lyxinstall)
 516         add_subdirectory(man)
 517         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 518                 add_subdirectory(doc)
 519         endif()
 520 endif()
 521 add_subdirectory(lyx2lyx)
 522 add_subdirectory(scripts)
 523
 524 if(lyxinstall)
 525         include(../Install)
 526 endif()
 527
 528 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 529 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 530 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 531
 532 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 533 #
 534 # needed by rpm
 535 SET(CPACK_SET_DESTDIR "ON")
 536 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 537 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 538 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 539 #
 540 # the next ones are needed by deb
 541 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 542 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 543
 544 # This is experimental, valid on _my_ system (Kornel)
 545 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 546 IF(ASPELL_FOUND)
 547   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 548 ENDIF()
 549 #
 550 # for the next ones, cpack insists on data with values in some file
 551 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 552 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 553
 554 # Find the revision number and use it as the release in rpm-package-build.
 555 # This way we may omit the otherwise needed "--force" parameter when
 556 # installing from that rpm package.
 557 FIND_PROGRAM(_svnversion svnversion)
 558 message(STATUS "svnversion = ${_svnversion}")
 559 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 560   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 561   # We use this value also to set the package-patch-value
 562   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 563     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 564   endif()
 565 endif()
 566
 567 # we do not have a readme or welcome data,
 568 # so we do not provide infofiles for
 569 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 570
 571 if(lyxinstall)
 572         include(CPack)
 573 endif()
 574
 575 #Now it is possible to create some packages
 576 # cd <BuildDir>
 577 # make package
 578 #############################################################################################
 579 # So, e.g. for variables
 580 #    CMAKE_PROJECT_NAME                     : lyx
 581 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 582 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 583 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 584 #    CMAKE_SYSTEM_NAME                      : Linux
 585 #    CPACK_BINARY_DEB:BOOL                  : ON
 586 #
 587 # the package name builds as "lyx-2.0.1-Linux.deb"
 588 #
 589 ############################## rpm ################################### deb ##################
 590 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 591 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 592 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 593 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 594 #