development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 project(lyx)
  15
  16 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  17
  18 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  19 # is checked
  20 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  21 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  22
  23
  24 option(lyxinstall "Build install projects/rules" ON)
  25
  26
  27
  28 # Supress regeneration
  29 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  30
  31 set(VERSION_INFO "CMake Build")
  32
  33 # Try to get some informations from configure.ac
  34
  35 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  36 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  37
  38 if(WIN32)
  39   set(USE_WINDOWS_PACKAGING 1)
  40 elseif(APPLE)
  41   set(USE_MACOSX_PACKAGING 1)
  42 else()
  43   set(USE_POSIX_PACKAGING 1)
  44 endif()
  45
  46 macro(setstripped _varname _value)
  47   string(STRIP ${_value} _v)
  48   if(USE_POSIX_PACKAGING)
  49     string(TOLOWER ${_v} ${_varname})
  50   else()
  51     set(${_varname} ${_v})
  52   endif()
  53 endmacro(setstripped)
  54
  55 foreach(_c_l ${_config_lines} )
  56   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  57     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  58     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  59     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  60     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  61       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  62       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  63       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  64       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  65       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  66     endif()
  67   endif()
  68   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  69     set(LYX_DATE "${CMAKE_MATCH_1}")
  70   endif()
  71 endforeach(_c_l)
  72
  73 if(UseVersionSuffix)
  74   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  75   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  76   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  77 else()
  78   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
  79   set(PACKAGE ${PACKAGE_BASE})
  80   set(PROGRAM_SUFFIX "")
  81 endif()
  82
  83 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  84   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  85   if (UNIX)
  86     # don't use the default "/usr/local"
  87     # but respect the user-choice on the command-line
  88     SET(CMAKE_INSTALL_PREFIX
  89       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
  90   endif()
  91   if(WIN32)
  92     SET(CMAKE_INSTALL_PREFIX
  93       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
  94   endif()
  95 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  96
  97 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
  98 set(LYX_LOCALEDIR "locale")
  99 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
 100 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 101
 102
 103 if(NOT GROUP_CODE)
 104         #set(GROUP_CODE "The Golden Code")
 105         set(GROUP_CODE flat)
 106 endif()
 107
 108 # lyx's source files
 109 set(LYX_CPP_FILES *.cpp)
 110 set(LYX_HPP_FILES *.h)
 111 set(LYX_MOC_FILES moc_*.cpp)
 112
 113 include(LyXMacros)
 114 include(ProjectSourceGroup)
 115
 116 if(merge OR merge_rebuild)
 117         set(merge 1 CACHE TYPE STRING FORCE)
 118         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 119         message(STATUS "")
 120         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 121         message(STATUS "")
 122 else()
 123         set(merge 0 CACHE TYPE STRING FORCE)
 124         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 125         message(STATUS "Enable merging files with -Dmerge=1")
 126 endif()
 127
 128
 129 set(CMAKE_BUILD_TYPE Release)
 130
 131 if(profile)
 132         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 133         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 134             CACHE TYPE STRING FORCE)
 135         set(profile)
 136 endif()
 137
 138 if(release)
 139         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 140         set(release TRUE CACHE TYPE STRING FORCE)
 141         set(release)
 142 endif()
 143
 144 if(debug)
 145         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 146         set(debug TRUE CACHE TYPE STRING FORCE)
 147         set(debug)
 148 endif()
 149
 150 if(shared)
 151         set(library_type SHARED)
 152         message(STATUS "building shared libraries")
 153 else()
 154         set(library_type STATIC)
 155 endif()
 156
 157 if(NOT MSVC)
 158         if(NOT quiet)
 159                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 160                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 161                 message(STATUS "")
 162         else()
 163                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 164         endif()
 165         set(LYX_CXX_FLAGS -Wall)
 166         if(stdlib-debug)
 167                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 168         endif()
 169         if(concept-checks)
 170                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 171         endif()
 172         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 173         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 174         if(MINGW)
 175                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 176         else()
 177                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 178         endif()
 179         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 180 endif()
 181
 182
 183 find_package(Qt4 REQUIRED)
 184 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 185
 186 find_package(ZLIB REQUIRED)
 187
 188 if(all OR aspell)
 189         set(aspell TRUE CACHE TYPE STRING)
 190         find_package(ASPELL REQUIRED)
 191 else()
 192         find_package(ASPELL)
 193 endif()
 194 set(aspell)
 195
 196 set(use_external_libintl TRUE)
 197
 198 if(use_external_libintl)
 199         find_package(Libintl REQUIRED)
 200         add_definitions(-DHAVE_GETTEXT)
 201 endif()
 202
 203 if(WIN32)
 204   find_library(HUNSPELL_LIBRARY "libhunspell")
 205 else()
 206   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 207   find_library(HUNSPELL_LIBRARY "hunspell" "/usr/local/lib" "/usr/lib")
 208 endif()
 209 if (HUNSPELL_LIBRARY)
 210   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 211 endif()
 212
 213 if (HUNSPELL_FOUND)
 214   add_definitions(-DUSE_HUNSPELL=1)
 215   message(STATUS "----- Building with USE_HUNSPELL")
 216 else()
 217   message(STATUS "----- Hunspell not found, building without hunspell support")
 218 endif()
 219
 220 if(WIN32)
 221   find_library(ENCHANT_LIBRARY "libenchant")
 222   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 223 else()
 224   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib")
 225   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant)
 226 endif()
 227 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 228   set(ENCHANT_FOUND TRUE)
 229   add_definitions(-DUSE_ENCHANT=1)
 230   message(STATUS "----- Building with USE_ENCHANT")
 231 else()
 232   message(STATUS "----- Enchant not found, building without enchant support")
 233 endif()
 234
 235 message(STATUS "")
 236 if(nls OR all)
 237         set(nls TRUE CACHE TYPE STRING)
 238         add_definitions(-DENABLE_NLS=1)
 239         message(STATUS "----- Building with ENABLE_NLS")
 240 else()
 241         message(STATUS "----- No nls, to enable use -Dnls=1")
 242 endif()
 243 set(nls)
 244 if(ASPELL_FOUND)
 245         add_definitions(-DUSE_ASPELL=1)
 246         message(STATUS "----- Building with USE_ASPELL")
 247 else()
 248         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 249 endif()
 250 set(all)
 251
 252 if(WIN32)
 253         if(noconsole)
 254                 set(noconsole TRUE CACHE TYPE STRING)
 255                 set(WIN32_CONSOLE WIN32)
 256                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 257                 message(STATUS "----- Console disabled")
 258         else()
 259                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 260         endif()
 261         if(MSVC)
 262                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 263                 # disable checked iterators for msvc release builds to get maximum speed
 264                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 265         else()
 266                 add_definitions(-DWINVER=0x0500)
 267         endif()
 268 endif()
 269
 270 message(STATUS "")
 271 foreach(_v PACKAGE PACKAGE_VERSION
 272     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 273     LYX_ABS_TOP_SRCDIR
 274     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 275   if(NOT DEFINED ${_v})
 276     message(FATAL_ERROR "${_v} not defined")
 277   endif()
 278   string(SUBSTRING "${_v}                            " 0 28 _v1)
 279   message(STATUS "----- ${_v1}: ${${_v}}")
 280 endforeach(_v)
 281 message(STATUS "")
 282
 283
 284 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 285 # Not sure if it works for all non-msvc compilers
 286 include(PCHSupport_26)
 287 if (MSVC)
 288         option(disable-pch "Disable precompiled headers" OFF)
 289 else()
 290         option(disable-pch "Disable precompiled headers" ON)
 291 endif()
 292
 293 if(NOT disable-pch)
 294
 295         message(STATUS "-----")
 296         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 297         message(STATUS "-----")
 298         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 299         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 300         add_definitions(-DLYX_ENABLE_PCH)
 301
 302         if(MSVC AND NOT MERGE_FILES)
 303                 macro(lyx_add_msvc_pch name_)
 304                         set_source_files_properties(${${name_}_sources} PROPERTIES
 305                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 306                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 307                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 308                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 309                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 310                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 311                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 312                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 313                 endmacro(lyx_add_msvc_pch)
 314                 macro(lyx_add_gcc_pch name_)
 315                 endmacro()
 316         else()
 317                 macro(lyx_add_msvc_pch name_)
 318                 endmacro()
 319                 macro(lyx_add_gcc_pch name_)
 320                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 321                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 322                 endmacro()
 323         endif()
 324 else()
 325         if(MSVC)
 326                 message(STATUS "-----")
 327                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 328                 message(STATUS "-----")
 329         endif()
 330         set(disable-pch TRUE CACHE TYPE STRING)
 331         macro(lyx_add_msvc_pch)
 332         endmacro(lyx_add_msvc_pch)
 333         macro(lyx_add_gcc_pch name_)
 334         endmacro()
 335 endif()
 336
 337 if(MSVC)
 338        if(vld)
 339                set(vld 1 CACHE TYPE STRING FORCE)
 340                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 341                message(STATUS "")
 342                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 343                message(STATUS "")
 344                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 345                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 346                include(${vld_path}/tools/cmake/vld.cmake)
 347        else()
 348                set(vld 0 CACHE TYPE STRING FORCE)
 349                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 350                message(STATUS "")
 351                message(STATUS "Enable leak detection with -Dvld=1")
 352                message(STATUS "")
 353        endif()
 354
 355         if(WALL)
 356                 set(WALL 1 CACHE TYPE STRING FORCE)
 357
 358                 # Use the highest warning level
 359                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 360                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 361
 362                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 363                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 364                 else()
 365                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 366                 endif()
 367
 368                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 369                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 370                 else()
 371                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 372                 endif()
 373
 374                 # add here warnings which should produce an error /weXXXX
 375                 set(MSVC_W_ERROR   "/we4101 /we4189")
 376                 # add here warnings which should be disabled /wdXXXX
 377                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 378
 379                 set(CMAKE_CXX_FLAGS_DEBUG
 380                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 381                 set(CMAKE_CXX_FLAGS_RELEASE
 382                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 383                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 384                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 385
 386         else()
 387                 set(WALL 0 CACHE TYPE STRING FORCE)
 388
 389                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 390                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 391
 392                 # add here warnings which should produce an error /weXXXX
 393                 set(MSVC_W_ERROR   "/we4101 /we4189")
 394                 # add here warnings which should be disabled /wdXXXX
 395                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 396
 397                 set(CMAKE_CXX_FLAGS_DEBUG
 398                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 399                 set(CMAKE_CXX_FLAGS_RELEASE
 400                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 401                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 402                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 403
 404         endif()
 405
 406         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 407         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 408         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 409         message(STATUS "")
 410
 411 endif()
 412
 413
 414 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 415 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 416     if(nls OR all)
 417       find_package(LyXGettext REQUIRED)
 418       include_directories(${TOP_SRC_DIR}/po)
 419       add_subdirectory(po)
 420     endif()
 421 endif()
 422
 423 # compiler tests, config.h generation
 424 if(MSVC AND NOT CONFIGURECHECKS)
 425         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 426 else()
 427         include(ConfigureChecks.cmake)
 428         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 429 endif()
 430
 431 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 432
 433 find_package(ICONV REQUIRED)
 434 add_definitions(-DHAVE_ICONV=1)
 435
 436
 437 include_directories(
 438   ${CMAKE_BINARY_DIR}
 439   ${TOP_SRC_DIR}/src)
 440
 441 option(UseExternalBoost "Use external boost" OFF)
 442 if(UseExternalBoost)
 443   message(STATUS "Searching for boost")
 444   find_package(Boost COMPONENTS signals regex)
 445   if(Boost_FOUND)
 446     message(STATUS "Boost found")
 447     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 448     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 449   else()
 450     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 451   endif()
 452 else()
 453   message(STATUS "----- Using internal boost. To build with installed version use -DUseExternalBoost:BOOL=ON")
 454   set(Lyx_Boost_Libraries boost_signals boost_regex)
 455   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 456   include_directories(${TOP_SRC_DIR}/boost)
 457   add_subdirectory(boost)
 458 endif()
 459
 460
 461 if(NOT use_external_libintl)
 462   add_subdirectory(intl)
 463 endif()
 464 add_subdirectory(src)
 465
 466 if(lyxinstall)
 467         add_subdirectory(man)
 468         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 469                 add_subdirectory(doc)
 470         endif()
 471 endif()
 472 add_subdirectory(lyx2lyx)
 473 add_subdirectory(scripts)
 474
 475 if(lyxinstall)
 476         include(../Install)
 477 endif()
 478
 479 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 480 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 481 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 482
 483 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 484 #
 485 # needed by rpm
 486 SET(CPACK_SET_DESTDIR "ON")
 487 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 488 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 489 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 490 #
 491 # the next ones are needed by deb
 492 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 493 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 494
 495 # This is experimental, valid on _my_ system (Kornel)
 496 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 497 IF(ASPELL_FOUND)
 498   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 499 ENDIF()
 500 #
 501 # for the next ones, cpack insists on data with values in some file
 502 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 503 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 504
 505 # Find the revision number and use it as the release in rpm-package-build.
 506 # This way we may omit the otherwise needed "--force" parameter when
 507 # installing from that rpm package.
 508 FIND_PROGRAM(_svnversion svnversion)
 509 message(STATUS "svnversion = ${_svnversion}")
 510 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 511   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 512   # We use this value also to set the package-patch-value
 513   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 514     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 515   endif()
 516 endif()
 517
 518 # we do not have a readme or welcome data,
 519 # so we do not provide infofiles for
 520 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 521
 522 if(lyxinstall)
 523         include(CPack)
 524 endif()
 525
 526 #Now it is possible to create some packages
 527 # cd <BuildDir>
 528 # make package
 529 #############################################################################################
 530 # So, e.g. for variables
 531 #    CMAKE_PROJECT_NAME                     : lyx
 532 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 533 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 534 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 535 #    CMAKE_SYSTEM_NAME                      : Linux
 536 #    CPACK_BINARY_DEB:BOOL                  : ON
 537 #
 538 # the package name builds as "lyx-2.0.1-Linux.deb"
 539 #
 540 ############################## rpm ################################### deb ##################
 541 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 542 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 543 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 544 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 545 #