development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  15
  16 project(lyx)
  17
  18 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  19 # is checked
  20 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  21 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  22
  23 # Supress regeneration
  24 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  25
  26 set(PACKAGE lyx)
  27 set(PACKAGE_VERSION 1.6svn)
  28 set(LYX_DATE "2007/2008")
  29 #TODO
  30 set(VERSION_INFO "CMake Build")
  31 set(LYX_DIR_VER "LYX_DIR_16x")
  32 set(LYX_USERDIR_VER "LYX_USERDIR_16x")
  33
  34 set(PROGRAM_SUFFIX "")
  35 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
  36 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
  37 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
  38
  39
  40 if(WIN32)
  41         set(USE_WINDOWS_PACKAGING 1)
  42 elseif(APPLE)
  43         set(USE_MACOSX_PACKAGING 1)
  44 else()
  45         set(USE_POSIX_PACKAGING 1)
  46 endif()
  47
  48 if(NOT GROUP_CODE)
  49         #set(GROUP_CODE "The Golden Code")
  50         set(GROUP_CODE flat)
  51 endif()
  52
  53 # lyx's source files
  54 set(LYX_CPP_FILES *.cpp)
  55 set(LYX_HPP_FILES *.h)
  56
  57 include(LyXPaths)
  58 include(LyXMacros)
  59 include(ProjectSourceGroup)
  60
  61 if(merge OR merge_rebuild)
  62         set(merge 1 CACHE TYPE STRING FORCE)
  63         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  64         message(STATUS "")
  65         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  66         message(STATUS "")
  67 else()
  68         set(merge 0 CACHE TYPE STRING FORCE)
  69         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
  70         message(STATUS "Enable merging files with -Dmerge=1")
  71 endif()
  72
  73
  74 set(CMAKE_BUILD_TYPE Release)
  75
  76 if(profile)
  77         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
  78         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
  79             CACHE TYPE STRING FORCE)
  80         set(profile)
  81 endif()
  82
  83 if(release)
  84         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
  85         set(release TRUE CACHE TYPE STRING FORCE)
  86         set(release)
  87 endif()
  88
  89 if(debug)
  90         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
  91         set(debug TRUE CACHE TYPE STRING FORCE)
  92         set(debug)
  93 endif()
  94
  95 if(shared)
  96         set(library_type SHARED)
  97         message(STATUS "building shared libraries")
  98 else()
  99         set(library_type STATIC)
 100 endif()
 101
 102 if(NOT MSVC)
 103         if(NOT quiet)
 104                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 105                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 106                 message(STATUS "")
 107         else()
 108                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 109         endif()
 110         set(LYX_CXX_FLAGS -Wall)
 111         if(stdlib-debug)
 112                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 113         endif()
 114         if(concept-checks)
 115                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 116         endif()
 117         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 118         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 119         if(MINGW)
 120                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 121         else()
 122                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 123         endif()
 124         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 125 endif()
 126
 127
 128 find_package(Qt4 REQUIRED)
 129 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 130
 131 find_package(ZLIB REQUIRED)
 132
 133 if(all OR aspell)
 134         set(aspell TRUE CACHE TYPE STRING)
 135         find_package(ASPELL REQUIRED)
 136 else()
 137         find_package(ASPELL)
 138 endif()
 139 set(aspell)
 140
 141 set(use_external_libintl TRUE)
 142
 143 if(use_external_libintl)
 144         find_package(Libintl REQUIRED)
 145         add_definitions(-DHAVE_GETTEXT)
 146 endif()
 147
 148 message("")
 149 if(nls OR all)
 150         set(nls TRUE CACHE TYPE STRING)
 151         add_definitions(-DENABLE_NLS=1)
 152         message("----- Building with ENABLE_NLS")
 153 else()
 154         message("----- No nls, to enable use -Dnls=1")
 155 endif()
 156 set(nls)
 157 if(ASPELL_FOUND)
 158         add_definitions(-DUSE_ASPELL=1)
 159         message("----- Building with USE_ASPELL")
 160 else()
 161         message("----- No aspell, to get more information use -Daspell=1")
 162 endif()
 163 set(all)
 164
 165 if(WIN32)
 166         if(noconsole)
 167                 set(noconsole TRUE CACHE TYPE STRING)
 168                 set(WIN32_CONSOLE WIN32)
 169                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 170                 message("----- Console disabled")
 171         else()
 172                 message("----- Console enabled, disable it with -Dnoconsole=1")
 173         endif()
 174         if(MSVC)
 175                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 176                 # disable checked iterators for msvc release builds to get maximum speed
 177                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 178         else()
 179                 add_definitions(-DWINVER=0x0500)
 180         endif()
 181 endif()
 182
 183 set(PROGRAM_SUFFIX "\"\"")
 184 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
 185 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
 186 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
 187
 188 message("")
 189 message("----- PROGRAM_SUFFIX              : ${PROGRAM_SUFFIX}")
 190 message("----- LYX_ABS_TOP_SRCDIR          : ${LYX_ABS_TOP_SRCDIR}")
 191 message("----- LYX_ABS_INSTALLED_DATADIR   : ${LYX_ABS_INSTALLED_DATADIR}")
 192 message("----- LYX_ABS_INSTALLED_LOCALEDIR : ${LYX_ABS_INSTALLED_LOCALEDIR}")
 193 message("")
 194
 195
 196 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 197
 198 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 199         message("-----")
 200         message("----- using precompiled headers, disable with -Ddisable-pch=1")
 201         message("-----")
 202         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 203                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 204         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 205                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 206         macro(lyx_add_msvc_pch name_)
 207                 set_source_files_properties(${${name_}_sources} PROPERTIES
 208                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 209                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 210                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 211                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 212                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 213                 add_definitions(/DLYX_ENABLE_PCH)
 214         endmacro(lyx_add_msvc_pch)
 215         set(CMAKE_CXX_FLAGS_DEBUG
 216                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 217         set(CMAKE_CXX_FLAGS_RELEASE
 218                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 219         set(CMAKE_CXX_FLAGS_MINSIZEREL
 220                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 221 else()
 222         if(MSVC)
 223                 message("-----")
 224                 message("----- precompiled headers disabled, enable with -Ddisable-pch=0")
 225                 message("-----")
 226         endif()
 227         set(disable-pch TRUE CACHE TYPE STRING)
 228         macro(lyx_add_msvc_pch)
 229         endmacro(lyx_add_msvc_pch)
 230 endif()
 231
 232 if(MSVC)
 233        if(vld)
 234                set(vld 1 CACHE TYPE STRING FORCE)
 235                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 236                message(STATUS "")
 237                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 238                message(STATUS "")
 239                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 240                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 241                include(${vld_path}/tools/cmake/vld.cmake)
 242        else()
 243                set(vld 0 CACHE TYPE STRING FORCE)
 244                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 245                message(STATUS "")
 246                message(STATUS "Enable leak detection with -Dvld=1")
 247                message(STATUS "")
 248        endif()
 249
 250         if(WALL)
 251                 set(WALL 1 CACHE TYPE STRING FORCE)
 252
 253                 # Use the highest warning level
 254                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 255                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 256
 257                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 258                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 259                 else()
 260                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 261                 endif()
 262
 263                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 264                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 265                 else()
 266                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 267                 endif()
 268
 269                 # add here warnings which should produce an error /weXXXX
 270                 set(MSVC_W_ERROR   "/we4101 /we4189")
 271                 # add here warnings which should be disabled /wdXXXX
 272                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 273
 274                 set(CMAKE_CXX_FLAGS_DEBUG
 275                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 276                 set(CMAKE_CXX_FLAGS_RELEASEs
 277                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 278                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 279                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 280
 281         else()
 282                 set(WALL 0 CACHE TYPE STRING FORCE)
 283
 284                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 285                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 286
 287                 # add here warnings which should produce an error /weXXXX
 288                 set(MSVC_W_ERROR   "/we4101 /we4189")
 289                 # add here warnings which should be disabled /wdXXXX
 290                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 291
 292                 set(CMAKE_CXX_FLAGS_DEBUG
 293                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 294                 set(CMAKE_CXX_FLAGS_RELEASE
 295                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 296                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 297                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 298
 299         endif()
 300
 301         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 302         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 303         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 304         message("")
 305
 306 endif()
 307
 308 # compiler tests, config.h generation
 309 if(MSVC AND NOT CONFIGURECHECKS)
 310         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 311 else()
 312         include(ConfigureChecks.cmake)
 313         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 314 endif()
 315 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 316
 317
 318 find_package(ICONV REQUIRED)
 319 add_definitions(-DHAVE_ICONV=1)
 320
 321
 322 #TODO: insource is not the best place
 323 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 324                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 325
 326 include_directories(
 327         ${CMAKE_BINARY_DIR}
 328         ${TOP_SRC_DIR}/src
 329         ${TOP_SRC_DIR}/boost)
 330
 331 add_subdirectory(boost)
 332 if(NOT use_external_libintl)
 333         add_subdirectory(intl)
 334 endif()
 335 add_subdirectory(src)
 336
 337 include(../Install)
 338