development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif(COMMAND cmake_policy)
  15
  16 project(lyx)
  17
  18 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  19
  20 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  21 # is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  24 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  25
  26
  27 option(lyxinstall "Build install projects/rules" ON)
  28
  29
  30 if(UNIX)
  31     # GCC does not support regex: there are linker errors
  32     # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  33     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  34     if(GCC_VERSION VERSION_GREATER 4.4)
  35         set(LYX_USE_TR1_REGEX 0)
  36         add_definitions(-DLYX_USE_TR1)
  37     endif()
  38 else()
  39     if(MSVC10)
  40         set(LYX_USE_TR1_REGEX 1)
  41         add_definitions(-DLYX_USE_TR1)
  42         add_definitions(-DLYX_USE_TR1_REGEX)
  43     endif()
  44 endif()
  45
  46
  47
  48
  49
  50 # Supress regeneration
  51 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  52
  53 set(VERSION_INFO "CMake Build")
  54
  55 # Try to get some informations from configure.ac
  56
  57 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  58 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  59
  60 if(WIN32)
  61   set(USE_WINDOWS_PACKAGING 1)
  62 elseif(APPLE)
  63   set(USE_MACOSX_PACKAGING 1)
  64 else()
  65   set(USE_POSIX_PACKAGING 1)
  66 endif()
  67
  68 macro(setstripped _varname _value)
  69   string(STRIP ${_value} _v)
  70   if(USE_POSIX_PACKAGING)
  71     string(TOLOWER ${_v} ${_varname})
  72   else()
  73     set(${_varname} ${_v})
  74   endif()
  75 endmacro(setstripped)
  76
  77 foreach(_c_l ${_config_lines} )
  78   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  79     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  80     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  81     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  82     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  83       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  84       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  85       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  86       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  87       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  88     endif()
  89   endif()
  90   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  91     set(LYX_DATE "${CMAKE_MATCH_1}")
  92   endif()
  93 endforeach(_c_l)
  94
  95 if(UseVersionSuffix)
  96   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  97   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  98   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  99 else()
 100   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
 101   set(PACKAGE ${PACKAGE_BASE})
 102   set(PROGRAM_SUFFIX "")
 103 endif()
 104
 105 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 106   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 107   if (UNIX)
 108     # don't use the default "/usr/local"
 109     # but respect the user-choice on the command-line
 110     SET(CMAKE_INSTALL_PREFIX
 111       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 112   endif()
 113   if(WIN32)
 114     SET(CMAKE_INSTALL_PREFIX
 115       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
 116   endif()
 117 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 118
 119 if (WIN32)
 120   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 121 else()
 122   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 123 endif()
 124
 125 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 126 set(LYX_LOCALEDIR "locale")
 127 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 128 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 129
 130
 131 if(NOT GROUP_CODE)
 132         #set(GROUP_CODE "The Golden Code")
 133         set(GROUP_CODE flat)
 134 endif()
 135
 136 # lyx's source files
 137 set(LYX_CPP_FILES *.cpp)
 138 set(LYX_HPP_FILES *.h)
 139 set(LYX_MOC_FILES moc_*.cpp)
 140
 141 include(LyXMacros)
 142 include(ProjectSourceGroup)
 143
 144 if(merge OR merge_rebuild)
 145         set(merge 1 CACHE TYPE STRING FORCE)
 146         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 147         message(STATUS "")
 148         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 149         message(STATUS "")
 150         add_definitions(-DLYX_MERGED_BUILD)
 151 else()
 152         set(merge 0 CACHE TYPE STRING FORCE)
 153         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 154         message(STATUS "Enable merging files with -Dmerge=1")
 155 endif()
 156
 157
 158 set(CMAKE_BUILD_TYPE Release)
 159
 160 if(profile)
 161         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 162         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 163             CACHE TYPE STRING FORCE)
 164         set(profile)
 165 endif()
 166
 167 if(release)
 168         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 169         set(release TRUE CACHE TYPE STRING FORCE)
 170         set(release)
 171 endif()
 172
 173 if(debug)
 174         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 175         set(debug TRUE CACHE TYPE STRING FORCE)
 176         set(debug)
 177 endif()
 178
 179 if(shared)
 180         set(library_type SHARED)
 181         message(STATUS "building shared libraries")
 182 else()
 183         set(library_type STATIC)
 184 endif()
 185
 186 if(NOT MSVC)
 187         if(NOT quiet)
 188                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 189                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 190                 message(STATUS "")
 191         else()
 192                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 193         endif()
 194         set(LYX_CXX_FLAGS -Wall)
 195         if(stdlib-debug)
 196                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 197         endif()
 198         if(concept-checks)
 199                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 200         endif()
 201         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 202         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 203         if(MINGW)
 204                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 205         else()
 206                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 207         endif()
 208         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 209 endif()
 210
 211
 212 find_package(Qt4 REQUIRED)
 213 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 214
 215 find_package(ZLIB REQUIRED)
 216
 217 if(all OR aspell)
 218         set(aspell TRUE CACHE TYPE STRING)
 219         find_package(ASPELL REQUIRED)
 220 else()
 221         find_package(ASPELL)
 222 endif()
 223 set(aspell)
 224
 225 set(use_external_libintl TRUE)
 226
 227 if(use_external_libintl)
 228         find_package(Libintl REQUIRED)
 229         add_definitions(-DHAVE_GETTEXT)
 230 endif()
 231
 232 if(WIN32)
 233   find_library(HUNSPELL_LIBRARY "libhunspell")
 234 else()
 235   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 236   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 237 endif()
 238 if (HUNSPELL_LIBRARY)
 239   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 240 endif()
 241
 242 if (HUNSPELL_FOUND)
 243   add_definitions(-DUSE_HUNSPELL=1)
 244   message(STATUS "----- Building with USE_HUNSPELL")
 245 else()
 246   message(STATUS "----- Hunspell not found, building without hunspell support")
 247 endif()
 248
 249 if(WIN32)
 250   find_library(ENCHANT_LIBRARY "libenchant")
 251   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 252 else()
 253   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 254   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 255 endif()
 256 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 257   set(ENCHANT_FOUND TRUE)
 258   add_definitions(-DUSE_ENCHANT=1)
 259   message(STATUS "----- Building with USE_ENCHANT")
 260 else()
 261   message(STATUS "----- Enchant not found, building without enchant support")
 262 endif()
 263
 264 message(STATUS "")
 265 if(nls OR all)
 266         set(nls TRUE CACHE TYPE STRING)
 267         add_definitions(-DENABLE_NLS=1)
 268         message(STATUS "----- Building with ENABLE_NLS")
 269 else()
 270         message(STATUS "----- No nls, to enable use -Dnls=1")
 271 endif()
 272 set(nls)
 273 if(ASPELL_FOUND)
 274         add_definitions(-DUSE_ASPELL=1)
 275         message(STATUS "----- Building with USE_ASPELL")
 276 else()
 277         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 278 endif()
 279 set(all)
 280
 281 if(WIN32)
 282         if(noconsole)
 283                 set(noconsole TRUE CACHE TYPE STRING)
 284                 set(WIN32_CONSOLE WIN32)
 285                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 286                 message(STATUS "----- Console disabled")
 287         else()
 288                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 289         endif()
 290         if(MSVC)
 291                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 292                 # disable checked iterators for msvc release builds to get maximum speed
 293                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 294         else()
 295                 add_definitions(-DWINVER=0x0500)
 296         endif()
 297 endif()
 298
 299 message(STATUS "")
 300 foreach(_v PACKAGE PACKAGE_VERSION
 301     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 302     LYX_ABS_TOP_SRCDIR
 303     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 304   if(NOT DEFINED ${_v})
 305     message(FATAL_ERROR "${_v} not defined")
 306   endif()
 307   string(SUBSTRING "${_v}                            " 0 28 _v1)
 308   message(STATUS "----- ${_v1}: ${${_v}}")
 309 endforeach(_v)
 310 message(STATUS "")
 311
 312
 313 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 314 # Not sure if it works for all non-msvc compilers
 315 include(PCHSupport_26)
 316 if (MSVC)
 317         option(disable-pch "Disable precompiled headers" ON)
 318 else()
 319         option(disable-pch "Disable precompiled headers" ON)
 320 endif()
 321
 322 if(NOT disable-pch)
 323
 324         message(STATUS "-----")
 325         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 326         message(STATUS "-----")
 327         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 328         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 329         add_definitions(-DLYX_ENABLE_PCH)
 330
 331         if(MSVC AND NOT MERGE_FILES)
 332                 macro(lyx_add_msvc_pch name_)
 333                         set_source_files_properties(${${name_}_sources} PROPERTIES
 334                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 335                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 336                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 337                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 338                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 339                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 340                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 341                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 342                 endmacro(lyx_add_msvc_pch)
 343                 macro(lyx_add_gcc_pch name_)
 344                 endmacro()
 345         else()
 346                 macro(lyx_add_msvc_pch name_)
 347                 endmacro()
 348                 macro(lyx_add_gcc_pch name_)
 349                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 350                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 351                 endmacro()
 352         endif()
 353 else()
 354         if(MSVC)
 355                 message(STATUS "-----")
 356                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 357                 message(STATUS "-----")
 358         endif()
 359         set(disable-pch TRUE CACHE TYPE STRING)
 360         macro(lyx_add_msvc_pch)
 361         endmacro(lyx_add_msvc_pch)
 362         macro(lyx_add_gcc_pch name_)
 363         endmacro()
 364 endif()
 365
 366 if(MSVC)
 367        if(vld)
 368                set(vld 1 CACHE TYPE STRING FORCE)
 369                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 370                message(STATUS "")
 371                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 372                message(STATUS "")
 373                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 374                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 375                include(${vld_path}/tools/cmake/vld.cmake)
 376        else()
 377                set(vld 0 CACHE TYPE STRING FORCE)
 378                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 379                message(STATUS "")
 380                message(STATUS "Enable leak detection with -Dvld=1")
 381                message(STATUS "")
 382        endif()
 383
 384         if(WALL)
 385                 set(WALL 1 CACHE TYPE STRING FORCE)
 386
 387                 # Use the highest warning level
 388                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 389                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 390
 391                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 392                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 393                 else()
 394                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 395                 endif()
 396
 397                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 398                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 399                 else()
 400                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 401                 endif()
 402
 403                 # add here warnings which should produce an error /weXXXX
 404                 set(MSVC_W_ERROR   "/we4101 /we4189")
 405                 # add here warnings which should be disabled /wdXXXX
 406                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 407
 408                 set(CMAKE_CXX_FLAGS_DEBUG
 409                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 410                 set(CMAKE_CXX_FLAGS_RELEASE
 411                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 412                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 413                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 414
 415         else()
 416                 set(WALL 0 CACHE TYPE STRING FORCE)
 417
 418                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 419                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 420
 421                 # add here warnings which should produce an error /weXXXX
 422                 set(MSVC_W_ERROR   "/we4101 /we4189")
 423                 # add here warnings which should be disabled /wdXXXX
 424                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 425
 426                 set(CMAKE_CXX_FLAGS_DEBUG
 427                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 428                 set(CMAKE_CXX_FLAGS_RELEASE
 429                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 430                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 431                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 432
 433         endif()
 434         set(CMAKE_CXX_FLAGS_DEBUG
 435                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 436         set(CMAKE_CXX_FLAGS_RELEASE
 437                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 438         set(CMAKE_CXX_FLAGS_MINSIZEREL
 439                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 440
 441         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 442         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 443         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 444         message(STATUS "")
 445
 446 endif()
 447
 448
 449 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 450 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 451     if(nls OR all)
 452       find_package(LyXGettext REQUIRED)
 453       include_directories(${TOP_SRC_DIR}/po)
 454       add_subdirectory(po)
 455     endif()
 456 endif()
 457
 458 option(debug_glibc "Enable libstdc++ debug mode" OFF)
 459 option(debug_glibc_pedantic "Enable libstdc++pedantic debug mode" OFF)
 460
 461 if(debug_glibc)
 462   set(_GLIBCXX_DEBUG 1)
 463 endif()
 464
 465 if(debug_glibc_pedantic)
 466   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 467 endif()
 468
 469 # compiler tests, config.h generation
 470 if(MSVC AND NOT CONFIGURECHECKS)
 471         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 472 else()
 473         include(ConfigureChecks.cmake)
 474         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 475 endif()
 476
 477 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 478
 479 find_package(ICONV REQUIRED)
 480 add_definitions(-DHAVE_ICONV=1)
 481
 482
 483 include_directories(
 484   ${CMAKE_BINARY_DIR}
 485   ${TOP_SRC_DIR}/src)
 486
 487 option(UseExternalBoost "Use external boost" OFF)
 488 if(UseExternalBoost)
 489   message(STATUS "Searching for boost")
 490   find_package(Boost COMPONENTS signals regex)
 491   if(Boost_FOUND)
 492     message(STATUS "Boost found")
 493     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 494     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 495   else()
 496     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 497   endif()
 498 else()
 499   message(STATUS "----- Using internal boost. To build with installed version use -DUseExternalBoost:BOOL=ON")
 500   if(LYX_USE_TR1_REGEX)
 501     set(Lyx_Boost_Libraries boost_signals)
 502   else()
 503     set(Lyx_Boost_Libraries boost_signals boost_regex)
 504   endif()
 505   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 506   include_directories(${TOP_SRC_DIR}/boost)
 507   add_subdirectory(boost)
 508 endif()
 509
 510
 511 if(NOT use_external_libintl)
 512   add_subdirectory(intl)
 513 endif()
 514 add_subdirectory(src)
 515
 516 if(lyxinstall)
 517         add_subdirectory(man)
 518         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 519                 add_subdirectory(doc)
 520         endif()
 521 endif()
 522 add_subdirectory(lyx2lyx)
 523 add_subdirectory(scripts)
 524
 525 if(lyxinstall)
 526         include(../Install)
 527 endif()
 528
 529 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 530 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 531 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 532
 533 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 534 #
 535 # needed by rpm
 536 SET(CPACK_SET_DESTDIR "ON")
 537 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 538 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 539 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 540 #
 541 # the next ones are needed by deb
 542 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 543 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 544
 545 # This is experimental, valid on _my_ system (Kornel)
 546 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 547 IF(ASPELL_FOUND)
 548   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 549 ENDIF()
 550 #
 551 # for the next ones, cpack insists on data with values in some file
 552 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 553 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 554
 555 # Find the revision number and use it as the release in rpm-package-build.
 556 # This way we may omit the otherwise needed "--force" parameter when
 557 # installing from that rpm package.
 558 FIND_PROGRAM(_svnversion svnversion)
 559 message(STATUS "svnversion = ${_svnversion}")
 560 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 561   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 562   # We use this value also to set the package-patch-value
 563   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 564     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 565   endif()
 566 endif()
 567
 568 # we do not have a readme or welcome data,
 569 # so we do not provide infofiles for
 570 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 571
 572 if(lyxinstall)
 573         include(CPack)
 574 endif()
 575
 576 #Now it is possible to create some packages
 577 # cd <BuildDir>
 578 # make package
 579 #############################################################################################
 580 # So, e.g. for variables
 581 #    CMAKE_PROJECT_NAME                     : lyx
 582 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 583 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 584 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 585 #    CMAKE_SYSTEM_NAME                      : Linux
 586 #    CPACK_BINARY_DEB:BOOL                  : ON
 587 #
 588 # the package name builds as "lyx-2.0.1-Linux.deb"
 589 #
 590 ############################## rpm ################################### deb ##################
 591 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 592 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 593 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 594 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 595 #