development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  15
  16 project(lyx)
  17
  18 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  19 # is checked
  20 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  21 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  22
  23 # Supress regeneration
  24 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  25
  26 set(VERSION_INFO "CMake Build")
  27
  28 # Try to get some informations from configure.ac
  29
  30 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  31 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  32
  33 if(WIN32)
  34   set(USE_WINDOWS_PACKAGING 1)
  35 elseif(APPLE)
  36   set(USE_MACOSX_PACKAGING 1)
  37 else()
  38   set(USE_POSIX_PACKAGING 1)
  39 endif()
  40
  41 macro(setstripped _varname _value)
  42   string(STRIP ${_value} _v)
  43   if(USE_POSIX_PACKAGING)
  44     string(TOLOWER ${_v} ${_varname})
  45   else()
  46     set(${_varname} ${_v})
  47   endif()
  48 endmacro(setstripped)
  49
  50 foreach(_c_l ${_config_lines} )
  51   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  52     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  53     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  54     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  55     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  56       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  57       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  58       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  59       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  60       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  61     endif()
  62   endif()
  63   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  64     set(LYX_DATE "${CMAKE_MATCH_1}")
  65   endif()
  66 endforeach(_c_l)
  67
  68 if(UseVersionSuffix)
  69   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  70   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  71   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  72 else()
  73   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
  74   set(PACKAGE ${PACKAGE_BASE})
  75   set(PROGRAM_SUFFIX "")
  76 endif()
  77
  78 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  79   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  80   if (UNIX)
  81     # don't use the default "/usr/local"
  82     # but respect the user-choice on the command-line
  83     SET(CMAKE_INSTALL_PREFIX
  84       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
  85   endif()
  86   if(WIN32)
  87     SET(CMAKE_INSTALL_PREFIX
  88       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
  89   endif()
  90 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  91
  92 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
  93 set(LYX_LOCALEDIR "locale")
  94 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
  95 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
  96
  97
  98 if(NOT GROUP_CODE)
  99         #set(GROUP_CODE "The Golden Code")
 100         set(GROUP_CODE flat)
 101 endif()
 102
 103 # lyx's source files
 104 set(LYX_CPP_FILES *.cpp)
 105 set(LYX_HPP_FILES *.h)
 106
 107 include(LyXMacros)
 108 include(ProjectSourceGroup)
 109
 110 if(merge OR merge_rebuild)
 111         set(merge 1 CACHE TYPE STRING FORCE)
 112         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 113         message(STATUS "")
 114         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 115         message(STATUS "")
 116 else()
 117         set(merge 0 CACHE TYPE STRING FORCE)
 118         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 119         message(STATUS "Enable merging files with -Dmerge=1")
 120 endif()
 121
 122
 123 set(CMAKE_BUILD_TYPE Release)
 124
 125 if(profile)
 126         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 127         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 128             CACHE TYPE STRING FORCE)
 129         set(profile)
 130 endif()
 131
 132 if(release)
 133         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 134         set(release TRUE CACHE TYPE STRING FORCE)
 135         set(release)
 136 endif()
 137
 138 if(debug)
 139         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 140         set(debug TRUE CACHE TYPE STRING FORCE)
 141         set(debug)
 142 endif()
 143
 144 if(shared)
 145         set(library_type SHARED)
 146         message(STATUS "building shared libraries")
 147 else()
 148         set(library_type STATIC)
 149 endif()
 150
 151 if(NOT MSVC)
 152         if(NOT quiet)
 153                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 154                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 155                 message(STATUS "")
 156         else()
 157                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 158         endif()
 159         set(LYX_CXX_FLAGS -Wall)
 160         if(stdlib-debug)
 161                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 162         endif()
 163         if(concept-checks)
 164                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 165         endif()
 166         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 167         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 168         if(MINGW)
 169                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 170         else()
 171                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 172         endif()
 173         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 174 endif()
 175
 176
 177 find_package(Qt4 REQUIRED)
 178 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 179
 180 find_package(ZLIB REQUIRED)
 181
 182 if(all OR aspell)
 183         set(aspell TRUE CACHE TYPE STRING)
 184         find_package(ASPELL REQUIRED)
 185 else()
 186         find_package(ASPELL)
 187 endif()
 188 set(aspell)
 189
 190 set(use_external_libintl TRUE)
 191
 192 if(use_external_libintl)
 193         find_package(Libintl REQUIRED)
 194         add_definitions(-DHAVE_GETTEXT)
 195 endif()
 196
 197 if(WIN32)
 198   find_library(HUNSPELL_LIBRARY "libhunspell")
 199 else()
 200   find_library(HUNSPELL_LIBRARY "hunspell")
 201 endif()
 202 if (HUNSPELL_LIBRARY)
 203   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 204 endif()
 205
 206 if (HUNSPELL_FOUND)
 207   add_definitions(-DUSE_HUNSPELL=1)
 208   message(STATUS "----- Building with USE_HUNSPELL")
 209 else()
 210   message(STATUS "----- Hunspell not found, building without hunspell support")
 211 endif()
 212
 213 message(STATUS "")
 214 if(nls OR all)
 215         set(nls TRUE CACHE TYPE STRING)
 216         add_definitions(-DENABLE_NLS=1)
 217         message(STATUS "----- Building with ENABLE_NLS")
 218 else()
 219         message(STATUS "----- No nls, to enable use -Dnls=1")
 220 endif()
 221 set(nls)
 222 if(ASPELL_FOUND)
 223         add_definitions(-DUSE_ASPELL=1)
 224         message(STATUS "----- Building with USE_ASPELL")
 225 else()
 226         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 227 endif()
 228 set(all)
 229
 230 if(WIN32)
 231         if(noconsole)
 232                 set(noconsole TRUE CACHE TYPE STRING)
 233                 set(WIN32_CONSOLE WIN32)
 234                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 235                 message(STATUS "----- Console disabled")
 236         else()
 237                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 238         endif()
 239         if(MSVC)
 240                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 241                 # disable checked iterators for msvc release builds to get maximum speed
 242                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 243         else()
 244                 add_definitions(-DWINVER=0x0500)
 245         endif()
 246 endif()
 247
 248 message(STATUS "")
 249 foreach(_v PACKAGE PACKAGE_VERSION
 250     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 251     LYX_ABS_TOP_SRCDIR
 252     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 253   if(NOT DEFINED ${_v})
 254     message(FATAL_ERROR "${_v} not defined")
 255   endif()
 256   string(SUBSTRING "${_v}                            " 0 28 _v1)
 257   message(STATUS "----- ${_v1}: ${${_v}}")
 258 endforeach(_v)
 259 message(STATUS "")
 260
 261
 262 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 263         message(STATUS "-----")
 264         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 265         message(STATUS "-----")
 266         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 267                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 268         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 269                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 270         macro(lyx_add_msvc_pch name_)
 271                 set_source_files_properties(${${name_}_sources} PROPERTIES
 272                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 273                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 274                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 275                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 276                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 277                 add_definitions(/DLYX_ENABLE_PCH)
 278         endmacro(lyx_add_msvc_pch)
 279         set(CMAKE_CXX_FLAGS_DEBUG
 280                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 281         set(CMAKE_CXX_FLAGS_RELEASE
 282                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 283         set(CMAKE_CXX_FLAGS_MINSIZEREL
 284                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 285 else()
 286         if(MSVC)
 287                 message(STATUS "-----")
 288                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 289                 message(STATUS "-----")
 290         endif()
 291         set(disable-pch TRUE CACHE TYPE STRING)
 292         macro(lyx_add_msvc_pch)
 293         endmacro(lyx_add_msvc_pch)
 294 endif()
 295
 296 if(MSVC)
 297        if(vld)
 298                set(vld 1 CACHE TYPE STRING FORCE)
 299                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 300                message(STATUS "")
 301                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 302                message(STATUS "")
 303                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 304                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 305                include(${vld_path}/tools/cmake/vld.cmake)
 306        else()
 307                set(vld 0 CACHE TYPE STRING FORCE)
 308                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 309                message(STATUS "")
 310                message(STATUS "Enable leak detection with -Dvld=1")
 311                message(STATUS "")
 312        endif()
 313
 314         if(WALL)
 315                 set(WALL 1 CACHE TYPE STRING FORCE)
 316
 317                 # Use the highest warning level
 318                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 319                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 320
 321                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 322                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 323                 else()
 324                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 325                 endif()
 326
 327                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 328                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 329                 else()
 330                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 331                 endif()
 332
 333                 # add here warnings which should produce an error /weXXXX
 334                 set(MSVC_W_ERROR   "/we4101 /we4189")
 335                 # add here warnings which should be disabled /wdXXXX
 336                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 337
 338                 set(CMAKE_CXX_FLAGS_DEBUG
 339                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 340                 set(CMAKE_CXX_FLAGS_RELEASE
 341                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 342                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 343                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 344
 345         else()
 346                 set(WALL 0 CACHE TYPE STRING FORCE)
 347
 348                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 349                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 350
 351                 # add here warnings which should produce an error /weXXXX
 352                 set(MSVC_W_ERROR   "/we4101 /we4189")
 353                 # add here warnings which should be disabled /wdXXXX
 354                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 355
 356                 set(CMAKE_CXX_FLAGS_DEBUG
 357                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 358                 set(CMAKE_CXX_FLAGS_RELEASE
 359                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 360                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 361                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 362
 363         endif()
 364
 365         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 366         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 367         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 368         message(STATUS "")
 369
 370 endif()
 371
 372
 373 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 374 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 375     if(nls OR all)
 376       find_package(LyXGettext REQUIRED)
 377       include_directories(${TOP_SRC_DIR}/po)
 378       add_subdirectory(po)
 379     endif()
 380 endif()
 381
 382 # compiler tests, config.h generation
 383 if(MSVC AND NOT CONFIGURECHECKS)
 384         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 385 else()
 386         include(ConfigureChecks.cmake)
 387         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 388 endif()
 389
 390 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 391
 392 find_package(ICONV REQUIRED)
 393 add_definitions(-DHAVE_ICONV=1)
 394
 395
 396 include_directories(
 397   ${CMAKE_BINARY_DIR}
 398   ${TOP_SRC_DIR}/src)
 399
 400 option(UseExternalBoost "Use external boost" OFF)
 401 if(UseExternalBoost)
 402   message(STATUS "Searching for boost")
 403   find_package(Boost COMPONENTS signals regex)
 404   if(Boost_FOUND)
 405     message(STATUS "Boost found")
 406     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 407     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 408   else()
 409     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 410   endif()
 411 else()
 412   message(STATUS "----- Using internal boost. To build with installed version use -DUseExternalBoost:BOOL=ON")
 413   set(Lyx_Boost_Libraries boost_signals boost_regex)
 414   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 415   include_directories(${TOP_SRC_DIR}/boost)
 416   add_subdirectory(boost)
 417 endif()
 418
 419
 420 if(NOT use_external_libintl)
 421   add_subdirectory(intl)
 422 endif()
 423 add_subdirectory(src)
 424
 425 add_subdirectory(man)
 426 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 427     add_subdirectory(doc)
 428 endif()
 429 add_subdirectory(lyx2lyx)
 430 add_subdirectory(scripts)
 431
 432 include(../Install)
 433
 434 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 435 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 436 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 437
 438 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 439 #
 440 # needed by rpm
 441 SET(CPACK_SET_DESTDIR "ON")
 442 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 443 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 444 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 445 #
 446 # the next ones are needed by deb
 447 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 448 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 449
 450 # This is experimental, valid on _my_ system (Kornel)
 451 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 452 IF(ASPELL_FOUND)
 453   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 454 ENDIF()
 455 #
 456 # for the next ones, cpack insists on data with values in some file
 457 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 458 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 459
 460 # Find the revision number and use it as the release in rpm-package-build.
 461 # This way we may omit the otherwise needed "--force" parameter when
 462 # installing from that rpm package.
 463 FIND_PROGRAM(_svnversion svnversion)
 464 message(STATUS "svnversion = ${_svnversion}")
 465 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 466   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 467   # We use this value also to set the package-patch-value
 468   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 469     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 470   endif()
 471 endif()
 472
 473 # we do not have a readme or welcome data,
 474 # so we do not provide infofiles for
 475 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 476
 477 include(CPack)
 478 #Now it is possible to create some packages
 479 # cd <BuildDir>
 480 # make package
 481 #############################################################################################
 482 # So, e.g. for variables
 483 #    CMAKE_PROJECT_NAME                     : lyx
 484 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 485 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 486 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 487 #    CMAKE_SYSTEM_NAME                      : Linux
 488 #    CPACK_BINARY_DEB:BOOL                  : ON
 489 #
 490 # the package name builds as "lyx-2.0.1-Linux.deb"
 491 #
 492 ############################## rpm ################################### deb ##################
 493 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 494 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 495 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 496 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 497 #