development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 #not really needed
   8 #CMAKE_MINIMUM_REQUIRED(VERSION 2.4.4 FATAL_ERROR)
   9
  10
  11 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  12 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  13
  14 set (EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  15
  16 set(PACKAGE lyx)
  17 set(PACKAGE_VERSION 1.5.1)
  18 set(LYX_DATE "August, 2007")
  19 #TODO
  20 set(VERSION_INFO "CMake Build")
  21
  22 if(WIN32)
  23         set(USE_WINDOWS_PACKAGING 1)
  24 elseif(APPLE)
  25         set(USE_MACOSX_PACKAGING 1)
  26 else(WIN32)
  27         set(USE_POSIX_PACKAGING 1)
  28 endif(WIN32)
  29
  30 if(NOT GROUP_CODE)
  31         #set(GROUP_CODE "The Golden Code")
  32         set(GROUP_CODE flat)
  33 endif(NOT GROUP_CODE)
  34
  35 # lyx's source files
  36 set(LYX_CPP_FILES *.cpp)
  37 set(LYX_HPP_FILES *.h)
  38
  39 include(LyXPaths)
  40 include(LyXMacros)
  41 include(ProjectSourceGroup)
  42
  43 if(merge)
  44         set(merge 1 CACHE TYPE STRING FORCE)
  45         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  46         message(STATUS "")
  47         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  48         message(STATUS "")
  49         set(disable-pch  1)
  50 else(merge)
  51         set(merge 0 CACHE TYPE STRING FORCE)
  52         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
  53         message(STATUS "Enable merging files with -Dmerge=1")
  54 endif(merge)
  55
  56
  57 set(CMAKE_BUILD_TYPE)
  58 if(profile)
  59         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
  60         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
  61         set(profile)
  62 endif(profile)
  63 if(release)
  64         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
  65         set(release)
  66 endif(release)
  67 if(debug)
  68         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
  69 endif(debug)
  70
  71 if(shared)
  72         set(library_type SHARED)
  73         message(STATUS "building shared libraries")
  74 else(shared)
  75         set(library_type STATIC)
  76 endif(shared)
  77
  78 if(UNIX)
  79         if(NOT quiet)
  80                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
  81                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
  82                 message(STATUS "")
  83         endif(NOT quiet)
  84         set(LYX_CXX_FLAGS -Wall)
  85         if(stdlib-debug)
  86                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
  87         endif(stdlib-debug)
  88         if(concept-checks)
  89                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
  90         endif(concept-checks)
  91         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
  92         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
  93         set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
  94         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
  95 endif(UNIX)
  96
  97
  98 set(qt_postfix qt4)
  99 project(lyx-${qt_postfix})
 100 find_package(Qt4 REQUIRED)
 101 add_definitions(-DQT_CLEAN_NAMESPACE -DQT_NO_STL -DQT_NO_KEYWORDS)
 102
 103 find_package(ZLIB REQUIRED)
 104
 105 if(all OR aspell)
 106         set(aspell TRUE CACHE TYPE STRING)
 107         find_package(ASPELL REQUIRED)
 108 else(all OR aspell)
 109         find_package(ASPELL)
 110 endif(all OR aspell)
 111 set(aspell)
 112
 113 message("")
 114 if(nls OR all)
 115         set(nls TRUE CACHE TYPE STRING)
 116         add_definitions(-DENABLE_NLS=1)
 117         message("----- Building with ENABLE_NLS")
 118 else(nls OR all)
 119         message("----- No nls, to enable use -Dnls=1")
 120 endif(nls OR all)
 121 set(nls)
 122 if(ASPELL_FOUND)
 123         add_definitions(-DUSE_ASPELL=1)
 124         message("----- Building with USE_ASPELL")
 125 else(ASPELL_FOUND)
 126         message("----- No aspell, to get more information use -Daspell=1")
 127 endif(ASPELL_FOUND)
 128 set(all)
 129
 130 if(WIN32)
 131         if(noconsole)
 132                 set(noconsole TRUE CACHE TYPE STRING)
 133                 set(WIN32_CONSOLE WIN32)
 134                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 135                 message("----- Console disabled")
 136         else(noconsole)
 137                 message("----- Console enabled, disable it with -Dnoconsole=1")
 138         endif(noconsole)
 139 endif(WIN32)
 140
 141 set(LYX_DIR         "")
 142 set(TOP_SRCDIR      "${TOP_SRC_DIR}")
 143 set(PROGRAM_SUFFIX  "")
 144 set(LOCALEDIR       "")
 145
 146 message("")
 147 message("----- LYX_DIR       : ${LYX_DIR}")
 148 message("----- TOP_SRCDIR    : ${TOP_SRCDIR}")
 149 message("----- PROGRAM_SUFFIX: ${PROGRAM_SUFFIX}")
 150 message("----- LOCALEDIR     : ${LOCALEDIR}")
 151 message("")
 152
 153 if(MSVC)
 154         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 155         # disable checked iterators for msvc release builds to get maximum speed
 156         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 157 endif(MSVC)
 158
 159 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 160
 161 if(MSVC AND NOT disable-pch)
 162         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h    ${CMAKE_BINARY_DIR}/pcheaders.h)
 163         configure_file(${CMAKE_SOURCE_DIR}/config.C.cmake ${CMAKE_BINARY_DIR}/config_pch.C)
 164         macro(lyx_add_msvc_pch name_)
 165                 SET_SOURCE_FILES_PROPERTIES(${${name_}_sources} PROPERTIES COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 166                 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/config_pch.C PROPERTIES COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 167                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.C ${CMAKE_BINARY_DIR}/pcheaders.h)
 168                 add_definitions(/DLYX_ENABLE_PCH)
 169         endmacro(lyx_add_msvc_pch)
 170         set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 171         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 172         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 173 else(MSVC AND NOT disable-pch)
 174         set(disable-pch TRUE CACHE TYPE STRING)
 175         macro(lyx_add_msvc_pch)
 176         endmacro(lyx_add_msvc_pch)
 177 endif(MSVC AND NOT disable-pch)
 178
 179 if(MSVC)
 180         if(WALL)
 181                 set(WALL 1 CACHE TYPE STRING FORCE)
 182
 183                 # Use the highest warning level
 184                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 185                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 186
 187                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 188                         STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 189                 else(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 190                         SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 191                 endif(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 192
 193                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 194                         STRING(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 195                 else(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 196                         SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 197                 endif(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 198
 199                 # add here warnings which should produce an error /weXXXX
 200                 SET(MSVC_W_ERROR   "/we4101 /we4189")
 201                 # add here warnings which should be disabled /wdXXXX
 202                 SET(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 203
 204                 set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 205                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 206                 set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 207
 208         else(WALL)
 209                 set(WALL 0 CACHE TYPE STRING FORCE)
 210
 211                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 212                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 213
 214                 # add here warnings which should produce an error /weXXXX
 215                 SET(MSVC_W_ERROR   "/we4101 /we4189")
 216                 # add here warnings which should be disabled /wdXXXX
 217                 SET(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4267 /wd4180")
 218
 219                 set(CMAKE_CXX_FLAGS_DEBUG    "${CMAKE_CXX_FLAGS_DEBUG}         ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 220                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE}       ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 221                 set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 222
 223         endif(WALL)
 224
 225         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 226         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 227         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 228         message("")
 229
 230 endif(MSVC)
 231
 232 # create config.h
 233 include(ConfigureChecks.cmake)
 234 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 235
 236 find_package(ICONV REQUIRED)
 237 add_definitions(-DHAVE_ICONV=1)
 238
 239
 240 #TODO: insource is not the best place
 241 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 242                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 243
 244 include_directories(
 245         ${CMAKE_BINARY_DIR}
 246         ${TOP_SRC_DIR}/src
 247         ${TOP_SRC_DIR}/boost
 248         ${QT_INCLUDES}
 249 )
 250
 251 add_subdirectory(boost)
 252 add_subdirectory(intl)
 253 add_subdirectory(src)
 254
 255
 256 include(../Install)
 257