development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif(COMMAND cmake_policy)
  15
  16 project(lyx)
  17
  18 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  19
  20 # where to look first for cmake modules,
  21 # before ${CMAKE_ROOT}/Modules is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 include(LyXMacros)
  24
  25 message(STATUS)
  26 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  27 LYX_OPTION(INSTALL "Build install projects/rules" ON)
  28 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON)
  29 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF)
  30 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF)
  31 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF)
  32 LYX_OPTION(NLS "Use nls" OFF)
  33 LYX_OPTION(ASPELL "Use aspell" OFF)
  34 LYX_OPTION(NO_CONSOLE "Suppress Console on Windows" OFF)
  35 LYX_OPTION(USE_VERSION_SUFFIX "Use version suffix for packaging" OFF)
  36 LYX_OPTION(VLD "Use VLD on with MSVC" OFF)
  37 LYX_OPTION(MERGE_FILES "Merge source files into one copilation unit" OFF)
  38 LYX_OPTION(DEBUG "Build debug version" OFF)
  39 LYX_OPTION(RELEASE "Build release" ON)
  40 LYX_OPTION(PROFILE "Enable profile build for GCC" OFF)
  41 LYX_OPTION(STDLIB_DEBUG "Use debug stdstdlib" OFF)
  42 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF)
  43 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF)
  44 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF)
  45 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON)
  46 message(STATUS)
  47
  48 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  49 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  50
  51
  52
  53 if(UNIX OR MINGW)
  54     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  55     message(STATUS "Using GCC version ${GCC_VERSION}")
  56     if(NOT GCC_VERSION VERSION_LESS 4.4)
  57         set(LYX_USE_TR1 1)
  58         # GCC <= 4.5 does not support regex: there are linker errors
  59         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  60         set(LYX_USE_TR1_REGEX 0)
  61     endif()
  62 else()
  63     if(MSVC10)
  64         set(LYX_USE_TR1 1)
  65         set(LYX_USE_TR1_REGEX 1)
  66     endif()
  67 endif()
  68
  69
  70
  71
  72
  73 # Supress regeneration
  74 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  75
  76 set(VERSION_INFO "CMake Build")
  77
  78 # Try to get some informations from configure.ac
  79
  80 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  81 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  82
  83 if(WIN32)
  84   set(USE_WINDOWS_PACKAGING 1)
  85 elseif(APPLE)
  86   set(USE_MACOSX_PACKAGING 1)
  87 else()
  88   set(USE_POSIX_PACKAGING 1)
  89 endif()
  90
  91 macro(setstripped _varname _value)
  92   string(STRIP ${_value} _v)
  93   if(USE_POSIX_PACKAGING)
  94     string(TOLOWER ${_v} ${_varname})
  95   else()
  96     set(${_varname} ${_v})
  97   endif()
  98 endmacro(setstripped)
  99
 100 foreach(_c_l ${_config_lines} )
 101   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 102     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 103     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 104     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 105     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 106       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 107       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 108       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 109       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 110       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 111     endif()
 112   endif()
 113   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 114     set(LYX_DATE "${CMAKE_MATCH_1}")
 115   endif()
 116 endforeach(_c_l)
 117
 118 if(LYX_USE_VERSION_SUFFIX)
 119   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 120   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 121 else()
 122   set(PACKAGE ${PACKAGE_BASE})
 123   set(PROGRAM_SUFFIX "")
 124 endif()
 125
 126
 127 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 128   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 129   if (UNIX)
 130     # don't use the default "/usr/local"
 131     # but respect the user-choice on the command-line
 132     SET(CMAKE_INSTALL_PREFIX
 133       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 134   endif()
 135   if(WIN32)
 136     SET(CMAKE_INSTALL_PREFIX
 137       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
 138   endif()
 139 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 140
 141 if (WIN32)
 142   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 143 else()
 144   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 145 endif()
 146
 147 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 148 set(LYX_LOCALEDIR "locale")
 149 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 150 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 151
 152
 153 if(NOT GROUP_CODE)
 154         #set(GROUP_CODE "The Golden Code")
 155         set(GROUP_CODE flat)
 156 endif()
 157
 158 # lyx's source files
 159 set(LYX_CPP_FILES *.cpp)
 160 set(LYX_HPP_FILES *.h)
 161 set(LYX_MOC_FILES moc_*.cpp)
 162
 163
 164 include(ProjectSourceGroup)
 165
 166 if(LYX_MERGE_FILES)
 167         add_definitions(-DLYX_MERGED_BUILD)
 168 endif()
 169
 170
 171 set(CMAKE_BUILD_TYPE Release)
 172
 173 if(LYX_PROFILE)
 174         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 175         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 176             CACHE TYPE STRING FORCE)
 177 endif()
 178
 179 if(LYX_RELEASE)
 180         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 181 endif()
 182
 183 if(LYX_DEBUG)
 184         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 185 endif()
 186
 187
 188
 189 if(LYX_SHARED_LIBRARIES)
 190         set(library_type SHARED)
 191 else()
 192         set(library_type STATIC)
 193 endif()
 194
 195 if(NOT MSVC)
 196         if(NOT LYX_QUIET)
 197                 set(CMAKE_VERBOSE_MAKEFILE ON)
 198         endif()
 199         set(LYX_CXX_FLAGS -Wall)
 200         if(LYX_STDLIB_DEBUG)
 201                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 202         endif()
 203         if(LYX_CONCEPT_CHECKS)
 204                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 205         endif()
 206         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 207         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 208         if(MINGW)
 209                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 210         else()
 211                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 212         endif()
 213         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 214 endif()
 215
 216
 217 find_package(Qt4 REQUIRED)
 218 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 219
 220 find_package(ZLIB REQUIRED)
 221
 222 if(LYX_ASPELL)
 223         find_package(ASPELL REQUIRED)
 224 else()
 225         find_package(ASPELL)
 226 endif()
 227
 228
 229 if(LYX_USE_EXTERNAL_LIBINTL)
 230         find_package(Libintl REQUIRED)
 231         add_definitions(-DHAVE_GETTEXT)
 232 endif()
 233
 234
 235 if(WIN32)
 236   find_library(HUNSPELL_LIBRARY "libhunspell")
 237 else()
 238   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 239   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 240 endif()
 241 if (HUNSPELL_LIBRARY)
 242   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 243 endif()
 244
 245 if (HUNSPELL_FOUND)
 246   add_definitions(-DUSE_HUNSPELL=1)
 247   message(STATUS "Building with USE_HUNSPELL")
 248 else()
 249   message(STATUS "Hunspell not found, building without hunspell support")
 250 endif()
 251
 252 if(WIN32)
 253   find_library(ENCHANT_LIBRARY "libenchant")
 254   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 255 else()
 256   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 257   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 258 endif()
 259 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 260   set(ENCHANT_FOUND TRUE)
 261   add_definitions(-DUSE_ENCHANT=1)
 262   message(STATUS "Building with USE_ENCHANT")
 263 else()
 264   message(STATUS "Enchant not found, building without enchant support")
 265 endif()
 266
 267
 268 if(LYX_NLS)
 269         add_definitions(-DENABLE_NLS=1)
 270 endif()
 271
 272 if(ASPELL_FOUND)
 273         add_definitions(-DUSE_ASPELL=1)
 274 endif()
 275
 276 if(WIN32)
 277         if(LYX_NO_CONSOLE)
 278                 set(WIN32_CONSOLE WIN32)
 279                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 280         endif()
 281         if(MSVC)
 282                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 283                 # disable checked iterators for msvc release builds to get maximum speed
 284                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 285         else()
 286                 add_definitions(-DWINVER=0x0500)
 287         endif()
 288 endif()
 289
 290 message(STATUS "")
 291 foreach(_v PACKAGE PACKAGE_VERSION
 292     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 293     LYX_ABS_TOP_SRCDIR
 294     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 295   if(NOT DEFINED ${_v})
 296     message(FATAL_ERROR "${_v} not defined")
 297   endif()
 298   string(SUBSTRING "${_v}                            " 0 28 _v1)
 299   message(STATUS "----- ${_v1}: ${${_v}}")
 300 endforeach(_v)
 301 message(STATUS "")
 302
 303
 304 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 305 # Not sure if it works for all non-msvc compilers
 306 include(PCHSupport_26)
 307
 308 if(NOT LYX_DISABLE_PCH)
 309
 310         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 311         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 312         add_definitions(-DLYX_ENABLE_PCH)
 313
 314         if(MSVC AND NOT MERGE_FILES)
 315                 macro(lyx_add_msvc_pch name_)
 316                         set_source_files_properties(${${name_}_sources} PROPERTIES
 317                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 318                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 319                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 320                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 321                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 322                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 323                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 324                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 325                 endmacro(lyx_add_msvc_pch)
 326                 macro(lyx_add_gcc_pch name_)
 327                 endmacro()
 328         else()
 329                 macro(lyx_add_msvc_pch name_)
 330                 endmacro()
 331                 macro(lyx_add_gcc_pch name_)
 332                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 333                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 334                 endmacro()
 335         endif()
 336 else()
 337         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 338         macro(lyx_add_msvc_pch)
 339         endmacro(lyx_add_msvc_pch)
 340         macro(lyx_add_gcc_pch name_)
 341         endmacro()
 342 endif()
 343
 344 if(MSVC)
 345        if(LYX_VLD)
 346                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 347                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 348                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 349                include(${vld_path}/tools/cmake/vld.cmake)
 350        endif()
 351
 352         # TODO options
 353         if(WALL)
 354                 set(WALL 1 CACHE TYPE STRING FORCE)
 355
 356                 # Use the highest warning level
 357                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 358                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 359
 360                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 361                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 362                 else()
 363                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 364                 endif()
 365
 366                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 367                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 368                 else()
 369                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 370                 endif()
 371
 372                 # add here warnings which should produce an error /weXXXX
 373                 set(MSVC_W_ERROR   "/we4101 /we4189")
 374                 # add here warnings which should be disabled /wdXXXX
 375                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 376
 377                 set(CMAKE_CXX_FLAGS_DEBUG
 378                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 379                 set(CMAKE_CXX_FLAGS_RELEASE
 380                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 381                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 382                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 383
 384         else()
 385                 set(WALL 0 CACHE TYPE STRING FORCE)
 386
 387                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 388                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 389
 390                 # add here warnings which should produce an error /weXXXX
 391                 set(MSVC_W_ERROR   "/we4101 /we4189")
 392                 # add here warnings which should be disabled /wdXXXX
 393                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 394
 395                 set(CMAKE_CXX_FLAGS_DEBUG
 396                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 397                 set(CMAKE_CXX_FLAGS_RELEASE
 398                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 399                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 400                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 401
 402         endif()
 403         set(CMAKE_CXX_FLAGS_DEBUG
 404                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 405         set(CMAKE_CXX_FLAGS_RELEASE
 406                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 407         set(CMAKE_CXX_FLAGS_MINSIZEREL
 408                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 409
 410         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 411         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 412         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 413         message(STATUS "")
 414
 415 endif()
 416
 417
 418 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 419 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 420     if(LYX_NLS)
 421       find_package(LyXGettext REQUIRED)
 422       include_directories(${TOP_SRC_DIR}/po)
 423       add_subdirectory(po)
 424     endif()
 425 endif()
 426
 427
 428
 429 if(LYX_DEBUG_GLIBC)
 430   set(_GLIBCXX_DEBUG 1)
 431 endif()
 432
 433 if(LYX_DEBUG_GLIBC_PEDANTIC)
 434   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 435 endif()
 436
 437 # compiler tests, config.h generation
 438 if(MSVC AND NOT CONFIGURECHECKS)
 439         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 440 else()
 441         include(ConfigureChecks.cmake)
 442         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 443 endif()
 444
 445 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 446
 447 find_package(ICONV REQUIRED)
 448 add_definitions(-DHAVE_ICONV=1)
 449
 450
 451 include_directories(
 452   ${CMAKE_BINARY_DIR}
 453   ${TOP_SRC_DIR}/src)
 454
 455
 456 if(LYX_USE_EXTERNAL_BOOST)
 457   message(STATUS "Searching for boost")
 458   find_package(Boost COMPONENTS signals regex)
 459   if(Boost_FOUND)
 460     message(STATUS "Boost found")
 461     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 462     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 463   else()
 464     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 465   endif()
 466 else()
 467   if(LYX_USE_TR1_REGEX)
 468     set(Lyx_Boost_Libraries boost_signals)
 469   else()
 470     set(Lyx_Boost_Libraries boost_signals boost_regex)
 471   endif()
 472   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 473   include_directories(${TOP_SRC_DIR}/boost)
 474   add_subdirectory(boost)
 475 endif()
 476
 477
 478 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 479   add_subdirectory(intl)
 480 endif()
 481 add_subdirectory(src)
 482
 483 if(LYX_INSTALL)
 484         add_subdirectory(man)
 485         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 486                 add_subdirectory(doc)
 487         endif()
 488 endif()
 489 add_subdirectory(lyx2lyx)
 490 add_subdirectory(scripts)
 491
 492 if(LYX_INSTALL)
 493         include(../Install)
 494 endif()
 495
 496 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 497 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 498 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 499
 500 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 501 #
 502 # needed by rpm
 503 SET(CPACK_SET_DESTDIR "ON")
 504 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 505 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 506 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 507 #
 508 # the next ones are needed by deb
 509 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 510 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 511
 512 # This is experimental, valid on _my_ system (Kornel)
 513 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 514 IF(ASPELL_FOUND)
 515   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 516 ENDIF()
 517 #
 518 # for the next ones, cpack insists on data with values in some file
 519 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 520 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 521
 522 # Find the revision number and use it as the release in rpm-package-build.
 523 # This way we may omit the otherwise needed "--force" parameter when
 524 # installing from that rpm package.
 525 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 526 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 527 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 528   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 529   # We use this value also to set the package-patch-value
 530   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 531     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 532   endif()
 533 endif()
 534
 535 # we do not have a readme or welcome data,
 536 # so we do not provide infofiles for
 537 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 538
 539 if(LYX_INSTALL)
 540         include(CPack)
 541 endif()
 542
 543 #Now it is possible to create some packages
 544 # cd <BuildDir>
 545 # make package
 546 #############################################################################################
 547 # So, e.g. for variables
 548 #    CMAKE_PROJECT_NAME                     : lyx
 549 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 550 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 551 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 552 #    CMAKE_SYSTEM_NAME                      : Linux
 553 #    CPACK_BINARY_DEB:BOOL                  : ON
 554 #
 555 # the package name builds as "lyx-2.0.1-Linux.deb"
 556 #
 557 ############################## rpm ################################### deb ##################
 558 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 559 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 560 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 561 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 562 #
 563 message(STATUS)