development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26
  27 # Usage LYX_OPTION
  28 # 1. parameter: option name without prefix 'LYX_'
  29 # 2. parameter: description
  30 # 3. parameter: default value, ON or OFF
  31 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  32 message(STATUS)
  33 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  34 message(STATUS)
  35
  36 LYX_OPTION(CPACK "Use the CPack management (Implies LYX_INSTALL option)" OFF ALL)
  37 if(LYX_CPACK)
  38         set(LYX_INSTALL ON CACHE BOOL "INSTALL option" FORCE)
  39 endif()
  40
  41 LYX_OPTION(INSTALL "Build install projects/rules (implies a bunch of other options)" OFF ALL)
  42 if(LYX_INSTALL)
  43         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  44         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  45         set(LYX_AIKSAURUS ON CACHE BOOL "Aiksaurus option" FORCE)
  46         if (WIN32)
  47                 set(LYX_HUNSPELL ON CACHE BOOL "Hunspell option" FORCE)
  48         endif()
  49         set(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  50         set(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  51         set(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  52         set(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  53         set(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  54 endif()
  55
  56 LYX_OPTION(NLS "Use nls" OFF ALL)
  57 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  58 LYX_OPTION(AIKSAURUS "Require Aiksaurus" OFF ALL)
  59 LYX_OPTION(ENCHANT "Require Enchant" OFF ALL)
  60 LYX_OPTION(HUNSPELL "Require Hunspell" OFF ALL)
  61 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  62 LYX_OPTION(RELEASE "Build release version" ON ALL)
  63 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  64 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  65 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  66 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  67 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  68 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  69 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  70 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  71 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  72 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  73 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  74 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  75 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  76 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  77 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  78 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  79
  80 message(STATUS)
  81
  82
  83
  84
  85 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  86 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  87
  88
  89
  90 if(UNIX OR MINGW)
  91     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  92     message(STATUS "Using GCC version ${GCC_VERSION}")
  93     if(NOT GCC_VERSION VERSION_LESS 4.4)
  94         set(LYX_USE_TR1 1)
  95         # GCC <= 4.5 does not support regex: there are linker errors
  96         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  97         set(LYX_USE_TR1_REGEX 0)
  98     endif()
  99 else()
 100     if(MSVC10)
 101         set(LYX_USE_TR1 1)
 102         set(LYX_USE_TR1_REGEX 1)
 103     endif()
 104 endif()
 105
 106
 107
 108 # Supress regeneration
 109 set(CMAKE_SUPPRESS_REGENERATION TRUE)
 110
 111 set(VERSION_INFO "CMake Build")
 112
 113 # Try to get some informations from configure.ac
 114
 115 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
 116 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 117
 118 if(WIN32)
 119   set(USE_WINDOWS_PACKAGING 1)
 120 elseif(APPLE)
 121   set(USE_MACOSX_PACKAGING 1)
 122 else()
 123   set(USE_POSIX_PACKAGING 1)
 124 endif()
 125
 126 macro(setstripped _varname _value)
 127   string(STRIP ${_value} _v)
 128   if(USE_POSIX_PACKAGING)
 129     string(TOLOWER ${_v} ${_varname})
 130   else()
 131     set(${_varname} ${_v})
 132   endif()
 133 endmacro(setstripped)
 134
 135 foreach(_c_l ${_config_lines} )
 136   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 137     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 138     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 139     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 140     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 141       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 142       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 143       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 144       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 145       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 146     endif()
 147   endif()
 148   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 149     set(LYX_DATE "${CMAKE_MATCH_1}")
 150   endif()
 151 endforeach(_c_l)
 152
 153
 154 if(LYX_PACKAGE_SUFFIX)
 155   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 156 else()
 157   set(PACKAGE ${PACKAGE_BASE})
 158 endif()
 159
 160 if(LYX_PROGRAM_SUFFIX)
 161   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 162 else()
 163   set(PROGRAM_SUFFIX "")
 164 endif()
 165
 166
 167 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 168   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 169   if (UNIX)
 170     # don't use the default "/usr/local"
 171     # but respect the user-choice on the command-line
 172     if(LYX_INSTALL_SUFFIX)
 173         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 174     else()
 175         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 176     endif()
 177   endif()
 178   if(WIN32)
 179     SET(CMAKE_INSTALL_PREFIX
 180       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 181   endif()
 182 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 183
 184 if (WIN32)
 185   set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 186 else()
 187   set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 188 endif()
 189
 190 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 191 set(LYX_LOCALEDIR "locale")
 192 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 193 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 194
 195
 196 if(NOT GROUP_CODE)
 197         #set(GROUP_CODE "The Golden Code")
 198         set(GROUP_CODE flat)
 199 endif()
 200
 201 # lyx's source files
 202 set(LYX_CPP_FILES *.cpp)
 203 set(LYX_HPP_FILES *.h)
 204 set(LYX_MOC_FILES moc_*.cpp)
 205
 206
 207 include(ProjectSourceGroup)
 208
 209
 210 if(LYX_PROFILE)
 211         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 212         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg" CACHE TYPE STRING FORCE)
 213 endif()
 214
 215 if(LYX_RELEASE)
 216         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 217 endif()
 218
 219 if(LYX_DEBUG)
 220         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 221 endif()
 222
 223
 224
 225 if(LYX_SHARED_LIBRARIES)
 226         set(library_type SHARED)
 227 else()
 228         set(library_type STATIC)
 229 endif()
 230
 231 if(NOT MSVC)
 232         if(NOT LYX_QUIET)
 233                 set(CMAKE_VERBOSE_MAKEFILE ON)
 234         endif()
 235         set(LYX_CXX_FLAGS -Wall)
 236         if(LYX_STDLIB_DEBUG)
 237                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 238         endif()
 239         if(LYX_CONCEPT_CHECKS)
 240                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 241         endif()
 242         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 243         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 244         if(MINGW)
 245                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 246         else()
 247                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 248         endif()
 249         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 250 endif()
 251
 252
 253 find_package(Qt4 REQUIRED)
 254 find_package(ICONV REQUIRED)
 255 find_package(ZLIB REQUIRED)
 256
 257 include_directories(${CMAKE_BINARY_DIR} ${TOP_SRC_DIR}/src)
 258
 259 if(LYX_ASPELL)
 260         find_package(ASPELL)
 261         include_directories(${ASPELL_INCLUDE_DIR})
 262 endif()
 263
 264 if(LYX_AIKSAURUS)
 265         find_package(AiksaurusLIB REQUIRED)
 266         include_directories(${AIKSAURUSLIB_INCLUDE_DIR})
 267 endif()
 268
 269 if(LYX_ENCHANT)
 270         find_package(Enchant REQUIRED)
 271         include_directories(${ENCHANT_INCLUDE_DIR})
 272 endif()
 273
 274 if(LYX_HUNSPELL)
 275         find_package(Hunspell REQUIRED)
 276         include_directories(${HUNSPELL_INCLUDE_DIR})
 277 endif()
 278
 279 if(LYX_NLS)
 280         FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 281         if(${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 282                 message(FATAL_ERROR "Python 2.6 needed!")
 283         endif()
 284         find_package(LyXGettext REQUIRED)
 285         include_directories(${TOP_SRC_DIR}/po)
 286         add_subdirectory(po)
 287 endif()
 288
 289 if(LYX_USE_EXTERNAL_LIBINTL)
 290         find_package(Libintl REQUIRED)
 291         add_definitions(-DHAVE_GETTEXT) #TODO move to config.h
 292 else()
 293         add_subdirectory(intl)
 294 endif()
 295
 296 if(LYX_USE_EXTERNAL_BOOST)
 297         message(STATUS "Searching for boost")
 298         find_package(Boost COMPONENTS signals regex) #TODO could REQUIRED be used
 299         if(Boost_FOUND)
 300                 message(STATUS "Boost found")
 301                 message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 302                 set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 303         else()
 304                 message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 305         endif()
 306 else()
 307         if(LYX_USE_TR1_REGEX)
 308                 set(Lyx_Boost_Libraries boost_signals)
 309         else()
 310                 set(Lyx_Boost_Libraries boost_signals boost_regex)
 311         endif()
 312         add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 313         include_directories(${TOP_SRC_DIR}/boost)
 314         add_subdirectory(boost)
 315 endif()
 316
 317
 318
 319
 320 if(WIN32)
 321         if(LYX_NO_CONSOLE)
 322                 set(WIN32_CONSOLE WIN32)
 323                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 324         endif()
 325         if(MSVC)
 326                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 327                 # disable checked iterators for msvc release builds to get maximum speed
 328                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 329         else()
 330                 add_definitions(-DWINVER=0x0500)
 331         endif()
 332 endif()
 333
 334 message(STATUS "")
 335 foreach(_v PACKAGE PACKAGE_VERSION
 336     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 337     LYX_ABS_TOP_SRCDIR
 338     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 339   if(NOT DEFINED ${_v})
 340     message(FATAL_ERROR "${_v} not defined")
 341   endif()
 342   string(SUBSTRING "${_v}                            " 0 28 _v1)
 343   message(STATUS "----- ${_v1}: ${${_v}}")
 344 endforeach(_v)
 345 message(STATUS "")
 346
 347
 348 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 349 # Not sure if it works for all non-msvc compilers
 350 include(PCHSupport_26)
 351
 352 if(NOT LYX_DISABLE_PCH)
 353
 354         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 355         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 356         add_definitions(-DLYX_ENABLE_PCH)
 357
 358         if(MSVC AND NOT MERGE_FILES)
 359                 macro(lyx_add_msvc_pch name_)
 360                         set_source_files_properties(${${name_}_sources} PROPERTIES
 361                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 362                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 363                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 364                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 365                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 366                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 367                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 368                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 369                 endmacro(lyx_add_msvc_pch)
 370                 macro(lyx_add_gcc_pch name_)
 371                 endmacro()
 372         else()
 373                 macro(lyx_add_msvc_pch name_)
 374                 endmacro()
 375                 macro(lyx_add_gcc_pch name_)
 376                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 377                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 378                 endmacro()
 379         endif()
 380 else()
 381         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 382         macro(lyx_add_msvc_pch)
 383         endmacro(lyx_add_msvc_pch)
 384         macro(lyx_add_gcc_pch name_)
 385         endmacro()
 386 endif()
 387
 388 if(MSVC)
 389         if(LYX_VLD)
 390            set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 391            set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 392            set(LYX_VLD_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 393            include(${LYX_VLD_PATH}/tools/cmake/vld.cmake)
 394         endif()
 395
 396         # TODO options
 397         if(LYX_WALL)
 398                 # Use the highest warning level
 399                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 400
 401                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 402                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 403                 else()
 404                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 405                 endif()
 406
 407                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 408                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 409                 else()
 410                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 411                 endif()
 412
 413                 # add here warnings which should produce an error /weXXXX
 414                 set(MSVC_W_ERROR   "/we4101 /we4189")
 415                 # add here warnings which should be disabled /wdXXXX
 416                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 417
 418                 set(CMAKE_CXX_FLAGS_DEBUG
 419                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 420                 set(CMAKE_CXX_FLAGS_RELEASE
 421                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 422                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 423                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 424
 425         else()
 426                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 427
 428                 # add here warnings which should produce an error /weXXXX
 429                 set(MSVC_W_ERROR   "/we4101 /we4189")
 430                 # add here warnings which should be disabled /wdXXXX
 431                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 432
 433                 set(CMAKE_CXX_FLAGS_DEBUG
 434                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 435                 set(CMAKE_CXX_FLAGS_RELEASE
 436                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 437                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 438                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 439
 440         endif()
 441         set(CMAKE_CXX_FLAGS_DEBUG
 442                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 443         set(CMAKE_CXX_FLAGS_RELEASE
 444                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 445         set(CMAKE_CXX_FLAGS_MINSIZEREL
 446                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 447
 448         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 449         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 450         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 451         message(STATUS "")
 452
 453 endif()
 454
 455
 456 if(LYX_DEBUG_GLIBC)
 457   set(_GLIBCXX_DEBUG 1)
 458 endif()
 459
 460 if(LYX_DEBUG_GLIBC_PEDANTIC)
 461   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 462 endif()
 463
 464 # compiler tests, config.h generation
 465 if(MSVC AND NOT CONFIGURECHECKS)
 466         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 467 else()
 468         include(ConfigureChecks.cmake)
 469         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 470 endif()
 471
 472 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 473
 474
 475 add_subdirectory(src)
 476 add_subdirectory(lyx2lyx)
 477 add_subdirectory(scripts)
 478
 479
 480 if(LYX_INSTALL)
 481         FIND_PROGRAM(LYX_PERL_EXECUTABLE perl)
 482         if(${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 483                 message(FATAL_ERROR "Perl required!")
 484         endif()
 485         add_subdirectory(man)
 486         add_subdirectory(doc)
 487         include(../Install)
 488 endif()
 489
 490
 491 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 492 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 493 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 494
 495 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 496 #
 497 # needed by rpm
 498 SET(CPACK_SET_DESTDIR "ON")
 499 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 500 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 501 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 502 #
 503 # the next ones are needed by deb
 504 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 505 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 506
 507 # This is experimental, valid on _my_ system (Kornel)
 508 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 509 IF(ASPELL_FOUND)
 510   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 511 ENDIF()
 512 #
 513 # for the next ones, cpack insists on data with values in some file
 514 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 515 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 516
 517 # Find the revision number and use it as the release in rpm-package-build.
 518 # This way we may omit the otherwise needed "--force" parameter when
 519 # installing from that rpm package.
 520 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 521 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 522 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 523   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 524   # We use this value also to set the package-patch-value
 525   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 526     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 527   endif()
 528 endif()
 529
 530 # we do not have a readme or welcome data,
 531 # so we do not provide infofiles for
 532 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 533
 534 include(CPack)
 535
 536 #Now it is possible to create some packages
 537 # cd <BuildDir>
 538 # make package
 539 #############################################################################################
 540 # So, e.g. for variables
 541 #    CMAKE_PROJECT_NAME                     : lyx
 542 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 543 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 544 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 545 #    CMAKE_SYSTEM_NAME                      : Linux
 546 #    CPACK_BINARY_DEB:BOOL                  : ON
 547 #
 548 # the package name builds as "lyx-2.0.1-Linux.deb"
 549 #
 550 ############################## rpm ################################### deb ##################
 551 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 552 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 553 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 554 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 555 #
 556 message(STATUS)