development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26 message(STATUS)
  27 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  28
  29 # Usage LYX_OPTION
  30 # 1. parameter: option name without prefix 'LYX_'
  31 # 2. parameter: description
  32 # 3. parameter: default value, ON or OFF
  33 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  34 LYX_OPTION(NLS "Use nls" OFF ALL)
  35 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  36 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  37 LYX_OPTION(RELEASE "Build release version" ON ALL)
  38 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  39 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  40 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules" ON ALL)
  42 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" OFF ALL)
  43 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  44 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  45 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  46 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  47 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  48 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  49 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  50 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  51 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  52 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  53 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  54
  55 message(STATUS)
  56
  57 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  58 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  59
  60
  61
  62 if(UNIX OR MINGW)
  63     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  64     message(STATUS "Using GCC version ${GCC_VERSION}")
  65     if(NOT GCC_VERSION VERSION_LESS 4.4)
  66         set(LYX_USE_TR1 1)
  67         # GCC <= 4.5 does not support regex: there are linker errors
  68         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  69         set(LYX_USE_TR1_REGEX 0)
  70     endif()
  71 else()
  72     if(MSVC10)
  73         set(LYX_USE_TR1 1)
  74         set(LYX_USE_TR1_REGEX 1)
  75     endif()
  76 endif()
  77
  78
  79
  80
  81
  82 # Supress regeneration
  83 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  84
  85 set(VERSION_INFO "CMake Build")
  86
  87 # Try to get some informations from configure.ac
  88
  89 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  90 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  91
  92 if(WIN32)
  93   set(USE_WINDOWS_PACKAGING 1)
  94 elseif(APPLE)
  95   set(USE_MACOSX_PACKAGING 1)
  96 else()
  97   set(USE_POSIX_PACKAGING 1)
  98 endif()
  99
 100 macro(setstripped _varname _value)
 101   string(STRIP ${_value} _v)
 102   if(USE_POSIX_PACKAGING)
 103     string(TOLOWER ${_v} ${_varname})
 104   else()
 105     set(${_varname} ${_v})
 106   endif()
 107 endmacro(setstripped)
 108
 109 foreach(_c_l ${_config_lines} )
 110   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 111     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 112     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 113     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 114     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 115       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 116       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 117       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 118       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 119       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 120     endif()
 121   endif()
 122   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 123     set(LYX_DATE "${CMAKE_MATCH_1}")
 124   endif()
 125 endforeach(_c_l)
 126
 127
 128 if(LYX_PACKAGE_SUFFIX)
 129   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 130 else()
 131   set(PACKAGE ${PACKAGE_BASE})
 132 endif()
 133
 134 if(LYX_PROGRAM_SUFFIX)
 135   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 136 else()
 137   set(PROGRAM_SUFFIX "")
 138 endif()
 139
 140
 141 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 142   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 143   if (UNIX)
 144     # don't use the default "/usr/local"
 145     # but respect the user-choice on the command-line
 146     if(LYX_INSTALL_SUFFIX)
 147         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 148     else()
 149         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 150     endif()
 151   endif()
 152   if(WIN32)
 153     SET(CMAKE_INSTALL_PREFIX
 154       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 155   endif()
 156 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 157
 158 if (WIN32)
 159   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 160 else()
 161   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 162 endif()
 163
 164 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 165 set(LYX_LOCALEDIR "locale")
 166 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 167 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 168
 169
 170 if(NOT GROUP_CODE)
 171         #set(GROUP_CODE "The Golden Code")
 172         set(GROUP_CODE flat)
 173 endif()
 174
 175 # lyx's source files
 176 set(LYX_CPP_FILES *.cpp)
 177 set(LYX_HPP_FILES *.h)
 178 set(LYX_MOC_FILES moc_*.cpp)
 179
 180
 181 include(ProjectSourceGroup)
 182
 183 if(LYX_MERGE_FILES)
 184         add_definitions(-DLYX_MERGED_BUILD)
 185 endif()
 186
 187
 188 set(CMAKE_BUILD_TYPE Release)
 189
 190 if(LYX_PROFILE)
 191         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 192         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 193             CACHE TYPE STRING FORCE)
 194 endif()
 195
 196 if(LYX_RELEASE)
 197         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 198 endif()
 199
 200 if(LYX_DEBUG)
 201         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 202 endif()
 203
 204
 205
 206 if(LYX_SHARED_LIBRARIES)
 207         set(library_type SHARED)
 208 else()
 209         set(library_type STATIC)
 210 endif()
 211
 212 if(NOT MSVC)
 213         if(NOT LYX_QUIET)
 214                 set(CMAKE_VERBOSE_MAKEFILE ON)
 215         endif()
 216         set(LYX_CXX_FLAGS -Wall)
 217         if(LYX_STDLIB_DEBUG)
 218                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 219         endif()
 220         if(LYX_CONCEPT_CHECKS)
 221                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 222         endif()
 223         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 224         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 225         if(MINGW)
 226                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 227         else()
 228                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 229         endif()
 230         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 231 endif()
 232
 233
 234 find_package(Qt4 REQUIRED)
 235 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 236
 237 find_package(ZLIB REQUIRED)
 238
 239 if(LYX_ASPELL)
 240         find_package(ASPELL REQUIRED)
 241 else()
 242         find_package(ASPELL)
 243 endif()
 244
 245
 246 if(LYX_USE_EXTERNAL_LIBINTL)
 247         find_package(Libintl REQUIRED)
 248         add_definitions(-DHAVE_GETTEXT)
 249 endif()
 250
 251
 252 if(WIN32)
 253   find_library(HUNSPELL_LIBRARY "libhunspell")
 254 else()
 255   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 256   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 257 endif()
 258 if (HUNSPELL_LIBRARY)
 259   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 260 endif()
 261
 262 if (HUNSPELL_FOUND)
 263   add_definitions(-DUSE_HUNSPELL=1)
 264   message(STATUS "Building with USE_HUNSPELL")
 265 else()
 266   message(STATUS "Hunspell not found, building without hunspell support")
 267 endif()
 268
 269 if(WIN32)
 270   find_library(ENCHANT_LIBRARY "libenchant")
 271   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 272 else()
 273   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 274   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 275 endif()
 276 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 277   set(ENCHANT_FOUND TRUE)
 278   add_definitions(-DUSE_ENCHANT=1)
 279   message(STATUS "Building with USE_ENCHANT")
 280 else()
 281   message(STATUS "Enchant not found, building without enchant support")
 282 endif()
 283
 284
 285 if(LYX_NLS)
 286         add_definitions(-DENABLE_NLS=1)
 287 endif()
 288
 289 if(ASPELL_FOUND)
 290         add_definitions(-DUSE_ASPELL=1)
 291 endif()
 292
 293 if(WIN32)
 294         if(LYX_NO_CONSOLE)
 295                 set(WIN32_CONSOLE WIN32)
 296                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 297         endif()
 298         if(MSVC)
 299                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 300                 # disable checked iterators for msvc release builds to get maximum speed
 301                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 302         else()
 303                 add_definitions(-DWINVER=0x0500)
 304         endif()
 305 endif()
 306
 307 message(STATUS "")
 308 foreach(_v PACKAGE PACKAGE_VERSION
 309     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 310     LYX_ABS_TOP_SRCDIR
 311     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 312   if(NOT DEFINED ${_v})
 313     message(FATAL_ERROR "${_v} not defined")
 314   endif()
 315   string(SUBSTRING "${_v}                            " 0 28 _v1)
 316   message(STATUS "----- ${_v1}: ${${_v}}")
 317 endforeach(_v)
 318 message(STATUS "")
 319
 320
 321 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 322 # Not sure if it works for all non-msvc compilers
 323 include(PCHSupport_26)
 324
 325 if(NOT LYX_DISABLE_PCH)
 326
 327         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 328         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 329         add_definitions(-DLYX_ENABLE_PCH)
 330
 331         if(MSVC AND NOT MERGE_FILES)
 332                 macro(lyx_add_msvc_pch name_)
 333                         set_source_files_properties(${${name_}_sources} PROPERTIES
 334                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 335                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 336                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 337                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 338                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 339                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 340                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 341                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 342                 endmacro(lyx_add_msvc_pch)
 343                 macro(lyx_add_gcc_pch name_)
 344                 endmacro()
 345         else()
 346                 macro(lyx_add_msvc_pch name_)
 347                 endmacro()
 348                 macro(lyx_add_gcc_pch name_)
 349                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 350                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 351                 endmacro()
 352         endif()
 353 else()
 354         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 355         macro(lyx_add_msvc_pch)
 356         endmacro(lyx_add_msvc_pch)
 357         macro(lyx_add_gcc_pch name_)
 358         endmacro()
 359 endif()
 360
 361 if(MSVC)
 362        if(LYX_VLD)
 363                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 364                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 365                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 366                include(${vld_path}/tools/cmake/vld.cmake)
 367        endif()
 368
 369         # TODO options
 370         if(WALL)
 371                 set(WALL 1 CACHE TYPE STRING FORCE)
 372
 373                 # Use the highest warning level
 374                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 375                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 376
 377                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 378                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 379                 else()
 380                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 381                 endif()
 382
 383                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 384                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 385                 else()
 386                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 387                 endif()
 388
 389                 # add here warnings which should produce an error /weXXXX
 390                 set(MSVC_W_ERROR   "/we4101 /we4189")
 391                 # add here warnings which should be disabled /wdXXXX
 392                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 393
 394                 set(CMAKE_CXX_FLAGS_DEBUG
 395                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 396                 set(CMAKE_CXX_FLAGS_RELEASE
 397                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 398                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 399                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 400
 401         else()
 402                 set(WALL 0 CACHE TYPE STRING FORCE)
 403
 404                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 405                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 406
 407                 # add here warnings which should produce an error /weXXXX
 408                 set(MSVC_W_ERROR   "/we4101 /we4189")
 409                 # add here warnings which should be disabled /wdXXXX
 410                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 411
 412                 set(CMAKE_CXX_FLAGS_DEBUG
 413                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 414                 set(CMAKE_CXX_FLAGS_RELEASE
 415                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 416                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 417                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 418
 419         endif()
 420         set(CMAKE_CXX_FLAGS_DEBUG
 421                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 422         set(CMAKE_CXX_FLAGS_RELEASE
 423                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 424         set(CMAKE_CXX_FLAGS_MINSIZEREL
 425                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 426
 427         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 428         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 429         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 430         message(STATUS "")
 431
 432 endif()
 433
 434 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 435 FIND_PROGRAM(_PYTHON_EXECUTABLE python)
 436 if( NOT ${_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 437     if(LYX_NLS)
 438       find_package(LyXGettext REQUIRED)
 439       include_directories(${TOP_SRC_DIR}/po)
 440       add_subdirectory(po)
 441     endif()
 442 endif()
 443
 444 if(LYX_DEBUG_GLIBC)
 445   set(_GLIBCXX_DEBUG 1)
 446 endif()
 447
 448 if(LYX_DEBUG_GLIBC_PEDANTIC)
 449   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 450 endif()
 451
 452 # compiler tests, config.h generation
 453 if(MSVC AND NOT CONFIGURECHECKS)
 454         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 455 else()
 456         include(ConfigureChecks.cmake)
 457         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 458 endif()
 459
 460 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 461
 462 find_package(ICONV REQUIRED)
 463 add_definitions(-DHAVE_ICONV=1)
 464
 465
 466 include_directories(
 467   ${CMAKE_BINARY_DIR}
 468   ${TOP_SRC_DIR}/src)
 469
 470
 471 if(LYX_USE_EXTERNAL_BOOST)
 472   message(STATUS "Searching for boost")
 473   find_package(Boost COMPONENTS signals regex)
 474   if(Boost_FOUND)
 475     message(STATUS "Boost found")
 476     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 477     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 478   else()
 479     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 480   endif()
 481 else()
 482   if(LYX_USE_TR1_REGEX)
 483     set(Lyx_Boost_Libraries boost_signals)
 484   else()
 485     set(Lyx_Boost_Libraries boost_signals boost_regex)
 486   endif()
 487   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 488   include_directories(${TOP_SRC_DIR}/boost)
 489   add_subdirectory(boost)
 490 endif()
 491
 492
 493 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 494   add_subdirectory(intl)
 495 endif()
 496 add_subdirectory(src)
 497
 498 if(LYX_INSTALL)
 499         add_subdirectory(man)
 500         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 501                 add_subdirectory(doc)
 502         endif()
 503 endif()
 504 add_subdirectory(lyx2lyx)
 505 add_subdirectory(scripts)
 506
 507 if(LYX_INSTALL)
 508         include(../Install)
 509 endif()
 510
 511 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 512 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 513 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 514
 515 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 516 #
 517 # needed by rpm
 518 SET(CPACK_SET_DESTDIR "ON")
 519 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 520 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 521 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 522 #
 523 # the next ones are needed by deb
 524 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 525 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 526
 527 # This is experimental, valid on _my_ system (Kornel)
 528 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 529 IF(ASPELL_FOUND)
 530   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 531 ENDIF()
 532 #
 533 # for the next ones, cpack insists on data with values in some file
 534 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 535 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 536
 537 # Find the revision number and use it as the release in rpm-package-build.
 538 # This way we may omit the otherwise needed "--force" parameter when
 539 # installing from that rpm package.
 540 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 541 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 542 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 543   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 544   # We use this value also to set the package-patch-value
 545   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 546     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 547   endif()
 548 endif()
 549
 550 # we do not have a readme or welcome data,
 551 # so we do not provide infofiles for
 552 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 553
 554 if(LYX_INSTALL)
 555         include(CPack)
 556 endif()
 557
 558 #Now it is possible to create some packages
 559 # cd <BuildDir>
 560 # make package
 561 #############################################################################################
 562 # So, e.g. for variables
 563 #    CMAKE_PROJECT_NAME                     : lyx
 564 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 565 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 566 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 567 #    CMAKE_SYSTEM_NAME                      : Linux
 568 #    CPACK_BINARY_DEB:BOOL                  : ON
 569 #
 570 # the package name builds as "lyx-2.0.1-Linux.deb"
 571 #
 572 ############################## rpm ################################### deb ##################
 573 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 574 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 575 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 576 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 577 #
 578 message(STATUS)