development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  40 if(LYX_CPACK)
  41         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  42 endif()
  43
  44 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  45 if(LYX_INSTALL)
  46         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  47         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  48         if (WIN32)
  49                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  50         endif()
  51         set(LYX_CONSOLE OFF CACHE BOOL "No console option" FORCE)
  52         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  53         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  54         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  55 endif()
  56
  57 # Options for all compilers/systems
  58 LYX_OPTION(NLS "Use nls" OFF ALL)
  59 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  60 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  61 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  62 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  63 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  64 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  65 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  66 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  67 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  68 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  69 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  70 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  71
  72 # GCC specific
  73 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  74 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  75 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  76 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  77 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  78 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  79 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  80
  81 # MSVC specific
  82 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  83 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  84 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  85 LYX_OPTION(LYX_CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  86
  87
  88 message(STATUS)
  89
  90 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  91 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  92
  93
  94
  95 if(UNIX OR MINGW)
  96         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  97         message(STATUS "Using GCC version ${GCC_VERSION}")
  98         if(NOT GCC_VERSION VERSION_LESS 4.4)
  99                 set(LYX_USE_TR1 1)
 100                 # GCC <= 4.5 does not support regex: there are linker errors
 101                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 102                 set(LYX_USE_TR1_REGEX 0)
 103         endif()
 104 else()
 105         if(MSVC10)
 106                 set(LYX_USE_TR1 1)
 107                 set(LYX_USE_TR1_REGEX 1)
 108         endif()
 109 endif()
 110
 111
 112 set(VERSION_INFO "CMake Build")
 113
 114 # Try to get some informations from configure.ac
 115
 116 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 117 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 118
 119 if(WIN32)
 120         set(USE_WINDOWS_PACKAGING 1)
 121 elseif(APPLE)
 122         set(USE_MACOSX_PACKAGING 1)
 123 else()
 124         set(USE_POSIX_PACKAGING 1)
 125 endif()
 126
 127 macro(setstripped _varname _value)
 128         string(STRIP ${_value} _v)
 129         if(USE_POSIX_PACKAGING)
 130                 string(TOLOWER ${_v} ${_varname})
 131         else()
 132                 set(${_varname} ${_v})
 133         endif()
 134 endmacro(setstripped)
 135
 136 foreach(_c_l ${_config_lines} )
 137         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 138                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 139                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 140                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 141                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 142                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 143                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 144                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 145                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 146                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 147                 endif()
 148         endif()
 149         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 150                 set(LYX_DATE "${CMAKE_MATCH_1}")
 151         endif()
 152 endforeach(_c_l)
 153
 154
 155 if (LYX_INSTALL_PREFIX)
 156         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 157         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 158 endif()
 159
 160 if(LYX_PACKAGE_SUFFIX)
 161         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 162 else()
 163         set(PACKAGE ${PACKAGE_BASE})
 164 endif()
 165
 166 if(LYX_PROGRAM_SUFFIX)
 167         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 168 else()
 169         set(PROGRAM_SUFFIX "")
 170 endif()
 171
 172
 173 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 174         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 175         if (UNIX)
 176                 # don't use the default "/usr/local"
 177                 # but respect the user-choice on the command-line
 178                 if(LYX_INSTALL_SUFFIX)
 179                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 180                 else()
 181                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 182                 endif()
 183         endif()
 184         if(WIN32)
 185                 set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 186         endif()
 187 endif()
 188
 189 if (WIN32)
 190         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 191 else()
 192         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 193 endif()
 194
 195 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 196 set(LYX_LOCALEDIR "locale")
 197 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 198 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 199
 200
 201 if(NOT GROUP_CODE)
 202         #set(GROUP_CODE "The Golden Code")
 203         set(GROUP_CODE flat)
 204 endif()
 205
 206 # lyx's source files
 207 set(LYX_CPP_FILES *.cpp)
 208 set(LYX_HPP_FILES *.h)
 209 set(LYX_MOC_FILES moc_*.cpp)
 210
 211
 212 include(ProjectSourceGroup)
 213
 214
 215 if(LYX_PROFILE)
 216         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 217         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 218 endif()
 219
 220 if(LYX_RELEASE)
 221         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 222 else()
 223         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 224 endif()
 225
 226 # When shared libs are supported enable this option
 227 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 228 if(LYX_SHARED_LIBRARIES)
 229         set(library_type SHARED)
 230 else()
 231         set(library_type STATIC)
 232 endif()
 233
 234 if(NOT MSVC)
 235         if(NOT LYX_QUIET)
 236                 set(CMAKE_VERBOSE_MAKEFILE ON)
 237         endif()
 238         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 239         if(LYX_STDLIB_DEBUG)
 240                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 241         endif()
 242         if(LYX_CONCEPT_CHECKS)
 243                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 244         endif()
 245         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 246         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 247         if(MINGW)
 248                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 249         else()
 250                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 251         endif()
 252         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 253 endif()
 254
 255
 256 find_package(Qt4 REQUIRED)
 257 find_package(ICONV REQUIRED)
 258 find_package(ZLIB REQUIRED)
 259
 260 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 261
 262 if(LYX_ASPELL)
 263         find_package(ASPELL)
 264         include_directories(${ASPELL_INCLUDE_DIR})
 265 endif()
 266
 267 if(LYX_ENCHANT)
 268         find_package(Enchant REQUIRED)
 269         include_directories(${ENCHANT_INCLUDE_DIR})
 270 endif()
 271
 272 if(LYX_HUNSPELL)
 273         find_package(Hunspell REQUIRED)
 274         include_directories(${HUNSPELL_INCLUDE_DIR})
 275 endif()
 276
 277 if(LYX_NLS)
 278         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 279         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 280                 message(FATAL_ERROR "Python 2.6 needed!")
 281         endif()
 282         find_package(LyXGettext REQUIRED)
 283         include_directories(${TOP_SRC_DIR}/po)
 284         add_subdirectory(po)
 285 endif()
 286
 287 if(LYX_EXTERNAL_LIBINTL)
 288         find_package(Libintl REQUIRED)
 289         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 290 else()
 291         add_subdirectory(intl)
 292 endif()
 293
 294 if(LYX_EXTERNAL_BOOST)
 295         message(STATUS "Searching for boost")
 296         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 297         if(Boost_FOUND)
 298                 message(STATUS "Boost found")
 299                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 300                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 301         else()
 302                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 303         endif()
 304 else()
 305         if(LYX_USE_TR1_REGEX)
 306                 set(Lyx_Boost_Libraries boost_signals)
 307         else()
 308                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 309         endif()
 310         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 311         include_directories(${TOP_SRC_DIR}/boost)
 312         add_subdirectory(boost)
 313 endif()
 314
 315
 316
 317
 318 if(WIN32)
 319         if(NOT LYX_CONSOLE)
 320                 set(WIN32_CONSOLE WIN32)
 321                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 322         endif()
 323         if(MSVC)
 324                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 325                 # disable checked iterators for msvc release builds to get maximum speed
 326                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 327         else()
 328                 add_definitions(-DWINVER=0x0500)
 329         endif()
 330 endif()
 331
 332 message(STATUS "")
 333 foreach(_v PACKAGE PACKAGE_VERSION
 334         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 335         LYX_ABS_TOP_SRCDIR
 336         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 337         if(NOT DEFINED ${_v})
 338                 message(FATAL_ERROR "${_v} not defined")
 339         endif()
 340         string(SUBSTRING "${_v}                            " 0 28 _v1)
 341         message(STATUS "----- ${_v1}: ${${_v}}")
 342 endforeach(_v)
 343 message(STATUS "")
 344
 345
 346 if(LYX_MERGE_FILES)
 347         set(LYX_PCH OFF)
 348 else()
 349         set(LYX_MERGE_REBUILD OFF)
 350 endif()
 351
 352 if(LYX_PCH)
 353         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 354         # Not sure if it works for all non-msvc compilers
 355         include(PCHSupport_26)
 356         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 357         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 358         add_definitions(-DLYX_ENABLE_PCH)
 359
 360         if(MSVC)
 361                 macro(lyx_add_msvc_pch name_)
 362                         set_source_files_properties(${${name_}_sources} PROPERTIES
 363                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 364                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 365                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 366                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 367                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 368                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 369                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 370                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 371                 endmacro(lyx_add_msvc_pch)
 372                 macro(lyx_add_gcc_pch name_)
 373                 endmacro()
 374         else()
 375                 macro(lyx_add_msvc_pch name_)
 376                 endmacro()
 377                 macro(lyx_add_gcc_pch name_)
 378                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 379                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 380                 endmacro()
 381         endif()
 382 else()
 383         set(LYX_PCH OFF CACHE STRING "Disable precompiled headers")
 384         macro(lyx_add_msvc_pch)
 385         endmacro(lyx_add_msvc_pch)
 386         macro(lyx_add_gcc_pch name_)
 387         endmacro()
 388 endif()
 389
 390 if(MSVC)
 391         if(LYX_VLD)
 392                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 393                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 394                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 395                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 396         endif()
 397
 398         if(LYX_WALL)
 399                 # Use the highest warning level
 400                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 401
 402                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 403                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 404                 else()
 405                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 406                 endif()
 407
 408                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 409                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 410                 else()
 411                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 412                 endif()
 413
 414                 # add here warnings which should produce an error /weXXXX
 415                 set(MSVC_W_ERROR   "/we4101 /we4189")
 416                 # add here warnings which should be disabled /wdXXXX
 417                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 418
 419                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 420                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 421                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 422
 423         else()
 424                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 425
 426                 # add here warnings which should produce an error /weXXXX
 427                 set(MSVC_W_ERROR   "/we4101 /we4189")
 428                 # add here warnings which should be disabled /wdXXXX
 429                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 430
 431                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 432                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 433                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 434
 435         endif()
 436         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 437         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 438         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 439
 440         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 441         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 442         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 443         message(STATUS "")
 444 endif()
 445
 446
 447 if(LYX_DEBUG_GLIBC)
 448         set(_GLIBCXX_DEBUG 1)
 449 endif()
 450
 451 if(LYX_DEBUG_GLIBC_PEDANTIC)
 452         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 453 endif()
 454
 455 # compiler tests, config.h generation
 456 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 457         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 458 else()
 459         include(ConfigureChecks.cmake)
 460         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 461 endif()
 462
 463 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 464
 465
 466 add_subdirectory(src)
 467 add_subdirectory(lyx2lyx)
 468 add_subdirectory(scripts)
 469
 470
 471 if(LYX_INSTALL)
 472         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 473         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 474                 message(FATAL_ERROR "Perl required!")
 475         endif()
 476         add_subdirectory(man)
 477         add_subdirectory(doc)
 478         include(../Install)
 479 endif()
 480
 481
 482 message(STATUS)
 483 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 484 message(STATUS)
 485 LYX_OPTION_LIST_ALL()
 486
 487
 488 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 489 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 490 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 491
 492 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 493 #
 494 # needed by rpm
 495 set(CPACK_SET_DESTDIR "ON")
 496 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 497 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 498 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 499 #
 500 # the next ones are needed by deb
 501 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 502 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 503
 504 # This is experimental, valid on _my_ system (Kornel)
 505 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 506 if(ASPELL_FOUND)
 507         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 508 endif()
 509 if(ENCHANT_FOUND)
 510         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 511 endif()
 512 if(LYX_EXTERNAL_BOOST)
 513         if(Boost_FOUND)
 514                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 515         endif()
 516 endif()
 517 #
 518 # for the next ones, cpack insists on data with values in some file
 519 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 520 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 521
 522 # Find the revision number and use it as the release in rpm-package-build.
 523 # This way we may omit the otherwise needed "--force" parameter when
 524 # installing from that rpm package.
 525 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 526 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 527 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 528         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 529         # We use this value also to set the package-patch-value
 530         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 531                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 532         endif()
 533 endif()
 534
 535 # we do not have a readme or welcome data,
 536 # so we do not provide infofiles for
 537 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 538
 539 include(CPack)
 540
 541 #Now it is possible to create some packages
 542 # cd <BuildDir>
 543 # make package
 544 #############################################################################################
 545 # So, e.g. for variables
 546 #    CMAKE_PROJECT_NAME                     : lyx
 547 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 548 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 549 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 550 #    CMAKE_SYSTEM_NAME                      : Linux
 551 #    CPACK_BINARY_DEB:BOOL                  : ON
 552 #
 553 # the package name builds as "lyx-2.0.1-Linux.deb"
 554 #
 555 ############################## rpm ################################### deb ##################
 556 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 557 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 558 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 559 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 560 #
 561 message(STATUS)