development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 # Options for all compilers/systems
  40 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 LYX_OPTION(NLS "Use nls" OFF ALL)
  43 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  44 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  45 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  46 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  47 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  48 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  49 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  50 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  51 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  52 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  53 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  54 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  55
  56 # GCC specific
  57 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  58 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  59 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  60 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  61 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  62 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  63 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  64
  65 # MSVC specific
  66 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  67 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  68 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  69 LYX_OPTION(CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  70 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  71
  72 # Check option dependencies
  73 if(LYX_CPACK)
  74         set(LYX_INSTALL ON)
  75 endif()
  76
  77 if(LYX_INSTALL)
  78         set(LYX_NLS ON)
  79         if (WIN32)
  80                 set(LYX_HUNSPELL ON)
  81         endif()
  82         set(LYX_CONSOLE OFF)
  83         set(LYX_PACKAGE_SUFFIX ON)
  84         set(LYX_RELEASE ON)
  85         set(LYX_PROFILE OFF)
  86 endif()
  87
  88 if(LYX_MERGE_FILES)
  89         set(LYX_PCH OFF)
  90 else()
  91         set(LYX_MERGE_REBUILD OFF)
  92 endif()
  93
  94 if(LYX_DEPENDENCIES_DOWNLOAD)
  95         message(STATUS)
  96         set(LYX_DEPENDENCIES_DIR ${CMAKE_BINARY_DIR}/msvc2010-deps)
  97         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
  98         set(deps_files lyx20-deps-msvc2010-x86.zip)
  99         foreach(it ${deps_files})
 100                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 101                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 102                 if(NOT already_downloaded)
 103                         message(STATUS "Downloading ${it} ...")
 104                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 105                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 106                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 107                 endif()
 108         endforeach()
 109         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 110 endif()
 111
 112
 113 message(STATUS)
 114
 115 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
 116 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
 117
 118
 119
 120 if(UNIX OR MINGW)
 121         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 122         message(STATUS "Using GCC version ${GCC_VERSION}")
 123         if(NOT GCC_VERSION VERSION_LESS 4.4)
 124                 set(LYX_USE_TR1 1)
 125                 # GCC <= 4.5 does not support regex: there are linker errors
 126                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 127                 set(LYX_USE_TR1_REGEX 0)
 128         endif()
 129 else()
 130         if(MSVC10)
 131                 set(LYX_USE_TR1 1)
 132                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 133         endif()
 134 endif()
 135
 136
 137 set(VERSION_INFO "CMake Build")
 138
 139 # Try to get some informations from configure.ac
 140
 141 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 142 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 143
 144 if(WIN32)
 145         set(USE_WINDOWS_PACKAGING 1)
 146 elseif(APPLE)
 147         set(USE_MACOSX_PACKAGING 1)
 148 else()
 149         set(USE_POSIX_PACKAGING 1)
 150 endif()
 151
 152 macro(setstripped _varname _value)
 153         string(STRIP ${_value} _v)
 154         if(USE_POSIX_PACKAGING)
 155                 string(TOLOWER ${_v} ${_varname})
 156         else()
 157                 set(${_varname} ${_v})
 158         endif()
 159 endmacro(setstripped)
 160
 161 foreach(_c_l ${_config_lines} )
 162         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 163                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 164                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 165                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 166                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 167                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 168                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 169                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 170                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 171                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 172                 endif()
 173         endif()
 174         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 175                 set(LYX_DATE "${CMAKE_MATCH_1}")
 176         endif()
 177 endforeach(_c_l)
 178
 179
 180 if (LYX_INSTALL_PREFIX)
 181         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 182         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 183 endif()
 184
 185 if(LYX_PACKAGE_SUFFIX)
 186         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 187 else()
 188         set(PACKAGE ${PACKAGE_BASE})
 189 endif()
 190
 191 if(LYX_PROGRAM_SUFFIX)
 192         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 193 else()
 194         set(PROGRAM_SUFFIX "")
 195 endif()
 196
 197
 198 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 199         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 200         if (UNIX)
 201                 # don't use the default "/usr/local"
 202                 # but respect the user-choice on the command-line
 203                 if(LYX_INSTALL_SUFFIX)
 204                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 205                 else()
 206                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 207                 endif()
 208         endif()
 209         if(WIN32)
 210                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 211         endif()
 212 endif()
 213
 214 if (WIN32)
 215         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 216 else()
 217         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 218 endif()
 219
 220 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 221 set(LYX_LOCALEDIR "locale")
 222 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 223 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 224
 225
 226 if(NOT GROUP_CODE)
 227         #set(GROUP_CODE "The Golden Code")
 228         set(GROUP_CODE flat)
 229 endif()
 230
 231 # lyx's source files
 232 set(LYX_CPP_FILES *.cpp)
 233 set(LYX_HPP_FILES *.h)
 234 set(LYX_MOC_FILES moc_*.cpp)
 235
 236
 237 include(ProjectSourceGroup)
 238
 239
 240 if(LYX_PROFILE)
 241         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 242         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 243 endif()
 244
 245 if(LYX_RELEASE)
 246         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 247 else()
 248         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 249 endif()
 250
 251 # When shared libs are supported enable this option
 252 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 253 if(LYX_SHARED_LIBRARIES)
 254         set(library_type SHARED)
 255 else()
 256         set(library_type STATIC)
 257 endif()
 258
 259 if(NOT MSVC)
 260         if(NOT LYX_QUIET)
 261                 set(CMAKE_VERBOSE_MAKEFILE ON)
 262         endif()
 263         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 264         if(LYX_STDLIB_DEBUG)
 265                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 266         endif()
 267         if(LYX_CONCEPT_CHECKS)
 268                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 269         endif()
 270         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 271         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 272         if(MINGW)
 273                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 274         else()
 275                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 276         endif()
 277         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 278 endif()
 279
 280
 281 find_package(Qt4 REQUIRED)
 282 find_package(ICONV REQUIRED)
 283 find_package(ZLIB REQUIRED)
 284
 285 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 286
 287 if(LYX_ASPELL)
 288         find_package(ASPELL)
 289         include_directories(${ASPELL_INCLUDE_DIR})
 290 endif()
 291
 292 if(LYX_ENCHANT)
 293         find_package(Enchant REQUIRED)
 294         include_directories(${ENCHANT_INCLUDE_DIR})
 295 endif()
 296
 297 if(LYX_HUNSPELL)
 298         find_package(Hunspell REQUIRED)
 299         include_directories(${HUNSPELL_INCLUDE_DIR})
 300 endif()
 301
 302 if(LYX_NLS)
 303         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 304         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 305                 message(FATAL_ERROR "Python 2.6 needed!")
 306         endif()
 307         find_package(LyXGettext REQUIRED)
 308         include_directories(${TOP_SRC_DIR}/po)
 309         add_subdirectory(po)
 310 endif()
 311
 312 if(LYX_EXTERNAL_LIBINTL)
 313         find_package(Libintl REQUIRED)
 314         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 315 else()
 316         add_subdirectory(intl)
 317 endif()
 318
 319 if(LYX_EXTERNAL_BOOST)
 320         message(STATUS "Searching for boost")
 321         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 322         if(Boost_FOUND)
 323                 message(STATUS "Boost found")
 324                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 325                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 326         else()
 327                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 328         endif()
 329 else()
 330         if(LYX_USE_TR1_REGEX)
 331                 set(Lyx_Boost_Libraries boost_signals)
 332         else()
 333                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 334         endif()
 335         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 336         include_directories(${TOP_SRC_DIR}/boost)
 337         add_subdirectory(boost)
 338 endif()
 339
 340
 341
 342
 343 if(WIN32)
 344         if(NOT LYX_CONSOLE)
 345                 set(WIN32_CONSOLE WIN32)
 346                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 347         endif()
 348         if(MSVC)
 349                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 350                 # disable checked iterators for msvc release builds to get maximum speed
 351                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 352         else()
 353                 add_definitions(-DWINVER=0x0500)
 354         endif()
 355 endif()
 356
 357 message(STATUS "")
 358 foreach(_v PACKAGE PACKAGE_VERSION
 359         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 360         LYX_ABS_TOP_SRCDIR
 361         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 362         if(NOT DEFINED ${_v})
 363                 message(FATAL_ERROR "${_v} not defined")
 364         endif()
 365         string(SUBSTRING "${_v}                            " 0 28 _v1)
 366         message(STATUS "----- ${_v1}: ${${_v}}")
 367 endforeach(_v)
 368 message(STATUS "")
 369
 370
 371 if(LYX_PCH)
 372         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 373         # Not sure if it works for all non-msvc compilers
 374         include(PCHSupport_26)
 375         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 376         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 377         add_definitions(-DLYX_ENABLE_PCH)
 378
 379         if(MSVC)
 380                 macro(lyx_add_msvc_pch name_)
 381                         set_source_files_properties(${${name_}_sources} PROPERTIES
 382                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 383                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 384                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 385                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 386                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 387                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 388                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 389                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 390                 endmacro(lyx_add_msvc_pch)
 391                 macro(lyx_add_gcc_pch name_)
 392                 endmacro()
 393         else()
 394                 macro(lyx_add_msvc_pch name_)
 395                 endmacro()
 396                 macro(lyx_add_gcc_pch name_)
 397                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 398                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 399                 endmacro()
 400         endif()
 401 else()
 402         macro(lyx_add_msvc_pch)
 403         endmacro(lyx_add_msvc_pch)
 404         macro(lyx_add_gcc_pch name_)
 405         endmacro()
 406 endif()
 407
 408 if(MSVC)
 409         if(LYX_VLD)
 410                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 411                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 412                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 413                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 414         endif()
 415
 416         if(LYX_WALL)
 417                 # Use the highest warning level
 418                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 419
 420                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 421                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 422                 else()
 423                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 424                 endif()
 425
 426                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 427                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 428                 else()
 429                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 430                 endif()
 431
 432                 # add here warnings which should produce an error /weXXXX
 433                 set(MSVC_W_ERROR   "/we4101 /we4189")
 434                 # add here warnings which should be disabled /wdXXXX
 435                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 436
 437                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 438                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 439                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 440
 441         else()
 442                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 443
 444                 # add here warnings which should produce an error /weXXXX
 445                 set(MSVC_W_ERROR   "/we4101 /we4189")
 446                 # add here warnings which should be disabled /wdXXXX
 447                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 448
 449                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 450                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 451                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 452
 453         endif()
 454         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 455         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 456         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 457
 458         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 459         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 460         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 461         message(STATUS "")
 462 endif()
 463
 464
 465 if(LYX_DEBUG_GLIBC)
 466         set(_GLIBCXX_DEBUG 1)
 467 endif()
 468
 469 if(LYX_DEBUG_GLIBC_PEDANTIC)
 470         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 471 endif()
 472
 473 # compiler tests, config.h generation
 474 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 475         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 476 else()
 477         include(ConfigureChecks.cmake)
 478         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 479 endif()
 480
 481 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 482
 483
 484 add_subdirectory(src)
 485 add_subdirectory(lyx2lyx)
 486 add_subdirectory(scripts)
 487
 488
 489 if(LYX_INSTALL)
 490         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 491         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 492                 message(FATAL_ERROR "Perl required!")
 493         endif()
 494         add_subdirectory(man)
 495         add_subdirectory(doc)
 496         include(../Install)
 497 endif()
 498
 499
 500 message(STATUS)
 501 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 502 message(STATUS)
 503 LYX_OPTION_LIST_ALL()
 504
 505
 506 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 507 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 508 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 509
 510 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 511 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 512
 513 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 514
 515 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 516 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 517 #
 518 # needed by rpm
 519 set(CPACK_SET_DESTDIR "ON")
 520 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 521 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 522 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 523 #
 524 # the next ones are needed by deb
 525 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 526 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 527
 528 # This is experimental, valid on _my_ system (Kornel)
 529 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 530 if(ASPELL_FOUND)
 531         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 532 endif()
 533 if(ENCHANT_FOUND)
 534         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 535 endif()
 536 if(LYX_EXTERNAL_BOOST)
 537         if(Boost_FOUND)
 538                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 539         endif()
 540 endif()
 541 #
 542 # for the next ones, cpack insists on data with values in some file
 543 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 544 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 545
 546 # Find the revision number and use it as the release in rpm-package-build.
 547 # This way we may omit the otherwise needed "--force" parameter when
 548 # installing from that rpm package.
 549 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 550 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 551 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 552         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 553         # We use this value also to set the package-patch-value
 554         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 555                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 556         endif()
 557 endif()
 558
 559 # we do not have a readme or welcome data,
 560 # so we do not provide infofiles for
 561 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 562
 563 if(LYX_CPACK)
 564         include(CPack)
 565 endif()
 566
 567 #Now it is possible to create some packages
 568 # cd <BuildDir>
 569 # make package
 570 #############################################################################################
 571 # So, e.g. for variables
 572 #    CMAKE_PROJECT_NAME                     : lyx
 573 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 574 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 575 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 576 #    CMAKE_SYSTEM_NAME                      : Linux
 577 #    CPACK_BINARY_DEB:BOOL                  : ON
 578 #
 579 # the package name builds as "lyx-2.0.1-Linux.deb"
 580 #
 581 ############################## rpm ################################### deb ##################
 582 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 583 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 584 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 585 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 586 #
 587 message(STATUS)