development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 #not really needed
   8 #CMAKE_MINIMUM_REQUIRED(VERSION 2.4.4 FATAL_ERROR)
   9
  10 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  11
  12 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  13 # is checked
  14 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  15 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  16
  17 # Supress regeneration
  18 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  19
  20 set(PACKAGE lyx)
  21 set(PACKAGE_VERSION 1.5.1)
  22 set(LYX_DATE "August, 2007")
  23 #TODO
  24 set(VERSION_INFO "CMake Build")
  25
  26 set(PROGRAM_SUFFIX "")
  27 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
  28 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
  29 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
  30
  31
  32 if(WIN32)
  33         set(USE_WINDOWS_PACKAGING 1)
  34 elseif(APPLE)
  35         set(USE_MACOSX_PACKAGING 1)
  36 else()
  37         set(USE_POSIX_PACKAGING 1)
  38 endif()
  39
  40 if(NOT GROUP_CODE)
  41         #set(GROUP_CODE "The Golden Code")
  42         set(GROUP_CODE flat)
  43 endif()
  44
  45 # lyx's source files
  46 set(LYX_CPP_FILES *.cpp)
  47 set(LYX_HPP_FILES *.h)
  48
  49 include(LyXPaths)
  50 include(LyXMacros)
  51 include(ProjectSourceGroup)
  52
  53 if(merge OR merge_rebuild)
  54         set(merge 1 CACHE TYPE STRING FORCE)
  55         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  56         message(STATUS "")
  57         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  58         message(STATUS "")
  59         set(disable-pch  1)
  60 else()
  61         set(merge 0 CACHE TYPE STRING FORCE)
  62         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
  63         message(STATUS "Enable merging files with -Dmerge=1")
  64 endif()
  65
  66
  67 set(CMAKE_BUILD_TYPE Release)
  68
  69 if(profile)
  70         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
  71         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
  72             CACHE TYPE STRING FORCE)
  73         set(profile)
  74 endif()
  75
  76 if(release)
  77         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
  78         set(release)
  79 endif()
  80
  81 if(debug)
  82         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
  83 endif()
  84
  85 if(shared)
  86         set(library_type SHARED)
  87         message(STATUS "building shared libraries")
  88 else()
  89         set(library_type STATIC)
  90 endif()
  91
  92 if(UNIX)
  93         if(NOT quiet)
  94                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
  95                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
  96                 message(STATUS "")
  97         endif()
  98         set(LYX_CXX_FLAGS -Wall)
  99         if(stdlib-debug)
 100                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 101         endif()
 102         if(concept-checks)
 103                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 104         endif()
 105         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 106         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 107         set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 108         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 109 endif()
 110
 111
 112 project(lyx)
 113 find_package(Qt4 REQUIRED)
 114 add_definitions(-DQT_CLEAN_NAMESPACE -DQT_NO_STL -DQT_NO_KEYWORDS)
 115
 116 find_package(ZLIB REQUIRED)
 117
 118 if(all OR aspell)
 119         set(aspell TRUE CACHE TYPE STRING)
 120         find_package(ASPELL REQUIRED)
 121 else()
 122         find_package(ASPELL)
 123 endif()
 124 set(aspell)
 125
 126 message("")
 127 if(nls OR all)
 128         set(nls TRUE CACHE TYPE STRING)
 129         add_definitions(-DENABLE_NLS=1)
 130         message("----- Building with ENABLE_NLS")
 131 else()
 132         message("----- No nls, to enable use -Dnls=1")
 133 endif()
 134 set(nls)
 135 if(ASPELL_FOUND)
 136         add_definitions(-DUSE_ASPELL=1)
 137         message("----- Building with USE_ASPELL")
 138 else()
 139         message("----- No aspell, to get more information use -Daspell=1")
 140 endif()
 141 set(all)
 142
 143 if(WIN32)
 144         if(noconsole)
 145                 set(noconsole TRUE CACHE TYPE STRING)
 146                 set(WIN32_CONSOLE WIN32)
 147                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 148                 message("----- Console disabled")
 149         else()
 150                 message("----- Console enabled, disable it with -Dnoconsole=1")
 151         endif()
 152 endif()
 153
 154 set(PROGRAM_SUFFIX "\"\"")
 155 set(LYX_ABS_TOP_SRCDIR "${CMAKE_SOURCE_DIR}")
 156 set(LYX_ABS_INSTALLED_DATADIR "/usr/local/share/lyx")
 157 set(LYX_ABS_INSTALLED_LOCALEDIR "/usr/local/share/locale")
 158
 159 message("")
 160 message("----- PROGRAM_SUFFIX              : ${PROGRAM_SUFFIX}")
 161 message("----- LYX_ABS_TOP_SRCDIR          : ${LYX_ABS_TOP_SRCDIR}")
 162 message("----- LYX_ABS_INSTALLED_DATADIR   : ${LYX_ABS_INSTALLED_DATADIR}")
 163 message("----- LYX_ABS_INSTALLED_LOCALEDIR : ${LYX_ABS_INSTALLED_LOCALEDIR}")
 164 message("")
 165
 166 if(MSVC)
 167         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 168         # disable checked iterators for msvc release builds to get maximum speed
 169         set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 170 endif()
 171
 172 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 173
 174 if(MSVC AND NOT disable-pch)
 175         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 176                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 177         configure_file(${CMAKE_SOURCE_DIR}/config.C.cmake
 178                 ${CMAKE_BINARY_DIR}/config_pch.C)
 179         macro(lyx_add_msvc_pch name_)
 180                 set_source_files_properties(${${name_}_sources} PROPERTIES
 181                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 182                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.C PROPERTIES
 183                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 184                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.C
 185                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 186                 add_definitions(/DLYX_ENABLE_PCH)
 187         endmacro(lyx_add_msvc_pch)
 188         set(CMAKE_CXX_FLAGS_DEBUG
 189                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 190         set(CMAKE_CXX_FLAGS_RELEASE
 191                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 192         set(CMAKE_CXX_FLAGS_MINSIZEREL
 193                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 194 else()
 195         set(disable-pch TRUE CACHE TYPE STRING)
 196         macro(lyx_add_msvc_pch)
 197         endmacro(lyx_add_msvc_pch)
 198 endif()
 199
 200 if(MSVC)
 201         if(WALL)
 202                 set(WALL 1 CACHE TYPE STRING FORCE)
 203
 204                 # Use the highest warning level
 205                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 206                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 207
 208                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 209                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 210                 else()
 211                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 212                 endif()
 213
 214                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 215                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 216                 else()
 217                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 218                 endif()
 219
 220                 # add here warnings which should produce an error /weXXXX
 221                 set(MSVC_W_ERROR   "/we4101 /we4189")
 222                 # add here warnings which should be disabled /wdXXXX
 223                 set(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 224
 225                 set(CMAKE_CXX_FLAGS_DEBUG
 226                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 227                 set(CMAKE_CXX_FLAGS_RELEASEs
 228                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 229                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 230                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 231
 232         else()
 233                 set(WALL 0 CACHE TYPE STRING FORCE)
 234
 235                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 236                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 237
 238                 # add here warnings which should produce an error /weXXXX
 239                 set(MSVC_W_ERROR   "/we4101 /we4189")
 240                 # add here warnings which should be disabled /wdXXXX
 241                 set(MSVC_W_DISABLE "/wd4800 /wd4996 /wd4267 /wd4180")
 242
 243                 set(CMAKE_CXX_FLAGS_DEBUG
 244                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 245                 set(CMAKE_CXX_FLAGS_RELEASE
 246                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 247                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 248                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 249
 250         endif()
 251
 252         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 253         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 254         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 255         message("")
 256
 257 endif()
 258
 259 # create config.h
 260 include(ConfigureChecks.cmake)
 261 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 262
 263 find_package(ICONV REQUIRED)
 264 add_definitions(-DHAVE_ICONV=1)
 265
 266
 267 #TODO: insource is not the best place
 268 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 269                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 270
 271 include_directories(
 272         ${CMAKE_BINARY_DIR}
 273         ${TOP_SRC_DIR}/src
 274         ${TOP_SRC_DIR}/boost)
 275
 276 add_subdirectory(boost)
 277 add_subdirectory(intl)
 278 add_subdirectory(src)
 279
 280 include(../Install)
 281