development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  15
  16 project(lyx)
  17
  18 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  19 # is checked
  20 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  21 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  22
  23 # Supress regeneration
  24 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  25
  26 set(VERSION_INFO "CMake Build")
  27
  28 # Try to get some informations from configure.ac
  29
  30 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  31 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  32
  33 if(WIN32)
  34   set(USE_WINDOWS_PACKAGING 1)
  35 elseif(APPLE)
  36   set(USE_MACOSX_PACKAGING 1)
  37 else()
  38   set(USE_POSIX_PACKAGING 1)
  39 endif()
  40
  41 macro(setstripped _varname _value)
  42   string(STRIP ${_value} _v)
  43   if(USE_POSIX_PACKAGING)
  44     string(TOLOWER ${_v} ${_varname})
  45   else()
  46     set(${_varname} ${_v})
  47   endif()
  48 endmacro(setstripped)
  49
  50 foreach(_c_l ${_config_lines} )
  51   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
  52     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
  53     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  54     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
  55     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  56       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
  57       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
  58       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  59       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  60       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  61     endif()
  62   endif()
  63   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  64     set(LYX_DATE "${CMAKE_MATCH_1}")
  65   endif()
  66 endforeach(_c_l)
  67
  68 if(UseVersionSuffix)
  69   message(STATUS "-- Using versioned PACKAGE. Disable with -DUseVersionSuffix=0")
  70   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
  71   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
  72 else()
  73   message(STATUS "-- PACKAGE not versioned, to enable use -DUseVersionSuffix=1")
  74   set(PACKAGE ${PACKAGE_BASE})
  75   set(PROGRAM_SUFFIX "")
  76 endif()
  77
  78 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  79   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  80   if (UNIX)
  81     # don't use the default "/usr/local"
  82     # but respect the user-choice on the command-line
  83     SET(CMAKE_INSTALL_PREFIX
  84       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
  85   endif()
  86   if(WIN32)
  87     SET(CMAKE_INSTALL_PREFIX
  88       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
  89   endif()
  90 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  91
  92 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
  93 set(LYX_LOCALEDIR "locale")
  94 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
  95 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
  96
  97
  98 if(NOT GROUP_CODE)
  99         #set(GROUP_CODE "The Golden Code")
 100         set(GROUP_CODE flat)
 101 endif()
 102
 103 # lyx's source files
 104 set(LYX_CPP_FILES *.cpp)
 105 set(LYX_HPP_FILES *.h)
 106
 107 include(LyXMacros)
 108 include(ProjectSourceGroup)
 109
 110 if(merge OR merge_rebuild)
 111         set(merge 1 CACHE TYPE STRING FORCE)
 112         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
 113         message(STATUS "")
 114         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
 115         message(STATUS "")
 116 else()
 117         set(merge 0 CACHE TYPE STRING FORCE)
 118         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 119         message(STATUS "Enable merging files with -Dmerge=1")
 120 endif()
 121
 122
 123 set(CMAKE_BUILD_TYPE Release)
 124
 125 if(profile)
 126         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 127         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 128             CACHE TYPE STRING FORCE)
 129         set(profile)
 130 endif()
 131
 132 if(release)
 133         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 134         set(release TRUE CACHE TYPE STRING FORCE)
 135         set(release)
 136 endif()
 137
 138 if(debug)
 139         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 140         set(debug TRUE CACHE TYPE STRING FORCE)
 141         set(debug)
 142 endif()
 143
 144 if(shared)
 145         set(library_type SHARED)
 146         message(STATUS "building shared libraries")
 147 else()
 148         set(library_type STATIC)
 149 endif()
 150
 151 if(NOT MSVC)
 152         if(NOT quiet)
 153                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 154                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 155                 message(STATUS "")
 156         else()
 157                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 158         endif()
 159         set(LYX_CXX_FLAGS -Wall)
 160         if(stdlib-debug)
 161                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 162         endif()
 163         if(concept-checks)
 164                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 165         endif()
 166         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 167         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 168         if(MINGW)
 169                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 170         else()
 171                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 172         endif()
 173         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 174 endif()
 175
 176
 177 find_package(Qt4 REQUIRED)
 178 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 179
 180 find_package(ZLIB REQUIRED)
 181
 182 if(all OR aspell)
 183         set(aspell TRUE CACHE TYPE STRING)
 184         find_package(ASPELL REQUIRED)
 185 else()
 186         find_package(ASPELL)
 187 endif()
 188 set(aspell)
 189
 190 set(use_external_libintl TRUE)
 191
 192 if(use_external_libintl)
 193         find_package(Libintl REQUIRED)
 194         add_definitions(-DHAVE_GETTEXT)
 195 endif()
 196
 197 if(WIN32)
 198     find_library(HUNSPELL_LIBRARY "libhunspell")
 199 else()
 200     find_library(HUNSPELL_LIBRARY "hunspell")
 201 endif()
 202 if (HUNSPELL_LIBRARY)
 203     find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 204 endif()
 205
 206 if (HUNSPELL_FOUND)
 207     message(STATUS "----- Building with Hunspell")
 208 else()
 209     message(STATUS "----- Hunspell not found, building without hunspell support")
 210 endif()
 211
 212 message(STATUS "")
 213 if(nls OR all)
 214         set(nls TRUE CACHE TYPE STRING)
 215         add_definitions(-DENABLE_NLS=1)
 216         message(STATUS "----- Building with ENABLE_NLS")
 217 else()
 218         message(STATUS "----- No nls, to enable use -Dnls=1")
 219 endif()
 220 set(nls)
 221 if(ASPELL_FOUND)
 222         add_definitions(-DUSE_ASPELL=1)
 223         message(STATUS "----- Building with USE_ASPELL")
 224 else()
 225         message(STATUS "----- No aspell, to get more information use -Daspell=1")
 226 endif()
 227 set(all)
 228
 229 if(WIN32)
 230         if(noconsole)
 231                 set(noconsole TRUE CACHE TYPE STRING)
 232                 set(WIN32_CONSOLE WIN32)
 233                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 234                 message(STATUS "----- Console disabled")
 235         else()
 236                 message(STATUS "----- Console enabled, disable it with -Dnoconsole=1")
 237         endif()
 238         if(MSVC)
 239                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 240                 # disable checked iterators for msvc release builds to get maximum speed
 241                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 242         else()
 243                 add_definitions(-DWINVER=0x0500)
 244         endif()
 245 endif()
 246
 247 message(STATUS "")
 248 foreach(_v PACKAGE PACKAGE_VERSION
 249     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 250     LYX_ABS_TOP_SRCDIR
 251     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 252   if(NOT DEFINED ${_v})
 253     message(FATAL_ERROR "${_v} not defined")
 254   endif()
 255   string(SUBSTRING "${_v}                            " 0 28 _v1)
 256   message(STATUS "----- ${_v1}: ${${_v}}")
 257 endforeach(_v)
 258 message(STATUS "")
 259
 260
 261 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 262
 263 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 264         message(STATUS "-----")
 265         message(STATUS "----- using precompiled headers, disable with -Ddisable-pch=1")
 266         message(STATUS "-----")
 267         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 268                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 269         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 270                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 271         macro(lyx_add_msvc_pch name_)
 272                 set_source_files_properties(${${name_}_sources} PROPERTIES
 273                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 274                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 275                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 276                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 277                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 278                 add_definitions(/DLYX_ENABLE_PCH)
 279         endmacro(lyx_add_msvc_pch)
 280         set(CMAKE_CXX_FLAGS_DEBUG
 281                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 282         set(CMAKE_CXX_FLAGS_RELEASE
 283                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 284         set(CMAKE_CXX_FLAGS_MINSIZEREL
 285                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 286 else()
 287         if(MSVC)
 288                 message(STATUS "-----")
 289                 message(STATUS "----- precompiled headers disabled, enable with -Ddisable-pch=0")
 290                 message(STATUS "-----")
 291         endif()
 292         set(disable-pch TRUE CACHE TYPE STRING)
 293         macro(lyx_add_msvc_pch)
 294         endmacro(lyx_add_msvc_pch)
 295 endif()
 296
 297 if(MSVC)
 298        if(vld)
 299                set(vld 1 CACHE TYPE STRING FORCE)
 300                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 301                message(STATUS "")
 302                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 303                message(STATUS "")
 304                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 305                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 306                include(${vld_path}/tools/cmake/vld.cmake)
 307        else()
 308                set(vld 0 CACHE TYPE STRING FORCE)
 309                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 310                message(STATUS "")
 311                message(STATUS "Enable leak detection with -Dvld=1")
 312                message(STATUS "")
 313        endif()
 314
 315         if(WALL)
 316                 set(WALL 1 CACHE TYPE STRING FORCE)
 317
 318                 # Use the highest warning level
 319                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 320                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 321
 322                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 323                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 324                 else()
 325                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 326                 endif()
 327
 328                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 329                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 330                 else()
 331                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 332                 endif()
 333
 334                 # add here warnings which should produce an error /weXXXX
 335                 set(MSVC_W_ERROR   "/we4101 /we4189")
 336                 # add here warnings which should be disabled /wdXXXX
 337                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 338
 339                 set(CMAKE_CXX_FLAGS_DEBUG
 340                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 341                 set(CMAKE_CXX_FLAGS_RELEASE
 342                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 343                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 344                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 345
 346         else()
 347                 set(WALL 0 CACHE TYPE STRING FORCE)
 348
 349                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 350                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 351
 352                 # add here warnings which should produce an error /weXXXX
 353                 set(MSVC_W_ERROR   "/we4101 /we4189")
 354                 # add here warnings which should be disabled /wdXXXX
 355                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 356
 357                 set(CMAKE_CXX_FLAGS_DEBUG
 358                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 359                 set(CMAKE_CXX_FLAGS_RELEASE
 360                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 361                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 362                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 363
 364         endif()
 365
 366         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 367         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 368         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 369         message(STATUS "")
 370
 371 endif()
 372
 373
 374 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 375 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 376     if(nls OR all)
 377       find_package(LyXGettext REQUIRED)
 378       include_directories(${TOP_SRC_DIR}/po)
 379       add_subdirectory(po)
 380     endif()
 381 endif()
 382
 383 # compiler tests, config.h generation
 384 if(MSVC AND NOT CONFIGURECHECKS)
 385         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 386 else()
 387         include(ConfigureChecks.cmake)
 388         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 389 endif()
 390
 391 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 392
 393 find_package(ICONV REQUIRED)
 394 add_definitions(-DHAVE_ICONV=1)
 395
 396 include_directories(
 397         ${CMAKE_BINARY_DIR}
 398         ${TOP_SRC_DIR}/src
 399         ${TOP_SRC_DIR}/boost)
 400
 401 add_subdirectory(boost)
 402 if(NOT use_external_libintl)
 403         add_subdirectory(intl)
 404 endif()
 405 add_subdirectory(src)
 406
 407 add_subdirectory(man)
 408 if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 409     add_subdirectory(doc)
 410 endif()
 411 add_subdirectory(lyx2lyx)
 412 add_subdirectory(scripts)
 413
 414 include(../Install)
 415
 416 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 417 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 418 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 419
 420 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 421 #
 422 # needed by rpm
 423 SET(CPACK_SET_DESTDIR "ON")
 424 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 425 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 426 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 427 #
 428 # the next ones are needed by deb
 429 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 430 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 431
 432 # This is experimental, valid on _my_ system (Kornel)
 433 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 434 IF(ASPELL_FOUND)
 435   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 436 ENDIF()
 437 #
 438 # for the next ones, cpack insists on data with values in some file
 439 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 440 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 441
 442 # Find the revision number and use it as the release in rpm-package-build.
 443 # This way we may omit the otherwise needed "--force" parameter when
 444 # installing from that rpm package.
 445 FIND_PROGRAM(_svnversion svnversion)
 446 message(STATUS "svnversion = ${_svnversion}")
 447 if(NOT ${_svnversion} MATCHES "-NOTFOUND")
 448   EXECUTE_PROCESS(COMMAND ${_svnversion} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 449   # We use this value also to set the package-patch-value
 450   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 451     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 452   endif()
 453 endif()
 454
 455 # we do not have a readme or welcome data,
 456 # so we do not provide infofiles for
 457 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 458
 459 include(CPack)
 460 #Now it is possible to create some packages
 461 # cd <BuildDir>
 462 # make package
 463 #############################################################################################
 464 # So, e.g. for variables
 465 #    CMAKE_PROJECT_NAME                     : lyx
 466 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 467 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 468 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 469 #    CMAKE_SYSTEM_NAME                      : Linux
 470 #    CPACK_BINARY_DEB:BOOL                  : ON
 471 #
 472 # the package name builds as "lyx-2.0.1-Linux.deb"
 473 #
 474 ############################## rpm ################################### deb ##################
 475 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 476 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 477 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 478 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 479 #