development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   6 #
   7
   8 cmake_minimum_required(VERSION 2.4)
   9
  10 if(COMMAND cmake_policy)
  11         cmake_policy(SET CMP0003 OLD)
  12         cmake_policy(SET CMP0005 OLD)
  13 endif(COMMAND cmake_policy)
  14
  15 project(lyx)
  16
  17 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  18
  19 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  20 # is checked
  21 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  22 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  23 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  24
  25
  26 option(lyxinstall "Build install projects/rules" ON)
  27
  28
  29
  30
  31 # Supress regeneration
  32 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  33
  34 set(VERSION_INFO "CMake Build")
  35
  36 # Try to get some informations from configure.ac
  37
  38 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  39 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  40
  41 if(WIN32)
  42   set(USE_WINDOWS_PACKAGING 1)
  43 elseif(APPLE)
  44   set(USE_MACOSX_PACKAGING 1)
  45 else()
  46   set(USE_POSIX_PACKAGING 1)
  47 endif()
  48
  49 macro(setstripped _varname _value)
  50   string(STRIP ${_value} _v)
  51   if(USE_POSIX_PACKAGING)
  52     string(TOLOWER ${_v} ${_varname})
  53   else()
  54     set(${_varname} ${_v})
  55   endif()
  56 endmacro(setstripped)
  57
  58 foreach(_c_l ${_config_lines} )
  59   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  60     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  61     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  62     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  63     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  64       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  65       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  66       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  67       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  68       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  69     endif()
  70   endif()
  71   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  72     set(LYX_DATE "${CMAKE_MATCH_1}")
  73   endif()
  74 endforeach(_c_l)
  75
  76 if(UseVersionSuffix)
  77   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  78   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  79   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  80 else()
  81   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
  82   set(PACKAGE ${PACKAGE_BASE})
  83   set(PROGRAM_SUFFIX "")
  84 endif()
  85
  86 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  87   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  88   if (UNIX)
  89     # don't use the default "/usr/local"
  90     # but respect the user-choice on the command-line
  91     SET(CMAKE_INSTALL_PREFIX
  92       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
  93   endif()
  94   if(WIN32)
  95     SET(CMAKE_INSTALL_PREFIX
  96       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
  97   endif()
  98 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  99
 100 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 101 set(LYX_LOCALEDIR "locale")
 102 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
 103 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 104
 105
 106 if(NOT GROUP_CODE)
 107         #set(GROUP_CODE "The Golden Code")
 108         set(GROUP_CODE flat)
 109 endif()
 110
 111 # lyx's source files
 112 set(LYX_CPP_FILES *.cpp)
 113 set(LYX_HPP_FILES *.h)
 114 set(LYX_MOC_FILES moc_*.cpp)
 115
 116 include(LyXMacros)
 117 include(ProjectSourceGroup)
 118
 119 if(merge OR merge_rebuild)
 120         set(merge 1 CACHE TYPE STRING FORCE)
 121         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 122         message(STATUS "")
 123         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 124         message(STATUS "")
 125         add_definitions(-DLYX_MERGED_BUILD)
 126 else()
 127         set(merge 0 CACHE TYPE STRING FORCE)
 128         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 129         message(STATUS "Enable merging files with -Dmerge=1")
 130 endif()
 131
 132
 133 set(CMAKE_BUILD_TYPE Release)
 134
 135 if(profile)
 136         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 137         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 138             CACHE TYPE STRING FORCE)
 139         set(profile)
 140 endif()
 141
 142 if(release)
 143         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 144         set(release TRUE CACHE TYPE STRING FORCE)
 145         set(release)
 146 endif()
 147
 148 if(debug)
 149         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 150         set(debug TRUE CACHE TYPE STRING FORCE)
 151         set(debug)
 152 endif()
 153
 154 if(shared)
 155         set(library_type SHARED)
 156         message(STATUS "building shared libraries")
 157 else()
 158         set(library_type STATIC)
 159 endif()
 160
 161 if(NOT MSVC)
 162         if(NOT quiet)
 163                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 164                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 165                 message(STATUS "")
 166         else()
 167                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 168         endif()
 169         set(LYX_CXX_FLAGS -Wall)
 170         if(stdlib-debug)
 171                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 172         endif()
 173         if(concept-checks)
 174                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 175         endif()
 176         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 177         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 178         if(MINGW)
 179                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 180         else()
 181                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 182         endif()
 183         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 184 endif()
 185
 186
 187 find_package(Qt4 REQUIRED)
 188 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 189
 190 find_package(ZLIB REQUIRED)
 191
 192 if(all OR aspell)
 193         set(aspell TRUE CACHE TYPE STRING)
 194         find_package(ASPELL REQUIRED)
 195 else()
 196         find_package(ASPELL)
 197 endif()
 198 set(aspell)
 199
 200 set(use_external_libintl TRUE)
 201
 202 if(use_external_libintl)
 203         find_package(Libintl REQUIRED)
 204         add_definitions(-DHAVE_GETTEXT)
 205 endif()
 206
 207 if(WIN32)
 208   find_library(HUNSPELL_LIBRARY "libhunspell")
 209 else()
 210   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 211   find_library(HUNSPELL_LIBRARY "hunspell" "/usr/local/lib" "/usr/lib")
 212 endif()
 213 if (HUNSPELL_LIBRARY)
 214   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 215 endif()
 216
 217 if (HUNSPELL_FOUND)
 218   add_definitions(-DUSE_HUNSPELL=1)
 219   message(STATUS "----- Building with USE_HUNSPELL")
 220 else()
 221   message(STATUS "----- Hunspell not found, building without hunspell support")
 222 endif()
 223
 224 if(WIN32)
 225   find_library(ENCHANT_LIBRARY "libenchant")
 226   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 227 else()
 228   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 229   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 230 endif()
 231 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 232   set(ENCHANT_FOUND TRUE)
 233   add_definitions(-DUSE_ENCHANT=1)
 234   message(STATUS "----- Building with USE_ENCHANT")
 235 else()
 236   message(STATUS "----- Enchant not found, building without enchant support")
 237 endif()
 238
 239 message(STATUS "")
 240 if(nls OR all)
 241         set(nls TRUE CACHE TYPE STRING)
 242         add_definitions(-DENABLE_NLS=1)
 243         message(STATUS "----- Building with ENABLE_NLS")
 244 else()
 245         message(STATUS "----- No nls, to enable use -Dnls=1")
 246 endif()
 247 set(nls)
 248 if(ASPELL_FOUND)
 249         add_definitions(-DUSE_ASPELL=1)
 250         message(STATUS "----- Building with USE_ASPELL")
 251 else()
 252         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 253 endif()
 254 set(all)
 255
 256 if(WIN32)
 257         if(noconsole)
 258                 set(noconsole TRUE CACHE TYPE STRING)
 259                 set(WIN32_CONSOLE WIN32)
 260                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 261                 message(STATUS "----- Console disabled")
 262         else()
 263                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 264         endif()
 265         if(MSVC)
 266                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 267                 # disable checked iterators for msvc release builds to get maximum speed
 268                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 269         else()
 270                 add_definitions(-DWINVER=0x0500)
 271         endif()
 272 endif()
 273
 274 message(STATUS "")
 275 foreach(_v PACKAGE PACKAGE_VERSION
 276     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 277     LYX_ABS_TOP_SRCDIR
 278     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 279   if(NOT DEFINED ${_v})
 280     message(FATAL_ERROR "${_v} not defined")
 281   endif()
 282   string(SUBSTRING "${_v}                            " 0 28 _v1)
 283   message(STATUS "----- ${_v1}: ${${_v}}")
 284 endforeach(_v)
 285 message(STATUS "")
 286
 287
 288 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 289 # Not sure if it works for all non-msvc compilers
 290 include(PCHSupport_26)
 291 if (MSVC)
 292         option(disable-pch "Disable precompiled headers" ON)
 293 else()
 294         option(disable-pch "Disable precompiled headers" ON)
 295 endif()
 296
 297 if(NOT disable-pch)
 298
 299         message(STATUS "-----")
 300         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 301         message(STATUS "-----")
 302         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 303         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 304         add_definitions(-DLYX_ENABLE_PCH)
 305
 306         if(MSVC AND NOT MERGE_FILES)
 307                 macro(lyx_add_msvc_pch name_)
 308                         set_source_files_properties(${${name_}_sources} PROPERTIES
 309                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 310                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 311                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 312                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 313                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 314                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 315                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 316                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 317                 endmacro(lyx_add_msvc_pch)
 318                 macro(lyx_add_gcc_pch name_)
 319                 endmacro()
 320         else()
 321                 macro(lyx_add_msvc_pch name_)
 322                 endmacro()
 323                 macro(lyx_add_gcc_pch name_)
 324                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 325                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 326                 endmacro()
 327         endif()
 328 else()
 329         if(MSVC)
 330                 message(STATUS "-----")
 331                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 332                 message(STATUS "-----")
 333         endif()
 334         set(disable-pch TRUE CACHE TYPE STRING)
 335         macro(lyx_add_msvc_pch)
 336         endmacro(lyx_add_msvc_pch)
 337         macro(lyx_add_gcc_pch name_)
 338         endmacro()
 339 endif()
 340
 341 if(MSVC)
 342        if(vld)
 343                set(vld 1 CACHE TYPE STRING FORCE)
 344                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 345                message(STATUS "")
 346                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 347                message(STATUS "")
 348                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 349                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 350                include(${vld_path}/tools/cmake/vld.cmake)
 351        else()
 352                set(vld 0 CACHE TYPE STRING FORCE)
 353                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 354                message(STATUS "")
 355                message(STATUS "Enable leak detection with -Dvld=1")
 356                message(STATUS "")
 357        endif()
 358
 359         if(WALL)
 360                 set(WALL 1 CACHE TYPE STRING FORCE)
 361
 362                 # Use the highest warning level
 363                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 364                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 365
 366                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 367                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 368                 else()
 369                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 370                 endif()
 371
 372                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 373                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 374                 else()
 375                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 376                 endif()
 377
 378                 # add here warnings which should produce an error /weXXXX
 379                 set(MSVC_W_ERROR   "/we4101 /we4189")
 380                 # add here warnings which should be disabled /wdXXXX
 381                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 382
 383                 set(CMAKE_CXX_FLAGS_DEBUG
 384                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 385                 set(CMAKE_CXX_FLAGS_RELEASE
 386                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 387                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 388                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 389
 390         else()
 391                 set(WALL 0 CACHE TYPE STRING FORCE)
 392
 393                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 394                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 395
 396                 # add here warnings which should produce an error /weXXXX
 397                 set(MSVC_W_ERROR   "/we4101 /we4189")
 398                 # add here warnings which should be disabled /wdXXXX
 399                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 400
 401                 set(CMAKE_CXX_FLAGS_DEBUG
 402                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 403                 set(CMAKE_CXX_FLAGS_RELEASE
 404                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 405                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 406                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 407
 408         endif()
 409         set(CMAKE_CXX_FLAGS_DEBUG
 410                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 411         set(CMAKE_CXX_FLAGS_RELEASE
 412                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 413         set(CMAKE_CXX_FLAGS_MINSIZEREL
 414                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 415
 416         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 417         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 418         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 419         message(STATUS "")
 420
 421 endif()
 422
 423
 424 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 425 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 426     if(nls OR all)
 427       find_package(LyXGettext REQUIRED)
 428       include_directories(${TOP_SRC_DIR}/po)
 429       add_subdirectory(po)
 430     endif()
 431 endif()
 432
 433 option(debug_glibc "Enable libstdc++ debug mode" OFF)
 434 option(debug_glibc_pedantic "Enable libstdc++pedantic debug mode" OFF)
 435
 436 if(debug_glibc)
 437   set(_GLIBCXX_DEBUG 1)
 438 endif()
 439
 440 if(debug_glibc_pedantic)
 441   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 442 endif()
 443
 444 # compiler tests, config.h generation
 445 if(MSVC AND NOT CONFIGURECHECKS)
 446         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 447 else()
 448         include(ConfigureChecks.cmake)
 449         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 450 endif()
 451
 452 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 453
 454 find_package(ICONV REQUIRED)
 455 add_definitions(-DHAVE_ICONV=1)
 456
 457
 458 include_directories(
 459   ${CMAKE_BINARY_DIR}
 460   ${TOP_SRC_DIR}/src)
 461
 462 option(UseExternalBoost "Use external boost" OFF)
 463 if(UseExternalBoost)
 464   message(STATUS "Searching for boost")
 465   find_package(Boost COMPONENTS signals regex)
 466   if(Boost_FOUND)
 467     message(STATUS "Boost found")
 468     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 469     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 470   else()
 471     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 472   endif()
 473 else()
 474   message(STATUS "----- Using internal boost. To build with installed version use -DUseExternalBoost:BOOL=ON")
 475   set(Lyx_Boost_Libraries boost_signals boost_regex)
 476   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 477   include_directories(${TOP_SRC_DIR}/boost)
 478   add_subdirectory(boost)
 479 endif()
 480
 481
 482 if(NOT use_external_libintl)
 483   add_subdirectory(intl)
 484 endif()
 485 add_subdirectory(src)
 486
 487 if(lyxinstall)
 488         add_subdirectory(man)
 489         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 490                 add_subdirectory(doc)
 491         endif()
 492 endif()
 493 add_subdirectory(lyx2lyx)
 494 add_subdirectory(scripts)
 495
 496 if(lyxinstall)
 497         include(../Install)
 498 endif()
 499
 500 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 501 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 502 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 503
 504 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 505 #
 506 # needed by rpm
 507 SET(CPACK_SET_DESTDIR "ON")
 508 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 509 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 510 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 511 #
 512 # the next ones are needed by deb
 513 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 514 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 515
 516 # This is experimental, valid on _my_ system (Kornel)
 517 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 518 IF(ASPELL_FOUND)
 519   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 520 ENDIF()
 521 #
 522 # for the next ones, cpack insists on data with values in some file
 523 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 524 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 525
 526 # Find the revision number and use it as the release in rpm-package-build.
 527 # This way we may omit the otherwise needed "--force" parameter when
 528 # installing from that rpm package.
 529 FIND_PROGRAM(_svnversion svnversion)
 530 message(STATUS "svnversion = ${_svnversion}")
 531 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 532   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 533   # We use this value also to set the package-patch-value
 534   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 535     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 536   endif()
 537 endif()
 538
 539 # we do not have a readme or welcome data,
 540 # so we do not provide infofiles for
 541 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 542
 543 if(lyxinstall)
 544         include(CPack)
 545 endif()
 546
 547 #Now it is possible to create some packages
 548 # cd <BuildDir>
 549 # make package
 550 #############################################################################################
 551 # So, e.g. for variables
 552 #    CMAKE_PROJECT_NAME                     : lyx
 553 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 554 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 555 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 556 #    CMAKE_SYSTEM_NAME                      : Linux
 557 #    CPACK_BINARY_DEB:BOOL                  : ON
 558 #
 559 # the package name builds as "lyx-2.0.1-Linux.deb"
 560 #
 561 ############################## rpm ################################### deb ##################
 562 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 563 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 564 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 565 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 566 #