development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif(COMMAND cmake_policy)
  15
  16 project(lyx)
  17
  18 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  19
  20 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  21 # is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  24 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  25
  26 option(LYX_DEBUG_GLIBC "Enable libstdc++ debug mode" OFF)
  27 option(LYX_DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF)
  28 option(LYX_INSTALL "Build install projects/rules" ON)
  29 option(LYX_USE_VERSION_SUFFIX "Using executables with versioned suffix" OFF)
  30 option(LYX_ASPELL "Use aspell library" OFF)
  31 option(LYX_NLS "Enable build with nls support" OFF)
  32 option(LYX_USE_EXTERNAL_BOOST "Use external boost" OFF)
  33 option(LYX_DISABLE_PCH "Disable precompiled headers" ON)
  34
  35 if(UNIX OR MINGW)
  36     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  37     message(STATUS "Using GCC version ${GCC_VERSION}")
  38     if(NOT GCC_VERSION VERSION_LESS 4.4)
  39         set(LYX_USE_TR1 1)
  40         # GCC <= 4.5 does not support regex: there are linker errors
  41         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  42         set(LYX_USE_TR1_REGEX 0)
  43     endif()
  44 else()
  45     if(MSVC10)
  46         set(LYX_USE_TR1 1)
  47         set(LYX_USE_TR1_REGEX 1)
  48     endif()
  49 endif()
  50
  51
  52
  53
  54
  55 # Supress regeneration
  56 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  57
  58 set(VERSION_INFO "CMake Build")
  59
  60 # Try to get some informations from configure.ac
  61
  62 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  63 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  64
  65 if(WIN32)
  66   set(USE_WINDOWS_PACKAGING 1)
  67 elseif(APPLE)
  68   set(USE_MACOSX_PACKAGING 1)
  69 else()
  70   set(USE_POSIX_PACKAGING 1)
  71 endif()
  72
  73 macro(setstripped _varname _value)
  74   string(STRIP ${_value} _v)
  75   if(USE_POSIX_PACKAGING)
  76     string(TOLOWER ${_v} ${_varname})
  77   else()
  78     set(${_varname} ${_v})
  79   endif()
  80 endmacro(setstripped)
  81
  82 foreach(_c_l ${_config_lines} )
  83   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  84     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  85     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  86     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  87     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  88       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  89       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  90       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  91       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  92       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  93     endif()
  94   endif()
  95   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  96     set(LYX_DATE "${CMAKE_MATCH_1}")
  97   endif()
  98 endforeach(_c_l)
  99
 100 if(LYX_USE_VERSION_SUFFIX)
 101   message(STATUS "-- Using versioned PACKAGE. Disable with -DLYX_USE_VERSION_SUFFIX=OFF")
 102   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 103   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 104 else()
 105   message(STATUS "-- PACKAGE not versioned, to enable use -DLYX_USE_VERSION_SUFFIX=ON")
 106   set(PACKAGE ${PACKAGE_BASE})
 107   set(PROGRAM_SUFFIX "")
 108 endif()
 109
 110
 111 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 112   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 113   if (UNIX)
 114     # don't use the default "/usr/local"
 115     # but respect the user-choice on the command-line
 116     SET(CMAKE_INSTALL_PREFIX
 117       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 118   endif()
 119   if(WIN32)
 120     SET(CMAKE_INSTALL_PREFIX
 121       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
 122   endif()
 123 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 124
 125 if (WIN32)
 126   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 127 else()
 128   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 129 endif()
 130
 131 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 132 set(LYX_LOCALEDIR "locale")
 133 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 134 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 135
 136
 137 if(NOT GROUP_CODE)
 138         #set(GROUP_CODE "The Golden Code")
 139         set(GROUP_CODE flat)
 140 endif()
 141
 142 # lyx's source files
 143 set(LYX_CPP_FILES *.cpp)
 144 set(LYX_HPP_FILES *.h)
 145 set(LYX_MOC_FILES moc_*.cpp)
 146
 147 include(LyXMacros)
 148 include(ProjectSourceGroup)
 149
 150 if(merge OR merge_rebuild)
 151         set(merge 1 CACHE TYPE STRING FORCE)
 152         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 153         message(STATUS "")
 154         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 155         message(STATUS "")
 156         add_definitions(-DLYX_MERGED_BUILD)
 157 else()
 158         set(merge 0 CACHE TYPE STRING FORCE)
 159         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 160         message(STATUS "Enable merging files with -Dmerge=1")
 161 endif()
 162
 163
 164 set(CMAKE_BUILD_TYPE Release)
 165
 166 if(profile)
 167         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 168         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 169             CACHE TYPE STRING FORCE)
 170         set(profile)
 171 endif()
 172
 173 if(release)
 174         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 175         set(release TRUE CACHE TYPE STRING FORCE)
 176         set(release)
 177 endif()
 178
 179 if(debug)
 180         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 181         set(debug TRUE CACHE TYPE STRING FORCE)
 182         set(debug)
 183 endif()
 184
 185 if(shared)
 186         set(library_type SHARED)
 187         message(STATUS "building shared libraries")
 188 else()
 189         set(library_type STATIC)
 190 endif()
 191
 192 if(NOT MSVC)
 193         if(NOT quiet)
 194                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 195                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 196                 message(STATUS "")
 197         else()
 198                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 199         endif()
 200         set(LYX_CXX_FLAGS -Wall)
 201         if(stdlib-debug)
 202                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 203         endif()
 204         if(concept-checks)
 205                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 206         endif()
 207         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 208         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 209         if(MINGW)
 210                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 211         else()
 212                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 213         endif()
 214         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 215 endif()
 216
 217
 218 find_package(Qt4 REQUIRED)
 219 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 220
 221 find_package(ZLIB REQUIRED)
 222
 223 if(all OR LYX_ASPELL)
 224         set(LYX_ASPELL TRUE CACHE TYPE STRING)
 225         find_package(ASPELL REQUIRED)
 226 else()
 227         find_package(ASPELL)
 228 endif()
 229 set(LYX_ASPELL)
 230
 231 set(use_external_libintl TRUE)
 232
 233 if(use_external_libintl)
 234         find_package(Libintl REQUIRED)
 235         add_definitions(-DHAVE_GETTEXT)
 236 endif()
 237
 238 if(WIN32)
 239   find_library(HUNSPELL_LIBRARY "libhunspell")
 240 else()
 241   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 242   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 243 endif()
 244 if (HUNSPELL_LIBRARY)
 245   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 246 endif()
 247
 248 if (HUNSPELL_FOUND)
 249   add_definitions(-DUSE_HUNSPELL=1)
 250   message(STATUS "----- Building with USE_HUNSPELL")
 251 else()
 252   message(STATUS "----- Hunspell not found, building without hunspell support")
 253 endif()
 254
 255 if(WIN32)
 256   find_library(ENCHANT_LIBRARY "libenchant")
 257   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 258 else()
 259   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 260   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 261 endif()
 262 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 263   set(ENCHANT_FOUND TRUE)
 264   add_definitions(-DUSE_ENCHANT=1)
 265   message(STATUS "----- Building with USE_ENCHANT")
 266 else()
 267   message(STATUS "----- Enchant not found, building without enchant support")
 268 endif()
 269
 270 message(STATUS "")
 271 if(LYX_NLS OR all)
 272         set(LYX_NLS TRUE CACHE TYPE STRING)
 273         add_definitions(-DENABLE_NLS=1)
 274         message(STATUS "----- Building with ENABLE_NLS")
 275 else()
 276         message(STATUS "----- No nls, to enable use -DLYX_NLS=1")
 277 endif()
 278 set(LYX_NLS)
 279 if(ASPELL_FOUND)
 280         add_definitions(-DUSE_ASPELL=1)
 281         message(STATUS "----- Building with USE_ASPELL")
 282 else()
 283         message(STATUS "----- No aspell, to get more information use -DLYX_ASPELL=ON")
 284 endif()
 285 set(all)
 286
 287 if(WIN32)
 288         option(LYX_NO_CONSOLE "Compile LyX as a GUI" OFF)
 289         if(LYX_NO_CONSOLE)
 290                 set(LYX_NO_CONSOLE TRUE CACHE TYPE STRING)
 291                 set(WIN32_CONSOLE WIN32)
 292                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 293                 message(STATUS "----- Console disabled")
 294         else()
 295                 message(STATUS "----- Console enabled, disable it with -DLYX_NO_CONSOLE=ON")
 296         endif()
 297         if(MSVC)
 298                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 299                 # disable checked iterators for msvc release builds to get maximum speed
 300                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 301         else()
 302                 add_definitions(-DWINVER=0x0500)
 303         endif()
 304 endif()
 305
 306 message(STATUS "")
 307 foreach(_v PACKAGE PACKAGE_VERSION
 308     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 309     LYX_ABS_TOP_SRCDIR
 310     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 311   if(NOT DEFINED ${_v})
 312     message(FATAL_ERROR "${_v} not defined")
 313   endif()
 314   string(SUBSTRING "${_v}                            " 0 28 _v1)
 315   message(STATUS "----- ${_v1}: ${${_v}}")
 316 endforeach(_v)
 317 message(STATUS "")
 318
 319
 320 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 321 # Not sure if it works for all non-msvc compilers
 322 include(PCHSupport_26)
 323
 324 if(NOT LYX_DISABLE_PCH)
 325
 326         message(STATUS "-----")
 327         message(STATUS "----- using precompiled headers, disable with -DLYX_DISABLE_PCH=1")
 328         message(STATUS "-----")
 329         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 330         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 331         add_definitions(-DLYX_ENABLE_PCH)
 332
 333         if(MSVC AND NOT MERGE_FILES)
 334                 macro(lyx_add_msvc_pch name_)
 335                         set_source_files_properties(${${name_}_sources} PROPERTIES
 336                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 337                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 338                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 339                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 340                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 341                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 342                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 343                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 344                 endmacro(lyx_add_msvc_pch)
 345                 macro(lyx_add_gcc_pch name_)
 346                 endmacro()
 347         else()
 348                 macro(lyx_add_msvc_pch name_)
 349                 endmacro()
 350                 macro(lyx_add_gcc_pch name_)
 351                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 352                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 353                 endmacro()
 354         endif()
 355 else()
 356         if(MSVC)
 357                 message(STATUS "-----")
 358                 message(STATUS "----- precompiled headers disabled, enable with -DLYX_DISABLE_PCH=0")
 359                 message(STATUS "-----")
 360         endif()
 361         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 362         macro(lyx_add_msvc_pch)
 363         endmacro(lyx_add_msvc_pch)
 364         macro(lyx_add_gcc_pch name_)
 365         endmacro()
 366 endif()
 367
 368 if(MSVC)
 369        if(vld)
 370                set(vld 1 CACHE TYPE STRING FORCE)
 371                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 372                message(STATUS "")
 373                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 374                message(STATUS "")
 375                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 376                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 377                include(${vld_path}/tools/cmake/vld.cmake)
 378        else()
 379                set(vld 0 CACHE TYPE STRING FORCE)
 380                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 381                message(STATUS "")
 382                message(STATUS "Enable leak detection with -Dvld=1")
 383                message(STATUS "")
 384        endif()
 385
 386         if(WALL)
 387                 set(WALL 1 CACHE TYPE STRING FORCE)
 388
 389                 # Use the highest warning level
 390                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 391                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 392
 393                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 394                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 395                 else()
 396                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 397                 endif()
 398
 399                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 400                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 401                 else()
 402                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 403                 endif()
 404
 405                 # add here warnings which should produce an error /weXXXX
 406                 set(MSVC_W_ERROR   "/we4101 /we4189")
 407                 # add here warnings which should be disabled /wdXXXX
 408                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 409
 410                 set(CMAKE_CXX_FLAGS_DEBUG
 411                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 412                 set(CMAKE_CXX_FLAGS_RELEASE
 413                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 414                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 415                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 416
 417         else()
 418                 set(WALL 0 CACHE TYPE STRING FORCE)
 419
 420                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 421                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 422
 423                 # add here warnings which should produce an error /weXXXX
 424                 set(MSVC_W_ERROR   "/we4101 /we4189")
 425                 # add here warnings which should be disabled /wdXXXX
 426                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 427
 428                 set(CMAKE_CXX_FLAGS_DEBUG
 429                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 430                 set(CMAKE_CXX_FLAGS_RELEASE
 431                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 432                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 433                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 434
 435         endif()
 436         set(CMAKE_CXX_FLAGS_DEBUG
 437                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 438         set(CMAKE_CXX_FLAGS_RELEASE
 439                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 440         set(CMAKE_CXX_FLAGS_MINSIZEREL
 441                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 442
 443         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 444         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 445         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 446         message(STATUS "")
 447
 448 endif()
 449
 450
 451 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 452 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 453     if(LYX_NLS OR all)
 454       find_package(LyXGettext REQUIRED)
 455       include_directories(${TOP_SRC_DIR}/po)
 456       add_subdirectory(po)
 457     endif()
 458 endif()
 459
 460 if(LYX_DEBUG_GLIBC)
 461   set(_GLIBCXX_DEBUG 1)
 462 endif()
 463
 464 if(LYX_DEBUG_GLIBC_PEDANTIC)
 465   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 466 endif()
 467
 468 # compiler tests, config.h generation
 469 if(MSVC AND NOT CONFIGURECHECKS)
 470         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 471 else()
 472         include(ConfigureChecks.cmake)
 473         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 474 endif()
 475
 476 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 477
 478 find_package(ICONV REQUIRED)
 479 add_definitions(-DHAVE_ICONV=1)
 480
 481
 482 include_directories(
 483   ${CMAKE_BINARY_DIR}
 484   ${TOP_SRC_DIR}/src)
 485
 486 if(LYX_USE_EXTERNAL_BOOST)
 487   message(STATUS "Searching for boost")
 488   find_package(Boost COMPONENTS signals regex)
 489   if(Boost_FOUND)
 490     message(STATUS "Boost found")
 491     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 492     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 493   else()
 494     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 495   endif()
 496 else()
 497   message(STATUS "----- Using internal boost. To build with installed version use -DLYX_USE_EXTERNAL_BOOST:BOOL=ON")
 498   if(LYX_USE_TR1_REGEX)
 499     set(Lyx_Boost_Libraries boost_signals)
 500   else()
 501     set(Lyx_Boost_Libraries boost_signals boost_regex)
 502   endif()
 503   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 504   include_directories(${TOP_SRC_DIR}/boost)
 505   add_subdirectory(boost)
 506 endif()
 507
 508
 509 if(NOT use_external_libintl)
 510   add_subdirectory(intl)
 511 endif()
 512 add_subdirectory(src)
 513
 514 if(LYX_INSTALL)
 515         add_subdirectory(man)
 516         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 517                 add_subdirectory(doc)
 518         endif()
 519 endif()
 520 add_subdirectory(lyx2lyx)
 521 add_subdirectory(scripts)
 522
 523 if(LYX_INSTALL)
 524         include(../Install)
 525 endif()
 526
 527 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 528 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 529 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 530
 531 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 532 #
 533 # needed by rpm
 534 SET(CPACK_SET_DESTDIR "ON")
 535 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 536 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 537 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 538 #
 539 # the next ones are needed by deb
 540 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 541 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 542
 543 # This is experimental, valid on _my_ system (Kornel)
 544 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 545 IF(ASPELL_FOUND)
 546   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 547 ENDIF()
 548 #
 549 # for the next ones, cpack insists on data with values in some file
 550 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 551 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 552
 553 # Find the revision number and use it as the release in rpm-package-build.
 554 # This way we may omit the otherwise needed "--force" parameter when
 555 # installing from that rpm package.
 556 FIND_PROGRAM(_svnversion svnversion)
 557 message(STATUS "svnversion = ${_svnversion}")
 558 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 559   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 560   # We use this value also to set the package-patch-value
 561   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 562     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 563   endif()
 564 endif()
 565
 566 # we do not have a readme or welcome data,
 567 # so we do not provide infofiles for
 568 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 569
 570 if(LYX_INSTALL)
 571         include(CPack)
 572 endif()
 573
 574 #Now it is possible to create some packages
 575 # cd <BuildDir>
 576 # make package
 577 #############################################################################################
 578 # So, e.g. for variables
 579 #    CMAKE_PROJECT_NAME                     : lyx
 580 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 581 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 582 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 583 #    CMAKE_SYSTEM_NAME                      : Linux
 584 #    CPACK_BINARY_DEB:BOOL                  : ON
 585 #
 586 # the package name builds as "lyx-2.0.1-Linux.deb"
 587 #
 588 ############################## rpm ################################### deb ##################
 589 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 590 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 591 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 592 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 593 #