development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26
  27 # Usage LYX_OPTION
  28 # 1. parameter: option name without prefix 'LYX_'
  29 # 2. parameter: description
  30 # 3. parameter: default value, ON or OFF
  31 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  32 message(STATUS)
  33 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  34 message(STATUS)
  35
  36 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  37 if(LYX_CPACK)
  38         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  39 endif()
  40
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 if(LYX_INSTALL)
  43         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  44         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  45         if (WIN32)
  46                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  47         endif()
  48         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  49         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  50         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  51         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  52         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  53 endif()
  54
  55 LYX_OPTION(NLS "Use nls" OFF ALL)
  56 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  57 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  58 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  59 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  60 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  61 LYX_OPTION(RELEASE "Build release version" ON ALL)
  62 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  63 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  64 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  65 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  66 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  67 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  68 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  69 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  70 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  71 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  72 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  73 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  74 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  75 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  76 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  77 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  78 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  79 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  80
  81 message(STATUS)
  82
  83 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  84 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  85
  86
  87
  88 if(UNIX OR MINGW)
  89         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  90         message(STATUS "Using GCC version ${GCC_VERSION}")
  91         if(NOT GCC_VERSION VERSION_LESS 4.4)
  92                 set(LYX_USE_TR1 1)
  93                 # GCC <= 4.5 does not support regex: there are linker errors
  94                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  95                 set(LYX_USE_TR1_REGEX 0)
  96         endif()
  97 else()
  98         if(MSVC10)
  99                 set(LYX_USE_TR1 1)
 100                 set(LYX_USE_TR1_REGEX 1)
 101         endif()
 102 endif()
 103
 104
 105
 106 # Supress regeneration
 107 set(CMAKE_SUPPRESS_REGENERATION TRUE)
 108
 109 set(VERSION_INFO "CMake Build")
 110
 111 # Try to get some informations from configure.ac
 112
 113 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 114 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 115
 116 if(WIN32)
 117         set(USE_WINDOWS_PACKAGING 1)
 118 elseif(APPLE)
 119         set(USE_MACOSX_PACKAGING 1)
 120 else()
 121         set(USE_POSIX_PACKAGING 1)
 122 endif()
 123
 124 macro(setstripped _varname _value)
 125         string(STRIP ${_value} _v)
 126         if(USE_POSIX_PACKAGING)
 127                 string(TOLOWER ${_v} ${_varname})
 128         else()
 129                 set(${_varname} ${_v})
 130         endif()
 131 endmacro(setstripped)
 132
 133 foreach(_c_l ${_config_lines} )
 134         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 135                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 136                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 137                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 138                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 139                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 140                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 141                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 142                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 143                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 144                 endif()
 145         endif()
 146         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 147                 set(LYX_DATE "${CMAKE_MATCH_1}")
 148         endif()
 149 endforeach(_c_l)
 150
 151
 152 if (LYX_INSTALL_PREFIX)
 153         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 154         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 155 endif()
 156
 157 if(LYX_PACKAGE_SUFFIX)
 158         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 159 else()
 160         set(PACKAGE ${PACKAGE_BASE})
 161 endif()
 162
 163 if(LYX_PROGRAM_SUFFIX)
 164         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 165 else()
 166         set(PROGRAM_SUFFIX "")
 167 endif()
 168
 169
 170 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 171         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 172         if (UNIX)
 173                 # don't use the default "/usr/local"
 174                 # but respect the user-choice on the command-line
 175                 if(LYX_INSTALL_SUFFIX)
 176                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 177                 else()
 178                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 179                 endif()
 180         endif()
 181         if(WIN32)
 182                 set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 183         endif()
 184 endif()
 185
 186 if (WIN32)
 187         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 188 else()
 189         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 190 endif()
 191
 192 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 193 set(LYX_LOCALEDIR "locale")
 194 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 195 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 196
 197
 198 if(NOT GROUP_CODE)
 199         #set(GROUP_CODE "The Golden Code")
 200         set(GROUP_CODE flat)
 201 endif()
 202
 203 # lyx's source files
 204 set(LYX_CPP_FILES *.cpp)
 205 set(LYX_HPP_FILES *.h)
 206 set(LYX_MOC_FILES moc_*.cpp)
 207
 208
 209 include(ProjectSourceGroup)
 210
 211
 212 if(LYX_PROFILE)
 213         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 214         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 215 endif()
 216
 217 if(LYX_RELEASE)
 218         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 219 endif()
 220
 221 if(LYX_DEBUG)
 222         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 223 endif()
 224
 225
 226
 227 if(LYX_SHARED_LIBRARIES)
 228         set(library_type SHARED)
 229 else()
 230         set(library_type STATIC)
 231 endif()
 232
 233 if(NOT MSVC)
 234         if(NOT LYX_QUIET)
 235                 set(CMAKE_VERBOSE_MAKEFILE ON)
 236         endif()
 237         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 238         if(LYX_STDLIB_DEBUG)
 239                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 240         endif()
 241         if(LYX_CONCEPT_CHECKS)
 242                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 243         endif()
 244         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 245         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 246         if(MINGW)
 247                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 248         else()
 249                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 250         endif()
 251         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 252 endif()
 253
 254
 255 find_package(Qt4 REQUIRED)
 256 find_package(ICONV REQUIRED)
 257 find_package(ZLIB REQUIRED)
 258
 259 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 260
 261 if(LYX_ASPELL)
 262         find_package(ASPELL)
 263         include_directories(${ASPELL_INCLUDE_DIR})
 264 endif()
 265
 266 if(LYX_ENCHANT)
 267         find_package(Enchant REQUIRED)
 268         include_directories(${ENCHANT_INCLUDE_DIR})
 269 endif()
 270
 271 if(LYX_HUNSPELL)
 272         find_package(Hunspell REQUIRED)
 273         include_directories(${HUNSPELL_INCLUDE_DIR})
 274 endif()
 275
 276 if(LYX_NLS)
 277         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 278         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 279                 message(FATAL_ERROR "Python 2.6 needed!")
 280         endif()
 281         find_package(LyXGettext REQUIRED)
 282         include_directories(${TOP_SRC_DIR}/po)
 283         add_subdirectory(po)
 284 endif()
 285
 286 if(LYX_USE_EXTERNAL_LIBINTL)
 287         find_package(Libintl REQUIRED)
 288         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 289 else()
 290         add_subdirectory(intl)
 291 endif()
 292
 293 if(LYX_USE_EXTERNAL_BOOST)
 294         message(STATUS "Searching for boost")
 295         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 296         if(Boost_FOUND)
 297                 message(STATUS "Boost found")
 298                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 299                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 300         else()
 301                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 302         endif()
 303 else()
 304         if(LYX_USE_TR1_REGEX)
 305                 set(Lyx_Boost_Libraries boost_signals)
 306         else()
 307                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 308         endif()
 309         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 310         include_directories(${TOP_SRC_DIR}/boost)
 311         add_subdirectory(boost)
 312 endif()
 313
 314
 315
 316
 317 if(WIN32)
 318         if(LYX_NO_CONSOLE)
 319                 set(WIN32_CONSOLE WIN32)
 320                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 321         endif()
 322         if(MSVC)
 323                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 324                 # disable checked iterators for msvc release builds to get maximum speed
 325                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 326         else()
 327                 add_definitions(-DWINVER=0x0500)
 328         endif()
 329 endif()
 330
 331 message(STATUS "")
 332 foreach(_v PACKAGE PACKAGE_VERSION
 333         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 334         LYX_ABS_TOP_SRCDIR
 335         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 336         if(NOT DEFINED ${_v})
 337                 message(FATAL_ERROR "${_v} not defined")
 338         endif()
 339         string(SUBSTRING "${_v}                            " 0 28 _v1)
 340         message(STATUS "----- ${_v1}: ${${_v}}")
 341 endforeach(_v)
 342 message(STATUS "")
 343
 344
 345 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 346 # Not sure if it works for all non-msvc compilers
 347 include(PCHSupport_26)
 348
 349 if(NOT LYX_DISABLE_PCH)
 350         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 351         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 352         add_definitions(-DLYX_ENABLE_PCH)
 353
 354         if(MSVC AND NOT MERGE_FILES)
 355                 macro(lyx_add_msvc_pch name_)
 356                         set_source_files_properties(${${name_}_sources} PROPERTIES
 357                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 358                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 359                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 360                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 361                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 362                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 363                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 364                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 365                 endmacro(lyx_add_msvc_pch)
 366                 macro(lyx_add_gcc_pch name_)
 367                 endmacro()
 368         else()
 369                 macro(lyx_add_msvc_pch name_)
 370                 endmacro()
 371                 macro(lyx_add_gcc_pch name_)
 372                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 373                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 374                 endmacro()
 375         endif()
 376 else()
 377         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 378         macro(lyx_add_msvc_pch)
 379         endmacro(lyx_add_msvc_pch)
 380         macro(lyx_add_gcc_pch name_)
 381         endmacro()
 382 endif()
 383
 384 if(MSVC)
 385         if(LYX_VLD)
 386                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 387                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 388                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 389                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 390         endif()
 391
 392         # TODO options
 393         if(LYX_WALL)
 394                 # Use the highest warning level
 395                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 396
 397                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 398                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 399                 else()
 400                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 401                 endif()
 402
 403                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 404                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 405                 else()
 406                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 407                 endif()
 408
 409                 # add here warnings which should produce an error /weXXXX
 410                 set(MSVC_W_ERROR   "/we4101 /we4189")
 411                 # add here warnings which should be disabled /wdXXXX
 412                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 413
 414                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 415                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 416                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 417
 418         else()
 419                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 420
 421                 # add here warnings which should produce an error /weXXXX
 422                 set(MSVC_W_ERROR   "/we4101 /we4189")
 423                 # add here warnings which should be disabled /wdXXXX
 424                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 425
 426                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 427                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 428                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 429
 430         endif()
 431         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 432         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 433         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 434
 435         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 436         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 437         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 438         message(STATUS "")
 439 endif()
 440
 441
 442 if(LYX_DEBUG_GLIBC)
 443         set(_GLIBCXX_DEBUG 1)
 444 endif()
 445
 446 if(LYX_DEBUG_GLIBC_PEDANTIC)
 447         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 448 endif()
 449
 450 # compiler tests, config.h generation
 451 if(MSVC AND NOT CONFIGURECHECKS)
 452         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 453 else()
 454         include(ConfigureChecks.cmake)
 455         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 456 endif()
 457
 458 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 459
 460
 461 add_subdirectory(src)
 462 add_subdirectory(lyx2lyx)
 463 add_subdirectory(scripts)
 464
 465
 466 if(LYX_INSTALL)
 467         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 468         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 469                 message(FATAL_ERROR "Perl required!")
 470         endif()
 471         add_subdirectory(man)
 472         add_subdirectory(doc)
 473         include(../Install)
 474 endif()
 475
 476
 477 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 478 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 479 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 480
 481 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 482 #
 483 # needed by rpm
 484 set(CPACK_SET_DESTDIR "ON")
 485 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 486 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 487 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 488 #
 489 # the next ones are needed by deb
 490 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 491 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 492
 493 # This is experimental, valid on _my_ system (Kornel)
 494 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 495 if(ASPELL_FOUND)
 496         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 497 endif()
 498 if(ENCHANT_FOUND)
 499         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 500 endif()
 501 if(LYX_USE_EXTERNAL_BOOST)
 502         if(Boost_FOUND)
 503                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 504         endif()
 505 endif()
 506 #
 507 # for the next ones, cpack insists on data with values in some file
 508 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 509 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 510
 511 # Find the revision number and use it as the release in rpm-package-build.
 512 # This way we may omit the otherwise needed "--force" parameter when
 513 # installing from that rpm package.
 514 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 515 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 516 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 517         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 518         # We use this value also to set the package-patch-value
 519         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 520                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 521         endif()
 522 endif()
 523
 524 # we do not have a readme or welcome data,
 525 # so we do not provide infofiles for
 526 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 527
 528 include(CPack)
 529
 530 #Now it is possible to create some packages
 531 # cd <BuildDir>
 532 # make package
 533 #############################################################################################
 534 # So, e.g. for variables
 535 #    CMAKE_PROJECT_NAME                     : lyx
 536 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 537 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 538 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 539 #    CMAKE_SYSTEM_NAME                      : Linux
 540 #    CPACK_BINARY_DEB:BOOL                  : ON
 541 #
 542 # the package name builds as "lyx-2.0.1-Linux.deb"
 543 #
 544 ############################## rpm ################################### deb ##################
 545 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 546 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 547 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 548 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 549 #
 550 message(STATUS)