development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif()
  15
  16 set(LYX_PROJECT lyx)
  17 project(${LYX_PROJECT})
  18
  19 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  20
  21 # where to look first for cmake modules,
  22 # before ${CMAKE_ROOT}/Modules is checked
  23 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  24 include(LyXMacros)
  25
  26 message(STATUS)
  27 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  28
  29 # Usage LYX_OPTION
  30 # 1. parameter: option name without prefix 'LYX_'
  31 # 2. parameter: description
  32 # 3. parameter: default value, ON or OFF
  33 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  34 LYX_OPTION(NLS "Use nls" OFF ALL)
  35 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  36 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  37 LYX_OPTION(RELEASE "Build release version" ON ALL)
  38 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  39 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  40 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  41 LYX_OPTION(INSTALL "Build install projects/rules" OFF ALL)
  42 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" ON ALL)
  43 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  44 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  45 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  46 LYX_OPTION(WALL "Enable all warnings" OFF MSVC)
  47 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  48 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  49 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  50 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  51 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  52 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  53 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  54 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  55 LYX_OPTION(ENCRYPTION "Build with encryption functionality" OFF ALL)
  56
  57 message(STATUS)
  58
  59 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  60 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  61
  62
  63
  64 if(UNIX OR MINGW)
  65     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  66     message(STATUS "Using GCC version ${GCC_VERSION}")
  67     if(NOT GCC_VERSION VERSION_LESS 4.4)
  68         set(LYX_USE_TR1 1)
  69         # GCC <= 4.5 does not support regex: there are linker errors
  70         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  71         set(LYX_USE_TR1_REGEX 0)
  72     endif()
  73 else()
  74     if(MSVC10)
  75         set(LYX_USE_TR1 1)
  76         set(LYX_USE_TR1_REGEX 1)
  77     endif()
  78 endif()
  79
  80
  81 if(LYX_INSTALL)
  82         set(LYX_ASPELL ON CACHE BOOL "Aspell option" FORCE)
  83         set(LYX_NLS ON CACHE BOOL "Nls option" FORCE)
  84         SET(LYX_NO_CONSOLE ON CACHE BOOL "No console option" FORCE)
  85         SET(LYX_PACKAGE_SUFFIX ON CACHE BOOL "Package suffix option" FORCE)
  86         SET(LYX_RELEASE ON CACHE BOOL "Release option" FORCE)
  87         SET(LYX_DEBUG OFF CACHE BOOL "Debug option" FORCE)
  88         SET(LYX_PROFILE OFF CACHE BOOL "Profile option" FORCE)
  89 endif()
  90
  91
  92
  93
  94
  95 # Supress regeneration
  96 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  97
  98 set(VERSION_INFO "CMake Build")
  99
 100 # Try to get some informations from configure.ac
 101
 102 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
 103 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
 104
 105 if(WIN32)
 106   set(USE_WINDOWS_PACKAGING 1)
 107 elseif(APPLE)
 108   set(USE_MACOSX_PACKAGING 1)
 109 else()
 110   set(USE_POSIX_PACKAGING 1)
 111 endif()
 112
 113 macro(setstripped _varname _value)
 114   string(STRIP ${_value} _v)
 115   if(USE_POSIX_PACKAGING)
 116     string(TOLOWER ${_v} ${_varname})
 117   else()
 118     set(${_varname} ${_v})
 119   endif()
 120 endmacro(setstripped)
 121
 122 foreach(_c_l ${_config_lines} )
 123   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 124     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 125     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 126     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 127     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 128       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 129       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 130       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 131       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 132       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 133     endif()
 134   endif()
 135   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 136     set(LYX_DATE "${CMAKE_MATCH_1}")
 137   endif()
 138 endforeach(_c_l)
 139
 140
 141 if(LYX_PACKAGE_SUFFIX)
 142   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 143 else()
 144   set(PACKAGE ${PACKAGE_BASE})
 145 endif()
 146
 147 if(LYX_PROGRAM_SUFFIX)
 148   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 149 else()
 150   set(PROGRAM_SUFFIX "")
 151 endif()
 152
 153
 154 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 155   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 156   if (UNIX)
 157     # don't use the default "/usr/local"
 158     # but respect the user-choice on the command-line
 159     if(LYX_INSTALL_SUFFIX)
 160         SET(CMAKE_INSTALL_PREFIX "/usr/local/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 161     else()
 162         SET(CMAKE_INSTALL_PREFIX "/usr/local/${LYX_PROJECT}" CACHE PATH "LyX install prefix" FORCE)
 163     endif()
 164   endif()
 165   if(WIN32)
 166     SET(CMAKE_INSTALL_PREFIX
 167       ${CMAKE_BINARY_DIR}/LYX_INSTALLED CACHE PATH "LyX install prefix" FORCE)
 168   endif()
 169 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 170
 171 if (WIN32)
 172   set(LYX_DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 173 else()
 174   set(LYX_DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 175 endif()
 176
 177 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 178 set(LYX_LOCALEDIR "locale")
 179 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_DATA_SUBDIR}${LYX_LOCALEDIR}")
 180 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 181
 182
 183 if(NOT GROUP_CODE)
 184         #set(GROUP_CODE "The Golden Code")
 185         set(GROUP_CODE flat)
 186 endif()
 187
 188 # lyx's source files
 189 set(LYX_CPP_FILES *.cpp)
 190 set(LYX_HPP_FILES *.h)
 191 set(LYX_MOC_FILES moc_*.cpp)
 192
 193
 194 include(ProjectSourceGroup)
 195
 196 if(LYX_MERGE_FILES)
 197         add_definitions(-DLYX_MERGED_BUILD)
 198 endif()
 199
 200
 201 set(CMAKE_BUILD_TYPE Release)
 202
 203 if(LYX_PROFILE)
 204         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 205         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 206             CACHE TYPE STRING FORCE)
 207 endif()
 208
 209 if(LYX_RELEASE)
 210         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 211 endif()
 212
 213 if(LYX_DEBUG)
 214         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 215 endif()
 216
 217
 218
 219 if(LYX_SHARED_LIBRARIES)
 220         set(library_type SHARED)
 221 else()
 222         set(library_type STATIC)
 223 endif()
 224
 225 if(NOT MSVC)
 226         if(NOT LYX_QUIET)
 227                 set(CMAKE_VERBOSE_MAKEFILE ON)
 228         endif()
 229         set(LYX_CXX_FLAGS -Wall)
 230         if(LYX_STDLIB_DEBUG)
 231                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 232         endif()
 233         if(LYX_CONCEPT_CHECKS)
 234                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 235         endif()
 236         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 237         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 238         if(MINGW)
 239                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 240         else()
 241                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 242         endif()
 243         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 244 endif()
 245
 246
 247 find_package(Qt4 REQUIRED)
 248 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 249
 250 find_package(ZLIB REQUIRED)
 251
 252 if(LYX_ASPELL)
 253         find_package(ASPELL REQUIRED)
 254 else()
 255         find_package(ASPELL)
 256 endif()
 257
 258
 259 if(LYX_USE_EXTERNAL_LIBINTL)
 260         find_package(Libintl REQUIRED)
 261         add_definitions(-DHAVE_GETTEXT)
 262 endif()
 263
 264
 265 if(WIN32)
 266   find_library(HUNSPELL_LIBRARY "libhunspell")
 267 else()
 268   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 269   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 270 endif()
 271 if (HUNSPELL_LIBRARY)
 272   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 273 endif()
 274
 275 if (HUNSPELL_FOUND)
 276   add_definitions(-DUSE_HUNSPELL=1)
 277   message(STATUS "Building with USE_HUNSPELL")
 278 else()
 279   message(STATUS "Hunspell not found, building without hunspell support")
 280 endif()
 281
 282 if(WIN32)
 283   find_library(ENCHANT_LIBRARY "libenchant")
 284   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 285 else()
 286   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 287   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 288 endif()
 289 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 290   set(ENCHANT_FOUND TRUE)
 291   add_definitions(-DUSE_ENCHANT=1)
 292   message(STATUS "Building with USE_ENCHANT")
 293 else()
 294   message(STATUS "Enchant not found, building without enchant support")
 295 endif()
 296
 297
 298 if(LYX_NLS)
 299         add_definitions(-DENABLE_NLS=1)
 300 endif()
 301
 302 if(ASPELL_FOUND)
 303         add_definitions(-DUSE_ASPELL=1)
 304 endif()
 305
 306 if(WIN32)
 307         if(LYX_NO_CONSOLE)
 308                 set(WIN32_CONSOLE WIN32)
 309                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 310         endif()
 311         if(MSVC)
 312                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 313                 # disable checked iterators for msvc release builds to get maximum speed
 314                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 315         else()
 316                 add_definitions(-DWINVER=0x0500)
 317         endif()
 318 endif()
 319
 320 message(STATUS "")
 321 foreach(_v PACKAGE PACKAGE_VERSION
 322     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 323     LYX_ABS_TOP_SRCDIR
 324     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 325   if(NOT DEFINED ${_v})
 326     message(FATAL_ERROR "${_v} not defined")
 327   endif()
 328   string(SUBSTRING "${_v}                            " 0 28 _v1)
 329   message(STATUS "----- ${_v1}: ${${_v}}")
 330 endforeach(_v)
 331 message(STATUS "")
 332
 333
 334 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 335 # Not sure if it works for all non-msvc compilers
 336 include(PCHSupport_26)
 337
 338 if(NOT LYX_DISABLE_PCH)
 339
 340         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 341         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 342         add_definitions(-DLYX_ENABLE_PCH)
 343
 344         if(MSVC AND NOT MERGE_FILES)
 345                 macro(lyx_add_msvc_pch name_)
 346                         set_source_files_properties(${${name_}_sources} PROPERTIES
 347                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 348                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 349                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 350                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 351                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 352                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 353                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 354                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 355                 endmacro(lyx_add_msvc_pch)
 356                 macro(lyx_add_gcc_pch name_)
 357                 endmacro()
 358         else()
 359                 macro(lyx_add_msvc_pch name_)
 360                 endmacro()
 361                 macro(lyx_add_gcc_pch name_)
 362                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 363                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 364                 endmacro()
 365         endif()
 366 else()
 367         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 368         macro(lyx_add_msvc_pch)
 369         endmacro(lyx_add_msvc_pch)
 370         macro(lyx_add_gcc_pch name_)
 371         endmacro()
 372 endif()
 373
 374 if(MSVC)
 375        if(LYX_VLD)
 376                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 377                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 378                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 379                include(${vld_path}/tools/cmake/vld.cmake)
 380        endif()
 381
 382         # TODO options
 383         if(LYX_WALL)
 384                 # Use the highest warning level
 385                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 386                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 387
 388                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 389                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 390                 else()
 391                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 392                 endif()
 393
 394                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 395                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 396                 else()
 397                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 398                 endif()
 399
 400                 # add here warnings which should produce an error /weXXXX
 401                 set(MSVC_W_ERROR   "/we4101 /we4189")
 402                 # add here warnings which should be disabled /wdXXXX
 403                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 404
 405                 set(CMAKE_CXX_FLAGS_DEBUG
 406                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 407                 set(CMAKE_CXX_FLAGS_RELEASE
 408                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 409                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 410                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 411
 412         else()
 413                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 414                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 415
 416                 # add here warnings which should produce an error /weXXXX
 417                 set(MSVC_W_ERROR   "/we4101 /we4189")
 418                 # add here warnings which should be disabled /wdXXXX
 419                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 420
 421                 set(CMAKE_CXX_FLAGS_DEBUG
 422                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 423                 set(CMAKE_CXX_FLAGS_RELEASE
 424                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 425                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 426                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 427
 428         endif()
 429         set(CMAKE_CXX_FLAGS_DEBUG
 430                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 431         set(CMAKE_CXX_FLAGS_RELEASE
 432                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 433         set(CMAKE_CXX_FLAGS_MINSIZEREL
 434                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 435
 436         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 437         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 438         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 439         message(STATUS "")
 440
 441 endif()
 442
 443 FIND_PROGRAM(LYX_PYTHON_EXECUTABLE python)
 444 if( NOT ${LYX_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND")
 445     if(LYX_NLS)
 446       find_package(LyXGettext REQUIRED)
 447       include_directories(${TOP_SRC_DIR}/po)
 448       add_subdirectory(po)
 449     endif()
 450 endif()
 451
 452 if(LYX_DEBUG_GLIBC)
 453   set(_GLIBCXX_DEBUG 1)
 454 endif()
 455
 456 if(LYX_DEBUG_GLIBC_PEDANTIC)
 457   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 458 endif()
 459
 460 # compiler tests, config.h generation
 461 if(MSVC AND NOT CONFIGURECHECKS)
 462         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 463 else()
 464         include(ConfigureChecks.cmake)
 465         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 466 endif()
 467
 468 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 469
 470 find_package(ICONV REQUIRED)
 471 add_definitions(-DHAVE_ICONV=1)
 472
 473
 474 include_directories(
 475   ${CMAKE_BINARY_DIR}
 476   ${TOP_SRC_DIR}/src)
 477
 478
 479 if(LYX_USE_EXTERNAL_BOOST)
 480   message(STATUS "Searching for boost")
 481   find_package(Boost COMPONENTS signals regex)
 482   if(Boost_FOUND)
 483     message(STATUS "Boost found")
 484     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 485     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 486   else()
 487     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 488   endif()
 489 else()
 490   if(LYX_USE_TR1_REGEX)
 491     set(Lyx_Boost_Libraries boost_signals)
 492   else()
 493     set(Lyx_Boost_Libraries boost_signals boost_regex)
 494   endif()
 495   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 496   include_directories(${TOP_SRC_DIR}/boost)
 497   add_subdirectory(boost)
 498 endif()
 499
 500 if(LYX_ENCRYPTION)
 501         #Ubuntu: libssl-dev
 502         find_package(OpenSSL REQUIRED)
 503         add_definitions(-DLYX_ENCRYPTION)
 504 endif()
 505
 506
 507 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 508   add_subdirectory(intl)
 509 endif()
 510 add_subdirectory(src)
 511
 512 if(LYX_INSTALL)
 513         add_subdirectory(man)
 514         FIND_PROGRAM(LYX_PERL_EXECUTABLE python)
 515         if(NOT ${LYX_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 516                 add_subdirectory(doc)
 517         endif()
 518 endif()
 519 add_subdirectory(lyx2lyx)
 520 add_subdirectory(scripts)
 521
 522 if(LYX_INSTALL)
 523         include(../Install)
 524 endif()
 525
 526 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 527 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 528 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 529
 530 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 531 #
 532 # needed by rpm
 533 SET(CPACK_SET_DESTDIR "ON")
 534 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 535 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 536 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 537 #
 538 # the next ones are needed by deb
 539 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 540 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${LYX_PROJECT}-${LYX_INSTALL_SUFFIX}")
 541
 542 # This is experimental, valid on _my_ system (Kornel)
 543 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 544 IF(ASPELL_FOUND)
 545   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 546 ENDIF()
 547 #
 548 # for the next ones, cpack insists on data with values in some file
 549 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 550 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 551
 552 # Find the revision number and use it as the release in rpm-package-build.
 553 # This way we may omit the otherwise needed "--force" parameter when
 554 # installing from that rpm package.
 555 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 556 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 557 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 558   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 559   # We use this value also to set the package-patch-value
 560   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 561     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 562   endif()
 563 endif()
 564
 565 # we do not have a readme or welcome data,
 566 # so we do not provide infofiles for
 567 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 568
 569 if(LYX_INSTALL)
 570         include(CPack)
 571 endif()
 572
 573 #Now it is possible to create some packages
 574 # cd <BuildDir>
 575 # make package
 576 #############################################################################################
 577 # So, e.g. for variables
 578 #    CMAKE_PROJECT_NAME                     : lyx
 579 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 580 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 581 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 582 #    CMAKE_SYSTEM_NAME                      : Linux
 583 #    CPACK_BINARY_DEB:BOOL                  : ON
 584 #
 585 # the package name builds as "lyx-2.0.1-Linux.deb"
 586 #
 587 ############################## rpm ################################### deb ##################
 588 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 589 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 590 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 591 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 592 #
 593 message(STATUS)