development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  15
  16 project(lyx)
  17
  18 option(lyxinstall "Build install projects/rules" ON)
  19
  20 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  21 # is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  24
  25 # Supress regeneration
  26 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  27
  28 set(VERSION_INFO "CMake Build")
  29
  30 # Try to get some informations from configure.ac
  31
  32 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  33 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  34
  35 if(WIN32)
  36   set(USE_WINDOWS_PACKAGING 1)
  37 elseif(APPLE)
  38   set(USE_MACOSX_PACKAGING 1)
  39 else()
  40   set(USE_POSIX_PACKAGING 1)
  41 endif()
  42
  43 macro(setstripped _varname _value)
  44   string(STRIP ${_value} _v)
  45   if(USE_POSIX_PACKAGING)
  46     string(TOLOWER ${_v} ${_varname})
  47   else()
  48     set(${_varname} ${_v})
  49   endif()
  50 endmacro(setstripped)
  51
  52 foreach(_c_l ${_config_lines} )
  53   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  54     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  55     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  56     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  57     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  58       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  59       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  60       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  61       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  62       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  63     endif()
  64   endif()
  65   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  66     set(LYX_DATE "${CMAKE_MATCH_1}")
  67   endif()
  68 endforeach(_c_l)
  69
  70 if(UseVersionSuffix)
  71   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  72   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  73   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  74 else()
  75   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
  76   set(PACKAGE ${PACKAGE_BASE})
  77   set(PROGRAM_SUFFIX "")
  78 endif()
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  81   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  82   if (UNIX)
  83     # don't use the default "/usr/local"
  84     # but respect the user-choice on the command-line
  85     SET(CMAKE_INSTALL_PREFIX
  86       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
  87   endif()
  88   if(WIN32)
  89     SET(CMAKE_INSTALL_PREFIX
  90       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
  91   endif()
  92 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  93
  94 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
  95 set(LYX_LOCALEDIR "locale")
  96 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
  97 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
  98
  99
 100 if(NOT GROUP_CODE)
 101         #set(GROUP_CODE "The Golden Code")
 102         set(GROUP_CODE flat)
 103 endif()
 104
 105 # lyx's source files
 106 set(LYX_CPP_FILES *.cpp)
 107 set(LYX_HPP_FILES *.h)
 108
 109 include(LyXMacros)
 110 include(ProjectSourceGroup)
 111
 112 if(merge OR merge_rebuild)
 113         set(merge 1 CACHE TYPE STRING FORCE)
 114         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 115         message(STATUS "")
 116         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 117         message(STATUS "")
 118 else()
 119         set(merge 0 CACHE TYPE STRING FORCE)
 120         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 121         message(STATUS "Enable merging files with -Dmerge=1")
 122 endif()
 123
 124
 125 set(CMAKE_BUILD_TYPE Release)
 126
 127 if(profile)
 128         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 129         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 130             CACHE TYPE STRING FORCE)
 131         set(profile)
 132 endif()
 133
 134 if(release)
 135         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 136         set(release TRUE CACHE TYPE STRING FORCE)
 137         set(release)
 138 endif()
 139
 140 if(debug)
 141         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 142         set(debug TRUE CACHE TYPE STRING FORCE)
 143         set(debug)
 144 endif()
 145
 146 if(shared)
 147         set(library_type SHARED)
 148         message(STATUS "building shared libraries")
 149 else()
 150         set(library_type STATIC)
 151 endif()
 152
 153 if(NOT MSVC)
 154         if(NOT quiet)
 155                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 156                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 157                 message(STATUS "")
 158         else()
 159                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 160         endif()
 161         set(LYX_CXX_FLAGS -Wall)
 162         if(stdlib-debug)
 163                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 164         endif()
 165         if(concept-checks)
 166                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 167         endif()
 168         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 169         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 170         if(MINGW)
 171                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 172         else()
 173                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 174         endif()
 175         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 176 endif()
 177
 178
 179 find_package(Qt4 REQUIRED)
 180 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 181
 182 find_package(ZLIB REQUIRED)
 183
 184 if(all OR aspell)
 185         set(aspell TRUE CACHE TYPE STRING)
 186         find_package(ASPELL REQUIRED)
 187 else()
 188         find_package(ASPELL)
 189 endif()
 190 set(aspell)
 191
 192 set(use_external_libintl TRUE)
 193
 194 if(use_external_libintl)
 195         find_package(Libintl REQUIRED)
 196         add_definitions(-DHAVE_GETTEXT)
 197 endif()
 198
 199 if(WIN32)
 200   find_library(HUNSPELL_LIBRARY "libhunspell")
 201 else()
 202   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 203   find_library(HUNSPELL_LIBRARY "hunspell" "/usr/local/lib" "/usr/lib")
 204 endif()
 205 if (HUNSPELL_LIBRARY)
 206   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 207 endif()
 208
 209 if (HUNSPELL_FOUND)
 210   add_definitions(-DUSE_HUNSPELL=1)
 211   message(STATUS "----- Building with USE_HUNSPELL")
 212 else()
 213   message(STATUS "----- Hunspell not found, building without hunspell support")
 214 endif()
 215
 216 message(STATUS "")
 217 if(nls OR all)
 218         set(nls TRUE CACHE TYPE STRING)
 219         add_definitions(-DENABLE_NLS=1)
 220         message(STATUS "----- Building with ENABLE_NLS")
 221 else()
 222         message(STATUS "----- No nls, to enable use -Dnls=1")
 223 endif()
 224 set(nls)
 225 if(ASPELL_FOUND)
 226         add_definitions(-DUSE_ASPELL=1)
 227         message(STATUS "----- Building with USE_ASPELL")
 228 else()
 229         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 230 endif()
 231 set(all)
 232
 233 if(WIN32)
 234         if(noconsole)
 235                 set(noconsole TRUE CACHE TYPE STRING)
 236                 set(WIN32_CONSOLE WIN32)
 237                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 238                 message(STATUS "----- Console disabled")
 239         else()
 240                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 241         endif()
 242         if(MSVC)
 243                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 244                 # disable checked iterators for msvc release builds to get maximum speed
 245                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 246         else()
 247                 add_definitions(-DWINVER=0x0500)
 248         endif()
 249 endif()
 250
 251 message(STATUS "")
 252 foreach(_v PACKAGE PACKAGE_VERSION
 253     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 254     LYX_ABS_TOP_SRCDIR
 255     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 256   if(NOT DEFINED ${_v})
 257     message(FATAL_ERROR "${_v} not defined")
 258   endif()
 259   string(SUBSTRING "${_v}                            " 0 28 _v1)
 260   message(STATUS "----- ${_v1}: ${${_v}}")
 261 endforeach(_v)
 262 message(STATUS "")
 263
 264
 265 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 266         message(STATUS "-----")
 267         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 268         message(STATUS "-----")
 269         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 270                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 271         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 272                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 273         macro(lyx_add_msvc_pch name_)
 274                 set_source_files_properties(${${name_}_sources} PROPERTIES
 275                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 276                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 277                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 278                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 279                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 280                 add_definitions(/DLYX_ENABLE_PCH)
 281         endmacro(lyx_add_msvc_pch)
 282         set(CMAKE_CXX_FLAGS_DEBUG
 283                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 284         set(CMAKE_CXX_FLAGS_RELEASE
 285                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 286         set(CMAKE_CXX_FLAGS_MINSIZEREL
 287                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 288 else()
 289         if(MSVC)
 290                 message(STATUS "-----")
 291                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 292                 message(STATUS "-----")
 293         endif()
 294         set(disable-pch TRUE CACHE TYPE STRING)
 295         macro(lyx_add_msvc_pch)
 296         endmacro(lyx_add_msvc_pch)
 297 endif()
 298
 299 if(MSVC)
 300        if(vld)
 301                set(vld 1 CACHE TYPE STRING FORCE)
 302                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 303                message(STATUS "")
 304                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 305                message(STATUS "")
 306                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 307                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 308                include(${vld_path}/tools/cmake/vld.cmake)
 309        else()
 310                set(vld 0 CACHE TYPE STRING FORCE)
 311                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 312                message(STATUS "")
 313                message(STATUS "Enable leak detection with -Dvld=1")
 314                message(STATUS "")
 315        endif()
 316
 317         if(WALL)
 318                 set(WALL 1 CACHE TYPE STRING FORCE)
 319
 320                 # Use the highest warning level
 321                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 322                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 323
 324                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 325                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 326                 else()
 327                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 328                 endif()
 329
 330                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 331                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 332                 else()
 333                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 334                 endif()
 335
 336                 # add here warnings which should produce an error /weXXXX
 337                 set(MSVC_W_ERROR   "/we4101 /we4189")
 338                 # add here warnings which should be disabled /wdXXXX
 339                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 340
 341                 set(CMAKE_CXX_FLAGS_DEBUG
 342                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 343                 set(CMAKE_CXX_FLAGS_RELEASE
 344                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 345                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 346                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 347
 348         else()
 349                 set(WALL 0 CACHE TYPE STRING FORCE)
 350
 351                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 352                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 353
 354                 # add here warnings which should produce an error /weXXXX
 355                 set(MSVC_W_ERROR   "/we4101 /we4189")
 356                 # add here warnings which should be disabled /wdXXXX
 357                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 358
 359                 set(CMAKE_CXX_FLAGS_DEBUG
 360                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 361                 set(CMAKE_CXX_FLAGS_RELEASE
 362                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 363                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 364                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 365
 366         endif()
 367
 368         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 369         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 370         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 371         message(STATUS "")
 372
 373 endif()
 374
 375
 376 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 377 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 378     if(nls OR all)
 379       find_package(LyXGettext REQUIRED)
 380       include_directories(${TOP_SRC_DIR}/po)
 381       add_subdirectory(po)
 382     endif()
 383 endif()
 384
 385 # compiler tests, config.h generation
 386 if(MSVC AND NOT CONFIGURECHECKS)
 387         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 388 else()
 389         include(ConfigureChecks.cmake)
 390         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 391 endif()
 392
 393 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 394
 395 find_package(ICONV REQUIRED)
 396 add_definitions(-DHAVE_ICONV=1)
 397
 398
 399 include_directories(
 400   ${CMAKE_BINARY_DIR}
 401   ${TOP_SRC_DIR}/src)
 402
 403 option(UseExternalBoost "Use external boost" OFF)
 404 if(UseExternalBoost)
 405   message(STATUS "Searching for boost")
 406   find_package(Boost COMPONENTS signals regex)
 407   if(Boost_FOUND)
 408     message(STATUS "Boost found")
 409     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 410     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 411   else()
 412     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 413   endif()
 414 else()
 415   message(STATUS "----- Using internal boost. To build with installed version use -DUseExternalBoost:BOOL=ON")
 416   set(Lyx_Boost_Libraries boost_signals boost_regex)
 417   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 418   include_directories(${TOP_SRC_DIR}/boost)
 419   add_subdirectory(boost)
 420 endif()
 421
 422
 423 if(NOT use_external_libintl)
 424   add_subdirectory(intl)
 425 endif()
 426 add_subdirectory(src)
 427
 428 if(lyxinstall)
 429         add_subdirectory(man)
 430         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 431                 add_subdirectory(doc)
 432         endif()
 433 endif()
 434 add_subdirectory(lyx2lyx)
 435 add_subdirectory(scripts)
 436
 437 if(lyxinstall)
 438         include(../Install)
 439 endif()
 440
 441 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 442 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 443 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 444
 445 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 446 #
 447 # needed by rpm
 448 SET(CPACK_SET_DESTDIR "ON")
 449 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 450 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 451 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 452 #
 453 # the next ones are needed by deb
 454 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 455 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 456
 457 # This is experimental, valid on _my_ system (Kornel)
 458 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 459 IF(ASPELL_FOUND)
 460   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 461 ENDIF()
 462 #
 463 # for the next ones, cpack insists on data with values in some file
 464 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 465 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 466
 467 # Find the revision number and use it as the release in rpm-package-build.
 468 # This way we may omit the otherwise needed "--force" parameter when
 469 # installing from that rpm package.
 470 FIND_PROGRAM(_svnversion svnversion)
 471 message(STATUS "svnversion = ${_svnversion}")
 472 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 473   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 474   # We use this value also to set the package-patch-value
 475   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 476     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 477   endif()
 478 endif()
 479
 480 # we do not have a readme or welcome data,
 481 # so we do not provide infofiles for
 482 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 483
 484 if(lyxinstall)
 485         include(CPack)
 486 endif()
 487
 488 #Now it is possible to create some packages
 489 # cd <BuildDir>
 490 # make package
 491 #############################################################################################
 492 # So, e.g. for variables
 493 #    CMAKE_PROJECT_NAME                     : lyx
 494 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 495 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 496 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 497 #    CMAKE_SYSTEM_NAME                      : Linux
 498 #    CPACK_BINARY_DEB:BOOL                  : ON
 499 #
 500 # the package name builds as "lyx-2.0.1-Linux.deb"
 501 #
 502 ############################## rpm ################################### deb ##################
 503 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 504 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 505 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 506 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 507 #