development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2011 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2011 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # Supress regeneration
  22 set(CMAKE_SUPPRESS_REGENERATION FALSE)
  23
  24 # where to look first for cmake modules,
  25 # before ${CMAKE_ROOT}/Modules is checked
  26 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  27 include(LyXMacros)
  28
  29
  30 # Usage LYX_OPTION
  31 # 1. parameter: option name without prefix 'LYX_'
  32 # 2. parameter: description
  33 # 3. parameter: default value, ON or OFF
  34 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  35
  36
  37 LYX_OPTION_INIT()
  38
  39 # Options for all compilers/systems
  40 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 LYX_OPTION(NLS "Use nls" OFF ALL)
  43 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  44 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  45 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  46 LYX_OPTION(DEVEL_VERSION "Build developer version" OFF ALL)
  47 LYX_OPTION(RELEASE "Build release version, build debug when disabled" ON ALL)
  48 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  49 LYX_OPTION(PCH "Use precompiled headers" OFF ALL)
  50 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  51 LYX_OPTION(MERGE_REBUILD "Rebuild generated files from merged files build" OFF ALL)
  52 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  53 LYX_OPTION(INSTALL_PREFIX "Install path for LyX" OFF ALL)
  54 LYX_OPTION(EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  55
  56 # GCC specific
  57 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  58 LYX_OPTION(EXTERNAL_BOOST "Use external boost" OFF GCC)
  59 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  60 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  61 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  62 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  63 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  64
  65 # MSVC specific
  66 LYX_OPTION(CONSOLE "Show console on Windows" ON MSVC)
  67 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  68 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  69 LYX_OPTION(CONFIGURE_CHECKS "Also run configure checks for MSVC" OFF MSVC)
  70 LYX_OPTION(3RDPARTY_DOWNLOAD "Download precompiled 3rd party libraries for MSVC 10" OFF MSVC)
  71
  72 # Check option dependencies
  73 if(LYX_CPACK)
  74         set(LYX_INSTALL ON)
  75 endif()
  76
  77 if(LYX_INSTALL)
  78         set(LYX_NLS ON)
  79         if(NOT LYX_3RDPARTY_DOWNLOAD)
  80                 set(LYX_ASPELL ON)
  81         endif()
  82         if (WIN32)
  83                 set(LYX_HUNSPELL ON)
  84         endif()
  85         set(LYX_CONSOLE OFF)
  86         set(LYX_PACKAGE_SUFFIX ON)
  87         set(LYX_RELEASE ON)
  88         set(LYX_PROFILE OFF)
  89 endif()
  90
  91 if(LYX_MERGE_FILES)
  92         set(LYX_PCH OFF)
  93 else()
  94         set(LYX_MERGE_REBUILD OFF)
  95 endif()
  96
  97 if(LYX_3RDPARTY_DOWNLOAD)
  98         message(STATUS)
  99         set(LYX_3RDPARTY_DIR ${CMAKE_BINARY_DIR}/msvc10-deps)
 100         message(STATUS "Using downloaded 3rd party libraries in ${LYX_3RDPARTY_DIR}")
 101         set(3rdparty_files
 102                 crt-msvc2010-x86.zip
 103                 dict-hunspell-all.zip
 104                 dtl-modified-msvc2010-x86.zip
 105                 dvipost-1.1-modified-msvc2010-x86.zip
 106                 gettext-tools-0.18.1-x86.zip
 107                 ghostscript-8.71-msvc2010-x86.zip
 108                 hunspell-1.2.11-msvc2010-x86.zip
 109                 iconv-1.13.1-msvc2010-x86.zip
 110                 imagemagick-6.6.3-0-modified-msvc2010-x86.zip
 111                 libintl-0.18.1-msvc2010-x86.zip
 112                 netpbm-pnmcrop-10.27-x86.zip
 113                 pdftools-msvc2010-x86.zip
 114                 pdfview-x86.zip
 115                 python-2.6.5-msvc2010-x86.zip
 116                 thes-mythes-all.zip
 117                 zlib-1.2.5-msvc2010-x86.zip)
 118         foreach(it ${3rdparty_files})
 119                 set(already_downloaded already_downloaded-NOTFOUND CACHE PATH "downloaded" FORCE)
 120                 find_file(already_downloaded ${it} "${LYX_3RDPARTY_DIR}/downloads")
 121                 if(NOT already_downloaded)
 122                         message(STATUS "Downloading ${it} ...")
 123                         file(DOWNLOAD ftp://ftp.devel.lyx.org/pub/contrib/windows/bin/${it} ${LYX_3RDPARTY_DIR}/downloads/${it} SHOW_PROGRESS)
 124                         execute_process(COMMAND ${CMAKE_COMMAND} -E tar xzf ${LYX_3RDPARTY_DIR}/downloads/${it}
 125                                       WORKING_DIRECTORY ${LYX_3RDPARTY_DIR})
 126                 endif()
 127         endforeach()
 128         set(GNUWIN32_DIR ${LYX_3RDPARTY_DIR})
 129 endif()
 130
 131
 132 message(STATUS)
 133
 134 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
 135 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
 136
 137
 138
 139 if(UNIX OR MINGW)
 140         execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
 141         message(STATUS "Using GCC version ${GCC_VERSION}")
 142         if(NOT GCC_VERSION VERSION_LESS 4.4)
 143                 set(LYX_USE_TR1 1)
 144                 # GCC <= 4.5 does not support regex: there are linker errors
 145                 # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
 146                 set(LYX_USE_TR1_REGEX 0)
 147         endif()
 148 else()
 149         if(MSVC10)
 150                 set(LYX_USE_TR1 1)
 151                 set(LYX_USE_TR1_REGEX 1)
 152         endif()
 153 endif()
 154
 155
 156 set(VERSION_INFO "CMake Build")
 157
 158 # Try to get some informations from configure.ac
 159
 160 include(LyXPaths)    #called here to define the needed TOP_SRC_DIR-variable
 161 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 162
 163 if(WIN32)
 164         set(USE_WINDOWS_PACKAGING 1)
 165 elseif(APPLE)
 166         set(USE_MACOSX_PACKAGING 1)
 167 else()
 168         set(USE_POSIX_PACKAGING 1)
 169 endif()
 170
 171 macro(setstripped _varname _value)
 172         string(STRIP ${_value} _v)
 173         if(USE_POSIX_PACKAGING)
 174                 string(TOLOWER ${_v} ${_varname})
 175         else()
 176                 set(${_varname} ${_v})
 177         endif()
 178 endmacro(setstripped)
 179
 180 foreach(_c_l ${_config_lines} )
 181         if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 182                 setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 183                 setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 184                 setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 185                 if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 186                         set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 187                         set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 188                         set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 189                         set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 190                         set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 191                 endif()
 192         endif()
 193         if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 194                 set(LYX_DATE "${CMAKE_MATCH_1}")
 195         endif()
 196 endforeach(_c_l)
 197
 198
 199 if (LYX_INSTALL_PREFIX)
 200         set(CMAKE_INSTALL_PREFIX ${LYX_INSTALL_PREFIX} CACHE PATH "LyX user's choice install prefix" FORCE)
 201         set(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 202 endif()
 203
 204 if(LYX_PACKAGE_SUFFIX)
 205         set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 206 else()
 207         set(PACKAGE ${PACKAGE_BASE})
 208 endif()
 209
 210 if(LYX_PROGRAM_SUFFIX)
 211         set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 212 else()
 213         set(PROGRAM_SUFFIX "")
 214 endif()
 215
 216
 217 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 218         # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 219         if (UNIX)
 220                 # don't use the default "/usr/local"
 221                 # but respect the user-choice on the command-line
 222                 if(LYX_INSTALL_SUFFIX)
 223                         set(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX default install prefix" FORCE)
 224                 else()
 225                         set(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX default install prefix" FORCE)
 226                 endif()
 227         endif()
 228         if(WIN32)
 229                 set(CMAKE_INSTALL_PREFIX LYX_INSTALLED CACHE PATH "LyX default install prefix" FORCE)
 230         endif()
 231 endif()
 232
 233 if (WIN32)
 234         set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 235 else()
 236         set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 237 endif()
 238
 239 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 240 set(LYX_LOCALEDIR "locale")
 241 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 242 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 243
 244
 245 if(NOT GROUP_CODE)
 246         #set(GROUP_CODE "The Golden Code")
 247         set(GROUP_CODE flat)
 248 endif()
 249
 250 # lyx's source files
 251 set(LYX_CPP_FILES *.cpp)
 252 set(LYX_HPP_FILES *.h)
 253 set(LYX_MOC_FILES moc_*.cpp)
 254
 255
 256 include(ProjectSourceGroup)
 257
 258
 259 if(LYX_PROFILE)
 260         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 261         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 262 endif()
 263
 264 if(LYX_RELEASE)
 265         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build release version" FORCE)
 266 else()
 267         set(CMAKE_BUILD_TYPE Debug CACHE STRING "Build debug version" FORCE)
 268 endif()
 269
 270 # When shared libs are supported enable this option
 271 #LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
 272 if(LYX_SHARED_LIBRARIES)
 273         set(library_type SHARED)
 274 else()
 275         set(library_type STATIC)
 276 endif()
 277
 278 if(NOT MSVC)
 279         if(NOT LYX_QUIET)
 280                 set(CMAKE_VERBOSE_MAKEFILE ON)
 281         endif()
 282         set(LYX_CXX_FLAGS "-Wall -Wunused-parameter")
 283         if(LYX_STDLIB_DEBUG)
 284                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 285         endif()
 286         if(LYX_CONCEPT_CHECKS)
 287                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 288         endif()
 289         set(CMAKE_CXX_FLAGS       "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 290         set(CMAKE_CXX_FLAGS_DEBUG "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 291         if(MINGW)
 292                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 293         else()
 294                 set(CMAKE_CXX_FLAGS_RELEASE "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 295         endif()
 296         set(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 297 endif()
 298
 299
 300 find_package(Qt4 REQUIRED)
 301 find_package(ICONV REQUIRED)
 302 find_package(ZLIB REQUIRED)
 303
 304 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 305
 306 if(LYX_ASPELL)
 307         find_package(ASPELL)
 308         include_directories(${ASPELL_INCLUDE_DIR})
 309 endif()
 310
 311 if(LYX_ENCHANT)
 312         find_package(Enchant REQUIRED)
 313         include_directories(${ENCHANT_INCLUDE_DIR})
 314 endif()
 315
 316 if(LYX_HUNSPELL)
 317         find_package(Hunspell REQUIRED)
 318         include_directories(${HUNSPELL_INCLUDE_DIR})
 319 endif()
 320
 321 if(LYX_NLS)
 322         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 323         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 324                 message(FATAL_ERROR "Python 2.6 needed!")
 325         endif()
 326         find_package(LyXGettext REQUIRED)
 327         include_directories(${TOP_SRC_DIR}/po)
 328         add_subdirectory(po)
 329 endif()
 330
 331 if(LYX_EXTERNAL_LIBINTL)
 332         find_package(Libintl REQUIRED)
 333         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 334 else()
 335         add_subdirectory(intl)
 336 endif()
 337
 338 if(LYX_EXTERNAL_BOOST)
 339         message(STATUS "Searching for boost")
 340         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 341         if(Boost_FOUND)
 342                 message(STATUS "Boost found")
 343                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 344                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 345         else()
 346                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 347         endif()
 348 else()
 349         if(LYX_USE_TR1_REGEX)
 350                 set(Lyx_Boost_Libraries boost_signals)
 351         else()
 352                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 353         endif()
 354         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 355         include_directories(${TOP_SRC_DIR}/boost)
 356         add_subdirectory(boost)
 357 endif()
 358
 359
 360
 361
 362 if(WIN32)
 363         if(NOT LYX_CONSOLE)
 364                 set(WIN32_CONSOLE WIN32)
 365                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 366         endif()
 367         if(MSVC)
 368                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 369                 # disable checked iterators for msvc release builds to get maximum speed
 370                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 371         else()
 372                 add_definitions(-DWINVER=0x0500)
 373         endif()
 374 endif()
 375
 376 message(STATUS "")
 377 foreach(_v PACKAGE PACKAGE_VERSION
 378         PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 379         LYX_ABS_TOP_SRCDIR
 380         LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 381         if(NOT DEFINED ${_v})
 382                 message(FATAL_ERROR "${_v} not defined")
 383         endif()
 384         string(SUBSTRING "${_v}                            " 0 28 _v1)
 385         message(STATUS "----- ${_v1}: ${${_v}}")
 386 endforeach(_v)
 387 message(STATUS "")
 388
 389
 390 if(LYX_PCH)
 391         # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 392         # Not sure if it works for all non-msvc compilers
 393         include(PCHSupport_26)
 394         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 395         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 396         add_definitions(-DLYX_ENABLE_PCH)
 397
 398         if(MSVC)
 399                 macro(lyx_add_msvc_pch name_)
 400                         set_source_files_properties(${${name_}_sources} PROPERTIES
 401                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 402                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 403                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 404                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 405                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 406                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 407                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 408                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 409                 endmacro(lyx_add_msvc_pch)
 410                 macro(lyx_add_gcc_pch name_)
 411                 endmacro()
 412         else()
 413                 macro(lyx_add_msvc_pch name_)
 414                 endmacro()
 415                 macro(lyx_add_gcc_pch name_)
 416                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 417                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 418                 endmacro()
 419         endif()
 420 else()
 421         macro(lyx_add_msvc_pch)
 422         endmacro(lyx_add_msvc_pch)
 423         macro(lyx_add_gcc_pch name_)
 424         endmacro()
 425 endif()
 426
 427 if(MSVC)
 428         if(LYX_VLD)
 429                 set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 430                 set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 431                 set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 432                 include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 433         endif()
 434
 435         if(LYX_WALL)
 436                 # Use the highest warning level
 437                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 438
 439                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 440                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 441                 else()
 442                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 443                 endif()
 444
 445                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 446                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 447                 else()
 448                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 449                 endif()
 450
 451                 # add here warnings which should produce an error /weXXXX
 452                 set(MSVC_W_ERROR   "/we4101 /we4189")
 453                 # add here warnings which should be disabled /wdXXXX
 454                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 455
 456                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 457                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 458                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 459
 460         else()
 461                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 462
 463                 # add here warnings which should produce an error /weXXXX
 464                 set(MSVC_W_ERROR   "/we4101 /we4189")
 465                 # add here warnings which should be disabled /wdXXXX
 466                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 467
 468                 set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 469                 set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 470                 set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 471
 472         endif()
 473         set(CMAKE_CXX_FLAGS_DEBUG      "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 474         set(CMAKE_CXX_FLAGS_RELEASE    "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 475         set(CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 476
 477         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 478         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 479         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 480         message(STATUS "")
 481 endif()
 482
 483
 484 if(LYX_DEBUG_GLIBC)
 485         set(_GLIBCXX_DEBUG 1)
 486 endif()
 487
 488 if(LYX_DEBUG_GLIBC_PEDANTIC)
 489         set(_GLIBCXX_DEBUG_PEDANTIC 1)
 490 endif()
 491
 492 # compiler tests, config.h generation
 493 if(MSVC AND NOT LYX_CONFIGURE_CHECKS)
 494         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 495 else()
 496         include(ConfigureChecks.cmake)
 497         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 498 endif()
 499
 500 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 501
 502
 503 add_subdirectory(src)
 504 add_subdirectory(lyx2lyx)
 505 add_subdirectory(scripts)
 506
 507
 508 if(LYX_INSTALL)
 509         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 510         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 511                 message(FATAL_ERROR "Perl required!")
 512         endif()
 513         add_subdirectory(man)
 514         add_subdirectory(doc)
 515         include(../Install)
 516 endif()
 517
 518
 519 message(STATUS)
 520 message(STATUS "Build options, switch LYX_* variables by -DLYX_*=1 or 0:")
 521 message(STATUS)
 522 LYX_OPTION_LIST_ALL()
 523
 524
 525 set(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 526 set(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 527 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 528
 529 set(CPACK_SOURCE_GENERATOR TGZ ZIP TBZ2)
 530 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${TOP_SRC_DIR};/") # http://www.mail-archive.com/cmake@cmake.org/msg33720.html
 531
 532 set(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 533 #
 534 # needed by rpm
 535 set(CPACK_SET_DESTDIR "ON")
 536 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 537 set(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 538 set(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 539 #
 540 # the next ones are needed by deb
 541 set(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 542 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 543
 544 # This is experimental, valid on _my_ system (Kornel)
 545 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 546 if(ASPELL_FOUND)
 547         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 548 endif()
 549 if(ENCHANT_FOUND)
 550         set(CPACK_DEBIAN_PACKAGE_DEPENDS "libenchant1c2a (>= 1.6.0-0),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 551 endif()
 552 if(LYX_EXTERNAL_BOOST)
 553         if(Boost_FOUND)
 554                 set(CPACK_DEBIAN_PACKAGE_DEPENDS "libboost-regex1.40.0 (>= 1.40.0-4),libboost-signals1.40.0 (>= 1.40.0-4),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 555         endif()
 556 endif()
 557 #
 558 # for the next ones, cpack insists on data with values in some file
 559 set(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 560 set(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 561
 562 # Find the revision number and use it as the release in rpm-package-build.
 563 # This way we may omit the otherwise needed "--force" parameter when
 564 # installing from that rpm package.
 565 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 566 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 567 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 568         EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 569         # We use this value also to set the package-patch-value
 570         if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 571                 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 572         endif()
 573 endif()
 574
 575 # we do not have a readme or welcome data,
 576 # so we do not provide infofiles for
 577 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 578
 579 include(CPack)
 580
 581 #Now it is possible to create some packages
 582 # cd <BuildDir>
 583 # make package
 584 #############################################################################################
 585 # So, e.g. for variables
 586 #    CMAKE_PROJECT_NAME                     : lyx
 587 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 588 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 589 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 590 #    CMAKE_SYSTEM_NAME                      : Linux
 591 #    CPACK_BINARY_DEB:BOOL                  : ON
 592 #
 593 # the package name builds as "lyx-2.0.1-Linux.deb"
 594 #
 595 ############################## rpm ################################### deb ##################
 596 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 597 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 598 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 599 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 600 #
 601 message(STATUS)