development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  10
  11 project(lyx)
  12
  13 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  14 # is checked
  15 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  16 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  17
  18 # Supress regeneration
  19 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  20
  21 set(PACKAGE lyx)
  22 set(PACKAGE_VERSION 1.6svn)
  23 set(LYX_DATE "2007/2008")
  24 #TODO
  25 set(VERSION_INFO "CMake Build")
  26
  27 set(PROGRAM_SUFFIX "")
  28 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
  29 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
  30 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
  31
  32
  33 if(WIN32)
  34         set(USE_WINDOWS_PACKAGING 1)
  35 elseif(APPLE)
  36         set(USE_MACOSX_PACKAGING 1)
  37 else()
  38         set(USE_POSIX_PACKAGING 1)
  39 endif()
  40
  41 if(NOT GROUP_CODE)
  42         #set(GROUP_CODE "The Golden Code")
  43         set(GROUP_CODE flat)
  44 endif()
  45
  46 # lyx's source files
  47 set(LYX_CPP_FILES *.cpp)
  48 set(LYX_HPP_FILES *.h)
  49
  50 include(LyXPaths)
  51 include(LyXMacros)
  52 include(ProjectSourceGroup)
  53
  54 if(merge OR merge_rebuild)
  55         set(merge 1 CACHE TYPE STRING FORCE)
  56         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  57         message(STATUS "")
  58         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  59         message(STATUS "")
  60 else()
  61         set(merge 0 CACHE TYPE STRING FORCE)
  62         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
  63         message(STATUS "Enable merging files with -Dmerge=1")
  64 endif()
  65
  66
  67 set(CMAKE_BUILD_TYPE Release)
  68
  69 if(profile)
  70         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
  71         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
  72             CACHE TYPE STRING FORCE)
  73         set(profile)
  74 endif()
  75
  76 if(release)
  77         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
  78         set(release)
  79 endif()
  80
  81 if(debug)
  82         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
  83 endif()
  84
  85 if(shared)
  86         set(library_type SHARED)
  87         message(STATUS "building shared libraries")
  88 else()
  89         set(library_type STATIC)
  90 endif()
  91
  92 if(UNIX)
  93         if(NOT quiet)
  94                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
  95                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
  96                 message(STATUS "")
  97         endif()
  98         set(LYX_CXX_FLAGS -Wall)
  99         if(stdlib-debug)
 100                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 101         endif()
 102         if(concept-checks)
 103                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 104         endif()
 105         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 106         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 107         set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 108         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 109 endif()
 110
 111
 112 find_package(Qt4 REQUIRED)
 113 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 114
 115 find_package(ZLIB REQUIRED)
 116
 117 if(all OR aspell)
 118         set(aspell TRUE CACHE TYPE STRING)
 119         find_package(ASPELL REQUIRED)
 120 else()
 121         find_package(ASPELL)
 122 endif()
 123 set(aspell)
 124
 125 if(WIN32)
 126         set(use_external_libintl TRUE)
 127 endif()
 128
 129 if(use_external_libintl)
 130         find_package(Libintl REQUIRED)
 131 endif()
 132
 133 message("")
 134 if(nls OR all)
 135         set(nls TRUE CACHE TYPE STRING)
 136         add_definitions(-DENABLE_NLS=1)
 137         message("----- Building with ENABLE_NLS")
 138 else()
 139         message("----- No nls, to enable use -Dnls=1")
 140 endif()
 141 set(nls)
 142 if(ASPELL_FOUND)
 143         add_definitions(-DUSE_ASPELL=1)
 144         message("----- Building with USE_ASPELL")
 145 else()
 146         message("----- No aspell, to get more information use -Daspell=1")
 147 endif()
 148 set(all)
 149
 150 if(WIN32)
 151         if(noconsole)
 152                 set(noconsole TRUE CACHE TYPE STRING)
 153                 set(WIN32_CONSOLE WIN32)
 154                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 155                 message("----- Console disabled")
 156         else()
 157                 message("----- Console enabled, disable it with -Dnoconsole=1")
 158         endif()
 159 endif()
 160
 161 set(PROGRAM_SUFFIX "\"\"")
 162 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
 163 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
 164 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
 165
 166 message("")
 167 message("----- PROGRAM_SUFFIX              : ${PROGRAM_SUFFIX}")
 168 message("----- LYX_ABS_TOP_SRCDIR          : ${LYX_ABS_TOP_SRCDIR}")
 169 message("----- LYX_ABS_INSTALLED_DATADIR   : ${LYX_ABS_INSTALLED_DATADIR}")
 170 message("----- LYX_ABS_INSTALLED_LOCALEDIR : ${LYX_ABS_INSTALLED_LOCALEDIR}")
 171 message("")
 172
 173 if(MSVC)
 174         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 175         # disable checked iterators for msvc release builds to get maximum speed
 176         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 177 endif()
 178
 179 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 180
 181 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 182         message("-----")
 183         message("----- using precompiled headers, disable with -Ddisable-pch=1")
 184         message("-----")
 185         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 186                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 187         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 188                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 189         macro(lyx_add_msvc_pch name_)
 190                 set_source_files_properties(${${name_}_sources} PROPERTIES
 191                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 192                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 193                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 194                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 195                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 196                 add_definitions(/DLYX_ENABLE_PCH)
 197         endmacro(lyx_add_msvc_pch)
 198         set(CMAKE_CXX_FLAGS_DEBUG
 199                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 200         set(CMAKE_CXX_FLAGS_RELEASE
 201                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 202         set(CMAKE_CXX_FLAGS_MINSIZEREL
 203                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 204 else()
 205         if(MSVC)
 206                 message("-----")
 207                 message("----- precompiled headers disabled, enable with -Ddisable-pch=0")
 208                 message("-----")
 209         endif()
 210         set(disable-pch TRUE CACHE TYPE STRING)
 211         macro(lyx_add_msvc_pch)
 212         endmacro(lyx_add_msvc_pch)
 213 endif()
 214
 215 if(MSVC)
 216        if(vld)
 217                set(vld 1 CACHE TYPE STRING FORCE)
 218                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 219                message(STATUS "")
 220                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 221                message(STATUS "")
 222                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 223                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 224                include(${vld_path}/tools/cmake/vld.cmake)
 225        else()
 226                set(vld 0 CACHE TYPE STRING FORCE)
 227                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 228                message(STATUS "")
 229                message(STATUS "Enable leak detection with -Dvld=1")
 230                message(STATUS "")
 231        endif()
 232
 233         if(WALL)
 234                 set(WALL 1 CACHE TYPE STRING FORCE)
 235
 236                 # Use the highest warning level
 237                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 238                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 239
 240                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 241                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 242                 else()
 243                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 244                 endif()
 245
 246                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 247                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 248                 else()
 249                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 250                 endif()
 251
 252                 # add here warnings which should produce an error /weXXXX
 253                 set(MSVC_W_ERROR   "/we4101 /we4189")
 254                 # add here warnings which should be disabled /wdXXXX
 255                 set(MSVC_W_DISABLE "/wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 256
 257                 set(CMAKE_CXX_FLAGS_DEBUG
 258                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 259                 set(CMAKE_CXX_FLAGS_RELEASEs
 260                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 261                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 262                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 263
 264         else()
 265                 set(WALL 0 CACHE TYPE STRING FORCE)
 266
 267                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 268                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 269
 270                 # add here warnings which should produce an error /weXXXX
 271                 set(MSVC_W_ERROR   "/we4101 /we4189")
 272                 # add here warnings which should be disabled /wdXXXX
 273                 set(MSVC_W_DISABLE "/wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 274
 275                 set(CMAKE_CXX_FLAGS_DEBUG
 276                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 277                 set(CMAKE_CXX_FLAGS_RELEASE
 278                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 279                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 280                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 281
 282         endif()
 283
 284         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 285         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 286         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 287         message("")
 288
 289 endif()
 290
 291 # compiler tests, config.h generation
 292 if(UNIX OR CONFIGURECHECKS)
 293         include(ConfigureChecks.cmake)
 294         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 295 else()
 296         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 297 endif()
 298 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 299
 300
 301 find_package(ICONV REQUIRED)
 302 add_definitions(-DHAVE_ICONV=1)
 303
 304
 305 #TODO: insource is not the best place
 306 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 307                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 308
 309 include_directories(
 310         ${CMAKE_BINARY_DIR}
 311         ${TOP_SRC_DIR}/src
 312         ${TOP_SRC_DIR}/boost)
 313
 314 add_subdirectory(boost)
 315 if(NOT use_external_libintl)
 316         add_subdirectory(intl)
 317 endif()
 318 add_subdirectory(src)
 319
 320 include(../Install)
 321