development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26
  27 # Usage LYX_OPTION
  28 # 1. parameter: option name without prefix 'LYX_'
  29 # 2. parameter: description
  30 # 3. parameter: default value, ON or OFF
  31 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  32 message(STATUS)
  33 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  34 message(STATUS)
  35
  36 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  37 if(LYX_CPACK)
  38         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  39 endif()
  40
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 if(LYX_INSTALL)
  43         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  44         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  45         if (WIN32)
  46                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  47         endif()
  48         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  49         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  50         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  51         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  52         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  53 endif()
  54
  55 LYX_OPTION(NLS "Use nls" OFF ALL)
  56 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  57 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  58 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  59 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  60 LYX_OPTION(RELEASE "Build release version" ON ALL)
  61 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  62 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  63 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  64 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  65 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  66 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  67 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  68 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  69 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  70 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  71 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  72 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  73 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  74 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  75 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  76 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  77 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  78
  79 message(STATUS)
  80
  81 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  82 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  83
  84
  85
  86 if(UNIX OR MINGW)
  87     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  88     message(STATUS "Using GCC version ${GCC_VERSION}")
  89     if(NOT GCC_VERSION VERSION_LESS 4.4)
  90         set(LYX_USE_TR1 1)
  91         # GCC <= 4.5 does not support regex: there are linker errors
  92         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  93         set(LYX_USE_TR1_REGEX 0)
  94     endif()
  95 else()
  96     if(MSVC10)
  97         set(LYX_USE_TR1 1)
  98         set(LYX_USE_TR1_REGEX 1)
  99     endif()
 100 endif()
 101
 102
 103
 104 # Supress regeneration
 105 set(CMAKE_SUPPRESS_REGENERATION TRUE)
 106
 107 set(VERSION_INFO "CMake Build")
 108
 109 # Try to get some informations from configure.ac
 110
 111 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
 112 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 113
 114 if(WIN32)
 115   set(USE_WINDOWS_PACKAGING 1)
 116 elseif(APPLE)
 117   set(USE_MACOSX_PACKAGING 1)
 118 else()
 119   set(USE_POSIX_PACKAGING 1)
 120 endif()
 121
 122 macro(setstripped _varname _value)
 123   string(STRIP ${_value} _v)
 124   if(USE_POSIX_PACKAGING)
 125     string(TOLOWER ${_v} ${_varname})
 126   else()
 127     set(${_varname} ${_v})
 128   endif()
 129 endmacro(setstripped)
 130
 131 foreach(_c_l ${_config_lines} )
 132   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 133     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 134     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 135     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 136     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 137       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 138       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 139       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 140       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 141       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 142     endif()
 143   endif()
 144   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 145     set(LYX_DATE "${CMAKE_MATCH_1}")
 146   endif()
 147 endforeach(_c_l)
 148
 149
 150 if (LYX_INSTALL_PREFIX)
 151         set(CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 152         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 153 endif()
 154
 155 if(LYX_PACKAGE_SUFFIX)
 156   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 157 else()
 158   set(PACKAGE ${PACKAGE_BASE})
 159 endif()
 160
 161 if(LYX_PROGRAM_SUFFIX)
 162   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 163 else()
 164   set(PROGRAM_SUFFIX "")
 165 endif()
 166
 167
 168 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 169   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 170   if (UNIX)
 171     # don't use the default "/usr/local"
 172     # but respect the user-choice on the command-line
 173     if(LYX_INSTALL_SUFFIX)
 174         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 175     else()
 176         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 177     endif()
 178   endif()
 179   if(WIN32)
 180     SET(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 181   endif()
 182 endif()
 183
 184 if (WIN32)
 185   set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 186 else()
 187   set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 188 endif()
 189
 190 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 191 set(LYX_LOCALEDIR "locale")
 192 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 193 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 194
 195
 196 if(NOT GROUP_CODE)
 197         #set(GROUP_CODE "The Golden Code")
 198         set(GROUP_CODE flat)
 199 endif()
 200
 201 # lyx's source files
 202 set(LYX_CPP_FILES *.cpp)
 203 set(LYX_HPP_FILES *.h)
 204 set(LYX_MOC_FILES moc_*.cpp)
 205
 206
 207 include(ProjectSourceGroup)
 208
 209
 210 if(LYX_PROFILE)
 211         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 212         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 213 endif()
 214
 215 if(LYX_RELEASE)
 216         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 217 endif()
 218
 219 if(LYX_DEBUG)
 220         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 221 endif()
 222
 223
 224
 225 if(LYX_SHARED_LIBRARIES)
 226         set(library_type SHARED)
 227 else()
 228         set(library_type STATIC)
 229 endif()
 230
 231 if(NOT MSVC)
 232         if(NOT LYX_QUIET)
 233                 set(CMAKE_VERBOSE_MAKEFILE ON)
 234         endif()
 235         set(LYX_CXX_FLAGS -Wall)
 236         if(LYX_STDLIB_DEBUG)
 237                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 238         endif()
 239         if(LYX_CONCEPT_CHECKS)
 240                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 241         endif()
 242         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 243         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 244         if(MINGW)
 245                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 246         else()
 247                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 248         endif()
 249         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 250 endif()
 251
 252
 253 find_package(Qt4 REQUIRED)
 254 find_package(ICONV REQUIRED)
 255 find_package(ZLIB REQUIRED)
 256
 257 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 258
 259 if(LYX_ASPELL)
 260         find_package(ASPELL)
 261         include_directories(${ASPELL_INCLUDE_DIR})
 262 endif()
 263
 264 if(LYX_ENCHANT)
 265         find_package(Enchant REQUIRED)
 266         include_directories(${ENCHANT_INCLUDE_DIR})
 267 endif()
 268
 269 if(LYX_HUNSPELL)
 270         find_package(Hunspell REQUIRED)
 271         include_directories(${HUNSPELL_INCLUDE_DIR})
 272 endif()
 273
 274 if(LYX_NLS)
 275         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 276         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 277                 message(FATAL_ERROR "Python 2.6 needed!")
 278         endif()
 279         find_package(LyXGettext REQUIRED)
 280         include_directories(${TOP_SRC_DIR}/po)
 281         add_subdirectory(po)
 282 endif()
 283
 284 if(LYX_USE_EXTERNAL_LIBINTL)
 285         find_package(Libintl REQUIRED)
 286         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 287 else()
 288         add_subdirectory(intl)
 289 endif()
 290
 291 if(LYX_USE_EXTERNAL_BOOST)
 292         message(STATUS "Searching for boost")
 293         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 294         if(Boost_FOUND)
 295                 message(STATUS "Boost found")
 296                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 297                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 298         else()
 299                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 300         endif()
 301 else()
 302         if(LYX_USE_TR1_REGEX)
 303                 set(Lyx_Boost_Libraries boost_signals)
 304         else()
 305                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 306         endif()
 307         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 308         include_directories(${TOP_SRC_DIR}/boost)
 309         add_subdirectory(boost)
 310 endif()
 311
 312
 313
 314
 315 if(WIN32)
 316         if(LYX_NO_CONSOLE)
 317                 set(WIN32_CONSOLE WIN32)
 318                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 319         endif()
 320         if(MSVC)
 321                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 322                 # disable checked iterators for msvc release builds to get maximum speed
 323                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 324         else()
 325                 add_definitions(-DWINVER=0x0500)
 326         endif()
 327 endif()
 328
 329 message(STATUS "")
 330 foreach(_v PACKAGE PACKAGE_VERSION
 331     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 332     LYX_ABS_TOP_SRCDIR
 333     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 334   if(NOT DEFINED ${_v})
 335     message(FATAL_ERROR "${_v} not defined")
 336   endif()
 337   string(SUBSTRING "${_v}                            " 0 28 _v1)
 338   message(STATUS "----- ${_v1}: ${${_v}}")
 339 endforeach(_v)
 340 message(STATUS "")
 341
 342
 343 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 344 # Not sure if it works for all non-msvc compilers
 345 include(PCHSupport_26)
 346
 347 if(NOT LYX_DISABLE_PCH)
 348
 349         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 350         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 351         add_definitions(-DLYX_ENABLE_PCH)
 352
 353         if(MSVC AND NOT MERGE_FILES)
 354                 macro(lyx_add_msvc_pch name_)
 355                         set_source_files_properties(${${name_}_sources} PROPERTIES
 356                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 357                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 358                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 359                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 360                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 361                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 362                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 363                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 364                 endmacro(lyx_add_msvc_pch)
 365                 macro(lyx_add_gcc_pch name_)
 366                 endmacro()
 367         else()
 368                 macro(lyx_add_msvc_pch name_)
 369                 endmacro()
 370                 macro(lyx_add_gcc_pch name_)
 371                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 372                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 373                 endmacro()
 374         endif()
 375 else()
 376         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 377         macro(lyx_add_msvc_pch)
 378         endmacro(lyx_add_msvc_pch)
 379         macro(lyx_add_gcc_pch name_)
 380         endmacro()
 381 endif()
 382
 383 if(MSVC)
 384         if(LYX_VLD)
 385            set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 386            set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 387            set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 388            include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 389         endif()
 390
 391         # TODO options
 392         if(LYX_WALL)
 393                 # Use the highest warning level
 394                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 395
 396                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 397                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 398                 else()
 399                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 400                 endif()
 401
 402                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 403                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 404                 else()
 405                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 406                 endif()
 407
 408                 # add here warnings which should produce an error /weXXXX
 409                 set(MSVC_W_ERROR   "/we4101 /we4189")
 410                 # add here warnings which should be disabled /wdXXXX
 411                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 412
 413                 set(CMAKE_CXX_FLAGS_DEBUG
 414                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 415                 set(CMAKE_CXX_FLAGS_RELEASE
 416                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 417                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 418                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 419
 420         else()
 421                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 422
 423                 # add here warnings which should produce an error /weXXXX
 424                 set(MSVC_W_ERROR   "/we4101 /we4189")
 425                 # add here warnings which should be disabled /wdXXXX
 426                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 427
 428                 set(CMAKE_CXX_FLAGS_DEBUG
 429                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 430                 set(CMAKE_CXX_FLAGS_RELEASE
 431                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 432                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 433                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 434
 435         endif()
 436         set(CMAKE_CXX_FLAGS_DEBUG
 437                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 438         set(CMAKE_CXX_FLAGS_RELEASE
 439                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 440         set(CMAKE_CXX_FLAGS_MINSIZEREL
 441                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 442
 443         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 444         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 445         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 446         message(STATUS "")
 447
 448 endif()
 449
 450
 451 if(LYX_DEBUG_GLIBC)
 452   set(_GLIBCXX_DEBUG 1)
 453 endif()
 454
 455 if(LYX_DEBUG_GLIBC_PEDANTIC)
 456   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 457 endif()
 458
 459 # compiler tests, config.h generation
 460 if(MSVC AND NOT CONFIGURECHECKS)
 461         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 462 else()
 463         include(ConfigureChecks.cmake)
 464         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 465 endif()
 466
 467 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 468
 469
 470 add_subdirectory(src)
 471 add_subdirectory(lyx2lyx)
 472 add_subdirectory(scripts)
 473
 474
 475 if(LYX_INSTALL)
 476         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 477         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 478                 message(FATAL_ERROR "Perl required!")
 479         endif()
 480         add_subdirectory(man)
 481         add_subdirectory(doc)
 482         include(../Install)
 483 endif()
 484
 485
 486 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 487 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 488 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 489
 490 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 491 #
 492 # needed by rpm
 493 SET(CPACK_SET_DESTDIR "ON")
 494 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 495 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 496 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 497 #
 498 # the next ones are needed by deb
 499 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 500 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 501
 502 # This is experimental, valid on _my_ system (Kornel)
 503 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 504 IF(ASPELL_FOUND)
 505   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 506 ENDIF()
 507 if(ENCHANT_FOUND)
 508   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 509 ENDIF()
 510 IF(LYX_USE_EXTERNAL_BOOST)
 511   IF(Boost_FOUND)
 512     SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.38.0 (>= 1.38.0-6),libboost-signals1.38.0 (>= 1.38.0-6),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 513   ENDIF()
 514 ENDIF()
 515 #
 516 # for the next ones, cpack insists on data with values in some file
 517 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 518 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 519
 520 # Find the revision number and use it as the release in rpm-package-build.
 521 # This way we may omit the otherwise needed "--force" parameter when
 522 # installing from that rpm package.
 523 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 524 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 525 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 526   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 527   # We use this value also to set the package-patch-value
 528   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 529     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 530   endif()
 531 endif()
 532
 533 # we do not have a readme or welcome data,
 534 # so we do not provide infofiles for
 535 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 536
 537 include(CPack)
 538
 539 #Now it is possible to create some packages
 540 # cd <BuildDir>
 541 # make package
 542 #############################################################################################
 543 # So, e.g. for variables
 544 #    CMAKE_PROJECT_NAME                     : lyx
 545 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 546 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 547 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 548 #    CMAKE_SYSTEM_NAME                      : Linux
 549 #    CPACK_BINARY_DEB:BOOL                  : ON
 550 #
 551 # the package name builds as "lyx-2.0.1-Linux.deb"
 552 #
 553 ############################## rpm ################################### deb ##################
 554 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 555 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 556 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 557 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 558 #
 559 message(STATUS)