development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.4 FATAL_ERROR)
   8
   9
  10 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  11 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  12
  13 set (EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  14
  15 set(PACKAGE lyx)
  16 set(PACKAGE_VERSION 1.5.0svn)
  17 set(LYX_DATE "not released yet")
  18 #TODO
  19 set(VERSION_INFO "CMake Build")
  20
  21 if(WIN32)
  22         set(USE_WINDOWS_PACKAGING 1)
  23 else(WIN32)
  24         set(USE_POSIX_PACKAGING 1)
  25 endif(WIN32)
  26
  27 if(NOT GROUP_CODE)
  28         #set(GROUP_CODE "The Golden Code")
  29         set(GROUP_CODE flat)
  30 endif(NOT GROUP_CODE)
  31
  32 include(LyXPaths)
  33 include(LyXMacros)
  34 include(ProjectSourceGroup)
  35
  36 if(merge OR MERGE_FILES)
  37         if(NOT MERGE_FILES)
  38                 set(MERGE_FILES TRUE CACHE TYPE STRING FORCE)
  39         endif(NOT MERGE_FILES)
  40         message(STATUS "")
  41         message(STATUS "will merge all *.C files of a project into one file (exception: qt4 and boost files)")
  42         message(STATUS "")
  43 endif(merge OR MERGE_FILES)
  44
  45 if(release)
  46         set(CMAKE_BUILD_TYPE Release)
  47         set(release)
  48 endif(release)
  49
  50
  51 set(qt_postfix qt4)
  52 project(lyx-${qt_postfix})
  53 find_package(Qt4 REQUIRED)
  54 # maybe anyway
  55 if(MERGE_FILES)
  56         add_definitions(-DQT_CLEAN_NAMESPACE -DQT_NO_STL -DQT_NO_KEYWORDS)
  57 endif(MERGE_FILES)
  58
  59 find_package(ZLIB REQUIRED)
  60 find_package(ICONV REQUIRED)
  61 add_definitions(-DHAVE_ICONV=1)
  62
  63 if(all OR aspell)
  64         set(aspell TRUE CACHE TYPE STRING)
  65         find_package(ASPELL REQUIRED)
  66 else(all OR aspell)
  67         find_package(ASPELL)
  68 endif(all OR aspell)
  69 set(aspell)
  70
  71 message("")
  72 if(nls OR all)
  73         set(nls TRUE CACHE TYPE STRING)
  74         add_definitions(-DENABLE_NLS=1)
  75         message("----- Building with ENABLE_NLS")
  76 else(nls OR all)
  77         message("----- No nls, to enable use -Dnls=1")
  78 endif(nls OR all)
  79 set(nls)
  80 if(ASPELL_FOUND)
  81         add_definitions(-DUSE_ASPELL=1)
  82         message("----- Building with USE_ASPELL")
  83 else(ASPELL_FOUND)
  84         message("----- No aspell, to get more information use -Daspell=1")
  85 endif(ASPELL_FOUND)
  86 set(all)
  87
  88 if(WIN32)
  89         if(noconsole)
  90                 set(noconsole TRUE CACHE TYPE STRING)
  91                 set(WIN32_CONSOLE WIN32)
  92                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
  93                 message("----- Console disabled")
  94         else(noconsole)
  95                 message("----- Console enabled, disable it with -Dnoconsole=1")
  96         endif(noconsole)
  97 endif(WIN32)
  98
  99 set(LYX_DIR         "")
 100 set(TOP_SRCDIR      "${TOP_SRC_DIR}")
 101 set(PROGRAM_SUFFIX  "")
 102 set(LOCALEDIR       "")
 103
 104 message("")
 105 message("----- LYX_DIR       : ${LYX_DIR}")
 106 message("----- TOP_SRCDIR    : ${TOP_SRCDIR}")
 107 message("----- PROGRAM_SUFFIX: ${PROGRAM_SUFFIX}")
 108 message("----- LOCALEDIR     : ${LOCALEDIR}")
 109 message("")
 110
 111 if(MSVC)
 112         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 113         # disable checked iterators for msvc release builds to get maximum speed
 114         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 115 endif(MSVC)
 116
 117 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 118
 119 if(MSVC AND NOT disable-pch)
 120         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h    ${CMAKE_BINARY_DIR}/pcheaders.h)
 121         configure_file(${CMAKE_SOURCE_DIR}/config.C.cmake ${CMAKE_BINARY_DIR}/config_pch.C)
 122         macro(lyx_add_msvc_pch name_)
 123                 SET_SOURCE_FILES_PROPERTIES(${${name_}_sources} PROPERTIES COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 124                 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/config_pch.C PROPERTIES COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 125                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.C ${CMAKE_BINARY_DIR}/pcheaders.h)
 126                 add_definitions(/DLYX_ENABLE_PCH)
 127         endmacro(lyx_add_msvc_pch)
 128         set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 129         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 130         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 131 else(MSVC AND NOT disable-pch)
 132         set(disable-pch TRUE CACHE TYPE STRING)
 133         macro(lyx_add_msvc_pch)
 134         endmacro(lyx_add_msvc_pch)
 135 endif(MSVC AND NOT disable-pch)
 136
 137 if(MSVC)
 138         if(WALL)
 139                 set(WALL 1 CACHE TYPE STRING FORCE)
 140                 set(DISABLEWALL 0 CACHE TYPE STRING FORCE)
 141         else(WALL)
 142                 set(DISABLEWALL 1 CACHE TYPE STRING FORCE)
 143         endif(WALL)
 144
 145         if(NOT DISABLEWALL)
 146
 147                 # Use the highest warning level
 148                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 149
 150                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 151                         STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 152                 else(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 153                         SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 154                 endif(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 155
 156                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 157                         STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 158                 else(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 159                         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 160                 endif(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 161
 162                 # add here warnings which should produce an error /weXXXX
 163                 SET(MSVC_W_ERROR   "/we4101 /we4189")
 164                 # add here warnings which should be disabled /wdXXXX
 165                 SET(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127")
 166
 167                 set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 168                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 169                 set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 170
 171         else(NOT DISABLEWALL)
 172
 173                 set(DISABLEWALL 1 CACHE TYPE STRING FORCE)
 174                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 175                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 176
 177                 # add here warnings which should produce an error /weXXXX
 178                 SET(MSVC_W_ERROR   "/we4101 /we4189")
 179                 # add here warnings which should be disabled /wdXXXX
 180                 SET(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4267")
 181
 182                 set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 183                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 184                 set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 185
 186         endif(NOT DISABLEWALL)
 187
 188         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 189         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 190         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 191         message("")
 192
 193 endif(MSVC)
 194
 195 # create config.h
 196 include(ConfigureChecks.cmake)
 197 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 198
 199 #TODO: insource is not the best place
 200 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 201                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 202
 203 include_directories(
 204         ${CMAKE_BINARY_DIR}
 205         ${TOP_SRC_DIR}/src
 206         ${TOP_SRC_DIR}/boost
 207         ${QT_INCLUDES}
 208 )
 209
 210 add_subdirectory(boost)
 211 add_subdirectory(intl)
 212 add_subdirectory(src)