development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 # Options for all compilers/systems
  40 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 LYX_OPTION(NLS "Use nls" OFF ALL)
  43 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  44 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  45 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  46 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  47 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  48 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  49 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  50 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  51 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  52 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  53 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  54 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  55
  56 # GCC specific
  57 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  58 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  59 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  60 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  61 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  62 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  63 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  64
  65 # MSVC specific
  66 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  67 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  68 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  69 LYX_OPTION(CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  70 LYX_OPTION(DEPENDENCIES_DOWNLOAD "Download dependencies for MSVC 10" OFF MSVC)
  71
  72 # Check option dependencies
  73 if(LYX_CPACK)
  74         set(LYX_INSTALL ON)
  75 endif()
  76
  77 if(LYX_INSTALL)
  78         set(LYX_NLS ON)
  79         if (WIN32)
  80                 set(LYX_HUNSPELL ON)
  81         endif()
  82         set(LYX_CONSOLE OFF)
  83         set(LYX_PACKAGE_SUFFIX ON)
  84         set(LYX_RELEASE ON)
  85         set(LYX_PROFILE OFF)
  86 endif()
  87
  88 if(LYX_MERGE_FILES)
  89         set(LYX_PCH OFF)
  90 else()
  91         set(LYX_MERGE_REBUILD OFF)
  92 endif()
  93
  94 if(LYX_DEPENDENCIES_DOWNLOAD)
  95         message(STATUS)
  96         set(LYX_DEPENDENCIES_DIR ${CMAKE_BINARY_DIR}/msvc2010-deps)
  97         message(STATUS "Using downloaded dependencies in ${LYX_DEPENDENCIES_DIR}")
  98         set(deps_files lyx20-deps-msvc2010-x86.zip)
  99         foreach(it ${deps_files})
 100                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 101                 find_file(already_downloaded ${it} "${LYX_DEPENDENCIES_DIR}/download")
 102                 if(NOT already_downloaded)
 103                         message(STATUS "Downloading ${it} ...")
 104                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/${it} ${LYX_DEPENDENCIES_DIR}/download/${it} SHOW_PROGRESS)
 105                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_DEPENDENCIES_DIR}/download/${it}
 106                                       WORKING_DIRECTORY ${LYX_DEPENDENCIES_DIR})
 107                 endif()
 108         endforeach()
 109         set(GNUWIN32_DIR ${LYX_DEPENDENCIES_DIR}/deps20)
 110 endif()
 111
 112
 113 message(STATUS)
 114
 115 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
 116 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
 117
 118
 119
 120 if(UNIX OR MINGW)
 121         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 122         message(STATUS "Using GCC version ${GCC_VERSION}")
 123         if(NOT GCC_VERSION VERSION_LESS 4.4)
 124                 set(LYX_USE_TR1 1)
 125                 # GCC <= 4.5 does not support regex: there are linker errors
 126                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 127                 set(LYX_USE_TR1_REGEX 0)
 128         endif()
 129 else()
 130         if(MSVC10)
 131                 set(LYX_USE_TR1 1)
 132                 #set(LYX_USE_TR1_REGEX 1) #TODO should we use it in ECMAScript mode?
 133         endif()
 134 endif()
 135
 136
 137 set(VERSION_INFO "CMake Build")
 138
 139 # Try to get some informations from configure.ac
 140
 141 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 142 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 143
 144 if(WIN32)
 145         set(USE_WINDOWS_PACKAGING 1)
 146 elseif(APPLE)
 147         set(USE_MACOSX_PACKAGING 1)
 148 else()
 149         set(USE_POSIX_PACKAGING 1)
 150 endif()
 151
 152 macro(setstripped _varname _value)
 153         string(STRIP ${_value} _v)
 154         if(USE_POSIX_PACKAGING)
 155                 string(TOLOWER ${_v} ${_varname})
 156         else()
 157                 set(${_varname} ${_v})
 158         endif()
 159 endmacro(setstripped)
 160
 161 foreach(_c_l ${_config_lines} )
 162         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 163                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 164                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 165                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 166                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 167                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 168                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 169                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 170                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 171                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 172                 endif()
 173         endif()
 174         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 175                 set(LYX_DATE "${CMAKE_MATCH_1}")
 176         endif()
 177 endforeach(_c_l)
 178
 179
 180 if (LYX_INSTALL_PREFIX)
 181         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 182         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 183 endif()
 184 set(LYX_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 185
 186 if(LYX_PACKAGE_SUFFIX)
 187         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 188 else()
 189         set(PACKAGE ${PACKAGE_BASE})
 190 endif()
 191
 192 if(LYX_PROGRAM_SUFFIX)
 193         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 194 else()
 195         set(PROGRAM_SUFFIX "")
 196 endif()
 197
 198
 199 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 200         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 201         if (UNIX)
 202                 # don't use the default "/usr/local"
 203                 # but respect the user-choice on the command-line
 204                 if(LYX_INSTALL_SUFFIX)
 205                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 206                 else()
 207                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 208                 endif()
 209         endif()
 210         if(WIN32)
 211                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 212         endif()
 213 endif()
 214
 215 if (WIN32)
 216         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 217 else()
 218         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 219 endif()
 220
 221 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 222 set(LYX_LOCALEDIR "locale")
 223 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 224 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 225
 226
 227 if(NOT GROUP_CODE)
 228         #set(GROUP_CODE "The Golden Code")
 229         set(GROUP_CODE flat)
 230 endif()
 231
 232 # lyx's source files
 233 set(LYX_CPP_FILES *.cpp)
 234 set(LYX_HPP_FILES *.h)
 235 set(LYX_MOC_FILES moc_*.cpp)
 236
 237
 238 include(ProjectSourceGroup)
 239
 240
 241 if(LYX_PROFILE)
 242         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 243         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 244 endif()
 245
 246 if(LYX_RELEASE)
 247         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 248 else()
 249         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 250 endif()
 251
 252 # When shared libs are supported enable this option
 253 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 254 if(LYX_SHARED_LIBRARIES)
 255         set(library_type SHARED)
 256 else()
 257         set(library_type STATIC)
 258 endif()
 259
 260 if(NOT MSVC)
 261         if(NOT LYX_QUIET)
 262                 set(CMAKE_VERBOSE_MAKEFILE ON)
 263         endif()
 264         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 265         if(LYX_STDLIB_DEBUG)
 266                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 267         endif()
 268         if(LYX_CONCEPT_CHECKS)
 269                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 270         endif()
 271         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 272         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 273         if(MINGW)
 274                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 275         else()
 276                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 277         endif()
 278         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 279 endif()
 280
 281
 282 find_package(Qt4 REQUIRED)
 283 find_package(ICONV REQUIRED)
 284 find_package(ZLIB REQUIRED)
 285
 286 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 287
 288 if(LYX_ASPELL)
 289         find_package(ASPELL)
 290         include_directories(${ASPELL_INCLUDE_DIR})
 291 endif()
 292
 293 if(LYX_ENCHANT)
 294         find_package(Enchant REQUIRED)
 295         include_directories(${ENCHANT_INCLUDE_DIR})
 296 endif()
 297
 298 if(LYX_HUNSPELL)
 299         find_package(Hunspell REQUIRED)
 300         include_directories(${HUNSPELL_INCLUDE_DIR})
 301 endif()
 302
 303 if(LYX_NLS)
 304         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python HINTS ${GNUWIN32_DIR}/python)
 305         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 306                 message(FATAL_ERROR "Python 2.6 needed!")
 307         endif()
 308         find_package(LyXGettext REQUIRED)
 309         include_directories(${TOP_SRC_DIR}/po)
 310         add_subdirectory(po)
 311 endif()
 312
 313 if(LYX_EXTERNAL_LIBINTL)
 314         find_package(Libintl REQUIRED)
 315         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 316 else()
 317         if(LYX_NLS)
 318                 add_subdirectory(intl)
 319         else()
 320                 # do not compile if nls disabled
 321         endif()
 322 endif()
 323
 324 if(LYX_EXTERNAL_BOOST)
 325         message(STATUS "Searching for boost")
 326         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 327         if(Boost_FOUND)
 328                 message(STATUS "Boost found")
 329                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 330                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 331         else()
 332                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 333         endif()
 334 else()
 335         if(LYX_USE_TR1_REGEX)
 336                 set(Lyx_Boost_Libraries boost_signals)
 337         else()
 338                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 339         endif()
 340         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 341         include_directories(${TOP_SRC_DIR}/boost)
 342         add_subdirectory(boost)
 343 endif()
 344
 345
 346
 347
 348 if(WIN32)
 349         if(NOT LYX_CONSOLE)
 350                 set(WIN32_CONSOLE WIN32)
 351                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 352         endif()
 353         if(MSVC)
 354                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 355                 # disable checked iterators for msvc release builds to get maximum speed
 356                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 357         else()
 358                 add_definitions(-DWINVER=0x0500)
 359         endif()
 360 endif()
 361
 362 message(STATUS "")
 363 foreach(_v PACKAGE PACKAGE_VERSION
 364         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 365         LYX_ABS_TOP_SRCDIR
 366         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 367         if(NOT DEFINED ${_v})
 368                 message(FATAL_ERROR "${_v} not defined")
 369         endif()
 370         string(SUBSTRING "${_v}                            " 0 28 _v1)
 371         message(STATUS "----- ${_v1}: ${${_v}}")
 372 endforeach(_v)
 373 message(STATUS "")
 374
 375
 376 if(LYX_PCH)
 377         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 378         # Not sure if it works for all non-msvc compilers
 379         include(PCHSupport_26)
 380         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 381         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 382         add_definitions(-DLYX_ENABLE_PCH)
 383
 384         if(MSVC)
 385                 macro(lyx_add_msvc_pch name_)
 386                         set_source_files_properties(${${name_}_sources} PROPERTIES
 387                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 388                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 389                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 390                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 391                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 392                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 393                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 394                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 395                 endmacro(lyx_add_msvc_pch)
 396                 macro(lyx_add_gcc_pch name_)
 397                 endmacro()
 398         else()
 399                 macro(lyx_add_msvc_pch name_)
 400                 endmacro()
 401                 macro(lyx_add_gcc_pch name_)
 402                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 403                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 404                 endmacro()
 405         endif()
 406 else()
 407         macro(lyx_add_msvc_pch)
 408         endmacro(lyx_add_msvc_pch)
 409         macro(lyx_add_gcc_pch name_)
 410         endmacro()
 411 endif()
 412
 413 if(MSVC)
 414         if(LYX_VLD)
 415                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 416                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 417                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 418                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 419         endif()
 420
 421         if(LYX_WALL)
 422                 # Use the highest warning level
 423                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 424
 425                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 426                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 427                 else()
 428                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 429                 endif()
 430
 431                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 432                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 433                 else()
 434                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 435                 endif()
 436
 437                 # add here warnings which should produce an error /weXXXX
 438                 set(MSVC_W_ERROR   "/we4101 /we4189")
 439                 # add here warnings which should be disabled /wdXXXX
 440                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 441
 442                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 443                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 444                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 445
 446         else()
 447                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 448
 449                 # add here warnings which should produce an error /weXXXX
 450                 set(MSVC_W_ERROR   "/we4101 /we4189")
 451                 # add here warnings which should be disabled /wdXXXX
 452                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 453
 454                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 455                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 456                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 457
 458         endif()
 459         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 460         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 461         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 462
 463         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 464         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 465         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 466         message(STATUS "")
 467 endif()
 468
 469
 470 if(LYX_DEBUG_GLIBC)
 471         set(_GLIBCXX_DEBUG 1)
 472 endif()
 473
 474 if(LYX_DEBUG_GLIBC_PEDANTIC)
 475         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 476 endif()
 477
 478 # compiler tests, config.h generation
 479 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 480         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 481 else()
 482         include(ConfigureChecks.cmake)
 483         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 484 endif()
 485
 486 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 487
 488
 489 add_subdirectory(src)
 490 add_subdirectory(lyx2lyx)
 491 add_subdirectory(scripts)
 492
 493
 494 if(LYX_INSTALL)
 495         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 496         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 497                 message(FATAL_ERROR "Perl required!")
 498         endif()
 499         add_subdirectory(man)
 500         add_subdirectory(doc)
 501         include(../Install)
 502 endif()
 503
 504
 505 message(STATUS)
 506 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 507 message(STATUS)
 508 LYX_OPTION_LIST_ALL()
 509
 510
 511 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 512 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 513 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 514
 515 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 516 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 517
 518 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 519
 520 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 521 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 522 #
 523 # needed by rpm
 524 set(CPACK_SET_DESTDIR "ON")
 525 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 526 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 527 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 528 #
 529 # the next ones are needed by deb
 530 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 531 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 532
 533 # This is experimental, valid on _my_ system (Kornel)
 534 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 535 if(ASPELL_FOUND)
 536         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 537 endif()
 538 if(ENCHANT_FOUND)
 539         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 540 endif()
 541 if(LYX_EXTERNAL_BOOST)
 542         if(Boost_FOUND)
 543                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 544         endif()
 545 endif()
 546 #
 547 # for the next ones, cpack insists on data with values in some file
 548 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 549 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 550
 551 # Find the revision number and use it as the release in rpm-package-build.
 552 # This way we may omit the otherwise needed "--force" parameter when
 553 # installing from that rpm package.
 554 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 555 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 556 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 557         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 558         # We use this value also to set the package-patch-value
 559         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 560                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 561         endif()
 562 endif()
 563
 564 # we do not have a readme or welcome data,
 565 # so we do not provide infofiles for
 566 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 567
 568 if(LYX_CPACK)
 569         include(CPack)
 570 endif()
 571
 572 #Now it is possible to create some packages
 573 # cd <BuildDir>
 574 # make package
 575 #############################################################################################
 576 # So, e.g. for variables
 577 #    CMAKE_PROJECT_NAME                     : lyx
 578 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 579 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 580 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 581 #    CMAKE_SYSTEM_NAME                      : Linux
 582 #    CPACK_BINARY_DEB:BOOL                  : ON
 583 #
 584 # the package name builds as "lyx-2.0.1-Linux.deb"
 585 #
 586 ############################## rpm ################################### deb ##################
 587 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 588 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 589 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 590 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 591 #
 592 message(STATUS)