development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26 message(STATUS)
  27 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  28
  29 # Usage LYX_OPTION
  30 # 1. parameter: option name without prefix 'LYX_'
  31 # 2. parameter: description
  32 # 3. parameter: default value, ON or OFF
  33 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  34 LYX_OPTION(NLS "Use nls" OFF ALL)
  35 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  36 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  37 LYX_OPTION(RELEASE "Build release version" ON ALL)
  38 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  39 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  40 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules" OFF ALL)
  42 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  43 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  44 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  45 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  46 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  47 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  48 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  49 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  50 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  51 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  52 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  53 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  54
  55 message(STATUS)
  56
  57 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  58 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  59
  60
  61
  62 if(UNIX OR MINGW)
  63     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  64     message(STATUS "Using GCC version ${GCC_VERSION}")
  65     if(NOT GCC_VERSION VERSION_LESS 4.4)
  66         set(LYX_USE_TR1 1)
  67         # GCC <= 4.5 does not support regex: there are linker errors
  68         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  69         set(LYX_USE_TR1_REGEX 0)
  70     endif()
  71 else()
  72     if(MSVC10)
  73         set(LYX_USE_TR1 1)
  74         set(LYX_USE_TR1_REGEX 1)
  75     endif()
  76 endif()
  77
  78
  79 if(LYX_INSTALL)
  80         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  81         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  82         SET(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  83         SET(PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  84         SET(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  85         SET(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  86         SET(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  87 endif()
  88
  89
  90 # Supress regeneration
  91 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  92
  93 set(VERSION_INFO "CMake Build")
  94
  95 # Try to get some informations from configure.ac
  96
  97 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  98 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  99
 100 if(WIN32)
 101   set(USE_WINDOWS_PACKAGING 1)
 102 elseif(APPLE)
 103   set(USE_MACOSX_PACKAGING 1)
 104 else()
 105   set(USE_POSIX_PACKAGING 1)
 106 endif()
 107
 108 macro(setstripped _varname _value)
 109   string(STRIP ${_value} _v)
 110   if(USE_POSIX_PACKAGING)
 111     string(TOLOWER ${_v} ${_varname})
 112   else()
 113     set(${_varname} ${_v})
 114   endif()
 115 endmacro(setstripped)
 116
 117 foreach(_c_l ${_config_lines} )
 118   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 119     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 120     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 121     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 122     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 123       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 124       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 125       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 126       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 127       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 128     endif()
 129   endif()
 130   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 131     set(LYX_DATE "${CMAKE_MATCH_1}")
 132   endif()
 133 endforeach(_c_l)
 134
 135
 136 if(LYX_PACKAGE_SUFFIX)
 137   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 138 else()
 139   set(PACKAGE ${PACKAGE_BASE})
 140 endif()
 141
 142 if(LYX_PROGRAM_SUFFIX)
 143   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 144 else()
 145   set(PROGRAM_SUFFIX "")
 146 endif()
 147
 148
 149 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 150   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 151   if (UNIX)
 152     # don't use the default "/usr/local"
 153     # but respect the user-choice on the command-line
 154     if(LYX_INSTALL_SUFFIX)
 155         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 156     else()
 157         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 158     endif()
 159   endif()
 160   if(WIN32)
 161     SET(CMAKE_INSTALL_PREFIX
 162       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 163   endif()
 164 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 165
 166 if (WIN32)
 167   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 168 else()
 169   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 170 endif()
 171
 172 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 173 set(LYX_LOCALEDIR "locale")
 174 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 175 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 176
 177
 178 if(NOT GROUP_CODE)
 179         #set(GROUP_CODE "The Golden Code")
 180         set(GROUP_CODE flat)
 181 endif()
 182
 183 # lyx's source files
 184 set(LYX_CPP_FILES *.cpp)
 185 set(LYX_HPP_FILES *.h)
 186 set(LYX_MOC_FILES moc_*.cpp)
 187
 188
 189 include(ProjectSourceGroup)
 190
 191 if(LYX_MERGE_FILES)
 192         add_definitions(-DLYX_MERGED_BUILD)
 193 endif()
 194
 195
 196 set(CMAKE_BUILD_TYPE Release)
 197
 198 if(LYX_PROFILE)
 199         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 200         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 201             CACHE TYPE STRING FORCE)
 202 endif()
 203
 204 if(LYX_RELEASE)
 205         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 206 endif()
 207
 208 if(LYX_DEBUG)
 209         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 210 endif()
 211
 212
 213
 214 if(LYX_SHARED_LIBRARIES)
 215         set(library_type SHARED)
 216 else()
 217         set(library_type STATIC)
 218 endif()
 219
 220 if(NOT MSVC)
 221         if(NOT LYX_QUIET)
 222                 set(CMAKE_VERBOSE_MAKEFILE ON)
 223         endif()
 224         set(LYX_CXX_FLAGS -Wall)
 225         if(LYX_STDLIB_DEBUG)
 226                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 227         endif()
 228         if(LYX_CONCEPT_CHECKS)
 229                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 230         endif()
 231         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 232         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 233         if(MINGW)
 234                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 235         else()
 236                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 237         endif()
 238         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 239 endif()
 240
 241
 242 find_package(Qt4 REQUIRED)
 243 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 244
 245 find_package(ZLIB REQUIRED)
 246
 247 if(LYX_ASPELL)
 248         find_package(ASPELL REQUIRED)
 249 else()
 250         find_package(ASPELL)
 251 endif()
 252
 253
 254 if(LYX_USE_EXTERNAL_LIBINTL)
 255         find_package(Libintl REQUIRED)
 256         add_definitions(-DHAVE_GETTEXT)
 257 endif()
 258
 259
 260 if(WIN32)
 261   find_library(HUNSPELL_LIBRARY "libhunspell")
 262 else()
 263   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 264   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 265 endif()
 266 if (HUNSPELL_LIBRARY)
 267   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 268 endif()
 269
 270 if (HUNSPELL_FOUND)
 271   add_definitions(-DUSE_HUNSPELL=1)
 272   message(STATUS "Building with USE_HUNSPELL")
 273 else()
 274   message(STATUS "Hunspell not found, building without hunspell support")
 275 endif()
 276
 277 if(WIN32)
 278   find_library(ENCHANT_LIBRARY "libenchant")
 279   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 280 else()
 281   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 282   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 283 endif()
 284 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 285   set(ENCHANT_FOUND TRUE)
 286   add_definitions(-DUSE_ENCHANT=1)
 287   message(STATUS "Building with USE_ENCHANT")
 288 else()
 289   message(STATUS "Enchant not found, building without enchant support")
 290 endif()
 291
 292
 293 if(LYX_NLS)
 294         add_definitions(-DENABLE_NLS=1)
 295 endif()
 296
 297 if(ASPELL_FOUND)
 298         add_definitions(-DUSE_ASPELL=1)
 299 endif()
 300
 301 if(WIN32)
 302         if(LYX_NO_CONSOLE)
 303                 set(WIN32_CONSOLE WIN32)
 304                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 305         endif()
 306         if(MSVC)
 307                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 308                 # disable checked iterators for msvc release builds to get maximum speed
 309                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 310         else()
 311                 add_definitions(-DWINVER=0x0500)
 312         endif()
 313 endif()
 314
 315 message(STATUS "")
 316 foreach(_v PACKAGE PACKAGE_VERSION
 317     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 318     LYX_ABS_TOP_SRCDIR
 319     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 320   if(NOT DEFINED ${_v})
 321     message(FATAL_ERROR "${_v} not defined")
 322   endif()
 323   string(SUBSTRING "${_v}                            " 0 28 _v1)
 324   message(STATUS "----- ${_v1}: ${${_v}}")
 325 endforeach(_v)
 326 message(STATUS "")
 327
 328
 329 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 330 # Not sure if it works for all non-msvc compilers
 331 include(PCHSupport_26)
 332
 333 if(NOT LYX_DISABLE_PCH)
 334
 335         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 336         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 337         add_definitions(-DLYX_ENABLE_PCH)
 338
 339         if(MSVC AND NOT MERGE_FILES)
 340                 macro(lyx_add_msvc_pch name_)
 341                         set_source_files_properties(${${name_}_sources} PROPERTIES
 342                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 343                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 344                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 345                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 346                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 347                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 348                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 349                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 350                 endmacro(lyx_add_msvc_pch)
 351                 macro(lyx_add_gcc_pch name_)
 352                 endmacro()
 353         else()
 354                 macro(lyx_add_msvc_pch name_)
 355                 endmacro()
 356                 macro(lyx_add_gcc_pch name_)
 357                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 358                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 359                 endmacro()
 360         endif()
 361 else()
 362         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 363         macro(lyx_add_msvc_pch)
 364         endmacro(lyx_add_msvc_pch)
 365         macro(lyx_add_gcc_pch name_)
 366         endmacro()
 367 endif()
 368
 369 if(MSVC)
 370        if(LYX_VLD)
 371                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 372                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 373                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 374                include(${vld_path}/tools/cmake/vld.cmake)
 375        endif()
 376
 377         # TODO options
 378         if(WALL)
 379                 set(WALL 1 CACHE TYPE STRING FORCE)
 380
 381                 # Use the highest warning level
 382                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 383                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 384
 385                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 386                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 387                 else()
 388                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 389                 endif()
 390
 391                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 392                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 393                 else()
 394                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 395                 endif()
 396
 397                 # add here warnings which should produce an error /weXXXX
 398                 set(MSVC_W_ERROR   "/we4101 /we4189")
 399                 # add here warnings which should be disabled /wdXXXX
 400                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 401
 402                 set(CMAKE_CXX_FLAGS_DEBUG
 403                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 404                 set(CMAKE_CXX_FLAGS_RELEASE
 405                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 406                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 407                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 408
 409         else()
 410                 set(WALL 0 CACHE TYPE STRING FORCE)
 411
 412                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 413                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 414
 415                 # add here warnings which should produce an error /weXXXX
 416                 set(MSVC_W_ERROR   "/we4101 /we4189")
 417                 # add here warnings which should be disabled /wdXXXX
 418                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 419
 420                 set(CMAKE_CXX_FLAGS_DEBUG
 421                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 422                 set(CMAKE_CXX_FLAGS_RELEASE
 423                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 424                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 425                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 426
 427         endif()
 428         set(CMAKE_CXX_FLAGS_DEBUG
 429                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 430         set(CMAKE_CXX_FLAGS_RELEASE
 431                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 432         set(CMAKE_CXX_FLAGS_MINSIZEREL
 433                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 434
 435         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 436         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 437         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 438         message(STATUS "")
 439
 440 endif()
 441
 442 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 443 FIND_PROGRAM(_PYTHON_EXECUTABLE python)
 444 if( NOT ${_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 445     if(LYX_NLS)
 446       find_package(LyXGettext REQUIRED)
 447       include_directories(${TOP_SRC_DIR}/po)
 448       add_subdirectory(po)
 449     endif()
 450 endif()
 451
 452 if(LYX_DEBUG_GLIBC)
 453   set(_GLIBCXX_DEBUG 1)
 454 endif()
 455
 456 if(LYX_DEBUG_GLIBC_PEDANTIC)
 457   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 458 endif()
 459
 460 # compiler tests, config.h generation
 461 if(MSVC AND NOT CONFIGURECHECKS)
 462         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 463 else()
 464         include(ConfigureChecks.cmake)
 465         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 466 endif()
 467
 468 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 469
 470 find_package(ICONV REQUIRED)
 471 add_definitions(-DHAVE_ICONV=1)
 472
 473
 474 include_directories(
 475   ${CMAKE_BINARY_DIR}
 476   ${TOP_SRC_DIR}/src)
 477
 478
 479 if(LYX_USE_EXTERNAL_BOOST)
 480   message(STATUS "Searching for boost")
 481   find_package(Boost COMPONENTS signals regex)
 482   if(Boost_FOUND)
 483     message(STATUS "Boost found")
 484     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 485     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 486   else()
 487     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 488   endif()
 489 else()
 490   if(LYX_USE_TR1_REGEX)
 491     set(Lyx_Boost_Libraries boost_signals)
 492   else()
 493     set(Lyx_Boost_Libraries boost_signals boost_regex)
 494   endif()
 495   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 496   include_directories(${TOP_SRC_DIR}/boost)
 497   add_subdirectory(boost)
 498 endif()
 499
 500
 501 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 502   add_subdirectory(intl)
 503 endif()
 504 add_subdirectory(src)
 505
 506 if(LYX_INSTALL)
 507         add_subdirectory(man)
 508         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 509                 add_subdirectory(doc)
 510         endif()
 511 endif()
 512 add_subdirectory(lyx2lyx)
 513 add_subdirectory(scripts)
 514
 515 if(LYX_INSTALL)
 516         include(../Install)
 517 endif()
 518
 519 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 520 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 521 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 522
 523 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 524 #
 525 # needed by rpm
 526 SET(CPACK_SET_DESTDIR "ON")
 527 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 528 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 529 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 530 #
 531 # the next ones are needed by deb
 532 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 533 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 534
 535 # This is experimental, valid on _my_ system (Kornel)
 536 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 537 IF(ASPELL_FOUND)
 538   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 539 ENDIF()
 540 #
 541 # for the next ones, cpack insists on data with values in some file
 542 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 543 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 544
 545 # Find the revision number and use it as the release in rpm-package-build.
 546 # This way we may omit the otherwise needed "--force" parameter when
 547 # installing from that rpm package.
 548 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 549 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 550 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 551   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 552   # We use this value also to set the package-patch-value
 553   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 554     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 555   endif()
 556 endif()
 557
 558 # we do not have a readme or welcome data,
 559 # so we do not provide infofiles for
 560 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 561
 562 if(LYX_INSTALL)
 563         include(CPack)
 564 endif()
 565
 566 #Now it is possible to create some packages
 567 # cd <BuildDir>
 568 # make package
 569 #############################################################################################
 570 # So, e.g. for variables
 571 #    CMAKE_PROJECT_NAME                     : lyx
 572 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 573 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 574 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 575 #    CMAKE_SYSTEM_NAME                      : Linux
 576 #    CPACK_BINARY_DEB:BOOL                  : ON
 577 #
 578 # the package name builds as "lyx-2.0.1-Linux.deb"
 579 #
 580 ############################## rpm ################################### deb ##################
 581 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 582 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 583 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 584 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 585 #
 586 message(STATUS)