development/cmake/CMakeLists.txt

   1
   2 # This file is part of LyX, the document processor.
   3 # Licence details can be found in the file COPYING.
   4 #
   5 # Copyright (c) 2006-2010 Peter Kümmel, <syntheticpp@gmx.net>
   6 # Copyright (c) 2008-2010 Kornel Benko, <Kornel.Benko@berlin.de>
   7
   8
   9 cmake_minimum_required(VERSION 2.6.4)
  10
  11 if(COMMAND cmake_policy)
  12         cmake_policy(SET CMP0003 OLD)
  13         cmake_policy(SET CMP0005 OLD)
  14 endif(COMMAND cmake_policy)
  15
  16 project(lyx)
  17
  18 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  19
  20 # where to look first for cmake modules,
  21 # before ${CMAKE_ROOT}/Modules is checked
  22 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  23 include(LyXMacros)
  24
  25 message(STATUS)
  26 message(STATUS "Switch LYX_* variables by -DLYX_*=1 or 0:")
  27
  28 # Usage LYX_OPTION
  29 # 1. parameter: option name without prefix 'LYX_'
  30 # 2. parameter: description
  31 # 3. parameter: default value, ON or OFF
  32 # 4. parameter: system on which option is used: ALL, GCC, MSVC, ...
  33 LYX_OPTION(NLS "Use nls" OFF ALL)
  34 LYX_OPTION(ASPELL "Require aspell" OFF ALL)
  35 LYX_OPTION(DEBUG "Build debug version" OFF ALL)
  36 LYX_OPTION(RELEASE "Build release version" ON ALL)
  37 LYX_OPTION(PROFILE "Build profile version" OFF GCC)
  38 LYX_OPTION(USE_EXTERNAL_BOOST "Use external boost" OFF GCC)
  39 LYX_OPTION(USE_EXTERNAL_LIBINTL "Use external libintl" ON ALL)
  40 LYX_OPTION(INSTALL "Build install projects/rules" ON ALL)
  41 LYX_OPTION(PACKAGE_SUFFIX "Use version suffix for packaging" OFF ALL)
  42 LYX_OPTION(PROGRAM_SUFFIX "Append version suffix to binaries" ON GCC)
  43 LYX_OPTION(NO_CONSOLE "Suppress console on Windows" OFF MSVC)
  44 LYX_OPTION(VLD "Use VLD with MSVC" OFF MSVC)
  45 LYX_OPTION(DISABLE_PCH "Disable precompiled headers" ON ALL)
  46 LYX_OPTION(MERGE_FILES "Merge source files into one compilation unit" OFF ALL)
  47 LYX_OPTION(DEBUG_GLIBC "Enable libstdc++ debug mode" OFF GCC)
  48 LYX_OPTION(DEBUG_GLIBC_PEDANTIC "Enable libstdc++pedantic debug mode" OFF GCC)
  49 LYX_OPTION(STDLIB_DEBUG "Use debug stdlib" OFF GCC)
  50 LYX_OPTION(CONCEPT_CHECKS "Enable concept-checks" OFF GCC)
  51 LYX_OPTION(QUIET "Don't generate verbose makefiles" OFF ALL)
  52 LYX_OPTION(SHARED_LIBRARIES "Build shared libraries" OFF ALL)
  53
  54 message(STATUS)
  55
  56 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  57 set(LIBRARY_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/lib)
  58
  59
  60
  61 if(UNIX OR MINGW)
  62     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
  63     message(STATUS "Using GCC version ${GCC_VERSION}")
  64     if(NOT GCC_VERSION VERSION_LESS 4.4)
  65         set(LYX_USE_TR1 1)
  66         # GCC <= 4.5 does not support regex: there are linker errors
  67         # http://gcc.gnu.org/onlinedocs/libstdc++/manual/status.html#status.iso.tr1
  68         set(LYX_USE_TR1_REGEX 0)
  69     endif()
  70 else()
  71     if(MSVC10)
  72         set(LYX_USE_TR1 1)
  73         set(LYX_USE_TR1_REGEX 1)
  74     endif()
  75 endif()
  76
  77
  78
  79
  80
  81 # Supress regeneration
  82 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  83
  84 set(VERSION_INFO "CMake Build")
  85
  86 # Try to get some informations from configure.ac
  87
  88 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  89 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  90
  91 if(WIN32)
  92   set(USE_WINDOWS_PACKAGING 1)
  93 elseif(APPLE)
  94   set(USE_MACOSX_PACKAGING 1)
  95 else()
  96   set(USE_POSIX_PACKAGING 1)
  97 endif()
  98
  99 macro(setstripped _varname _value)
 100   string(STRIP ${_value} _v)
 101   if(USE_POSIX_PACKAGING)
 102     string(TOLOWER ${_v} ${_varname})
 103   else()
 104     set(${_varname} ${_v})
 105   endif()
 106 endmacro(setstripped)
 107
 108 foreach(_c_l ${_config_lines} )
 109   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\), *\\[\([^,]+\)\\] *,\(.*\)")
 110     setstripped(PACKAGE_BASE ${CMAKE_MATCH_1})
 111     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
 112     setstripped(PACKAGE_BUGREPORT ${CMAKE_MATCH_3})
 113     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
 114       set(LYX_MAJOR_VERSION ${CMAKE_MATCH_1})
 115       set(LYX_MINOR_VERSION ${CMAKE_MATCH_2})
 116       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 117       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
 118       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
 119     endif()
 120   endif()
 121   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
 122     set(LYX_DATE "${CMAKE_MATCH_1}")
 123   endif()
 124 endforeach(_c_l)
 125
 126
 127 if(LYX_PACKAGE_SUFFIX)
 128   set(PACKAGE ${PACKAGE_BASE}${LYX_INSTALL_SUFFIX})
 129 else()
 130   set(PACKAGE ${PACKAGE_BASE})
 131 endif()
 132
 133 if(LYX_PROGRAM_SUFFIX)
 134   set(PROGRAM_SUFFIX "${LYX_INSTALL_SUFFIX}")
 135 else()
 136   set(PROGRAM_SUFFIX "")
 137 endif()
 138
 139
 140 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 141   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
 142   if (UNIX)
 143     # don't use the default "/usr/local"
 144     # but respect the user-choice on the command-line
 145     SET(CMAKE_INSTALL_PREFIX
 146       "/usr/local/${project}${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
 147   endif()
 148   if(WIN32)
 149     SET(CMAKE_INSTALL_PREFIX
 150       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
 151   endif()
 152 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 153
 154 if (WIN32)
 155   set(DATA_SUBDIR "Resources/" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 156 else()
 157   set(DATA_SUBDIR "" CACHE STRING "Subdirectory for all lyx-system-data" FORCE)
 158 endif()
 159
 160 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
 161 set(LYX_LOCALEDIR "locale")
 162 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${DATA_SUBDIR}${LYX_LOCALEDIR}")
 163 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
 164
 165
 166 if(NOT GROUP_CODE)
 167         #set(GROUP_CODE "The Golden Code")
 168         set(GROUP_CODE flat)
 169 endif()
 170
 171 # lyx's source files
 172 set(LYX_CPP_FILES *.cpp)
 173 set(LYX_HPP_FILES *.h)
 174 set(LYX_MOC_FILES moc_*.cpp)
 175
 176
 177 include(ProjectSourceGroup)
 178
 179 if(LYX_MERGE_FILES)
 180         add_definitions(-DLYX_MERGED_BUILD)
 181 endif()
 182
 183
 184 set(CMAKE_BUILD_TYPE Release)
 185
 186 if(LYX_PROFILE)
 187         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 188         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 189             CACHE TYPE STRING FORCE)
 190 endif()
 191
 192 if(LYX_RELEASE)
 193         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 194 endif()
 195
 196 if(LYX_DEBUG)
 197         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 198 endif()
 199
 200
 201
 202 if(LYX_SHARED_LIBRARIES)
 203         set(library_type SHARED)
 204 else()
 205         set(library_type STATIC)
 206 endif()
 207
 208 if(NOT MSVC)
 209         if(NOT LYX_QUIET)
 210                 set(CMAKE_VERBOSE_MAKEFILE ON)
 211         endif()
 212         set(LYX_CXX_FLAGS -Wall)
 213         if(LYX_STDLIB_DEBUG)
 214                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 215         endif()
 216         if(LYX_CONCEPT_CHECKS)
 217                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 218         endif()
 219         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS} -fno-strict-aliasing " CACHE TYPE STRING FORCE)
 220         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -fno-strict-aliasing -O0 -g -D_DEBUG" CACHE TYPE STRING FORCE)
 221         if(MINGW)
 222                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 223         else()
 224                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 225         endif()
 226         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 227 endif()
 228
 229
 230 find_package(Qt4 REQUIRED)
 231 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 232
 233 find_package(ZLIB REQUIRED)
 234
 235 if(LYX_ASPELL)
 236         find_package(ASPELL REQUIRED)
 237 else()
 238         find_package(ASPELL)
 239 endif()
 240
 241
 242 if(LYX_USE_EXTERNAL_LIBINTL)
 243         find_package(Libintl REQUIRED)
 244         add_definitions(-DHAVE_GETTEXT)
 245 endif()
 246
 247
 248 if(WIN32)
 249   find_library(HUNSPELL_LIBRARY "libhunspell")
 250 else()
 251   #find_library(HUNSPELL_LIBRARY NAME "hunspell" PATH "/usr/local/lib" "/usr/lib" NO_DEFAULT_PATH)
 252   find_library(HUNSPELL_LIBRARY NAMES "hunspell" "hunspell-1.2" PATHS "/usr/local/lib" "/usr/lib" "/usr/lib64")
 253 endif()
 254 if (HUNSPELL_LIBRARY)
 255   find_file(HUNSPELL_FOUND "hunspell/hunspell.hxx")
 256 endif()
 257
 258 if (HUNSPELL_FOUND)
 259   add_definitions(-DUSE_HUNSPELL=1)
 260   message(STATUS "Building with USE_HUNSPELL")
 261 else()
 262   message(STATUS "Hunspell not found, building without hunspell support")
 263 endif()
 264
 265 if(WIN32)
 266   find_library(ENCHANT_LIBRARY "libenchant")
 267   find_path(ENCHANT_INCLUDE_DIR "enchant++.h")
 268 else()
 269   find_library(ENCHANT_LIBRARY "enchant"  "/usr/local/lib" "/usr/lib" "/usr/local/lib" "/opt/local/lib")
 270   find_path(ENCHANT_INCLUDE_DIR "enchant++.h" PATHS /usr/local/include /usr/local/include/enchant /usr/include /usr/include/enchant /opt/local/include/enchant)
 271 endif()
 272 if (ENCHANT_LIBRARY AND ENCHANT_INCLUDE_DIR)
 273   set(ENCHANT_FOUND TRUE)
 274   add_definitions(-DUSE_ENCHANT=1)
 275   message(STATUS "Building with USE_ENCHANT")
 276 else()
 277   message(STATUS "Enchant not found, building without enchant support")
 278 endif()
 279
 280
 281 if(LYX_NLS)
 282         add_definitions(-DENABLE_NLS=1)
 283 endif()
 284
 285 if(ASPELL_FOUND)
 286         add_definitions(-DUSE_ASPELL=1)
 287 endif()
 288
 289 if(WIN32)
 290         if(LYX_NO_CONSOLE)
 291                 set(WIN32_CONSOLE WIN32)
 292                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 293         endif()
 294         if(MSVC)
 295                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 296                 # disable checked iterators for msvc release builds to get maximum speed
 297                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 298         else()
 299                 add_definitions(-DWINVER=0x0500)
 300         endif()
 301 endif()
 302
 303 message(STATUS "")
 304 foreach(_v PACKAGE PACKAGE_VERSION
 305     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 306     LYX_ABS_TOP_SRCDIR
 307     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 308   if(NOT DEFINED ${_v})
 309     message(FATAL_ERROR "${_v} not defined")
 310   endif()
 311   string(SUBSTRING "${_v}                            " 0 28 _v1)
 312   message(STATUS "----- ${_v1}: ${${_v}}")
 313 endforeach(_v)
 314 message(STATUS "")
 315
 316
 317 # PCHs not supported by cmake: http://www.cmake.org/Bug/view.php?id=1260
 318 # Not sure if it works for all non-msvc compilers
 319 include(PCHSupport_26)
 320
 321 if(NOT LYX_DISABLE_PCH)
 322
 323         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h ${CMAKE_BINARY_DIR}/pcheaders.h)
 324         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake ${CMAKE_BINARY_DIR}/config_pch.cpp)
 325         add_definitions(-DLYX_ENABLE_PCH)
 326
 327         if(MSVC AND NOT MERGE_FILES)
 328                 macro(lyx_add_msvc_pch name_)
 329                         set_source_files_properties(${${name_}_sources} PROPERTIES
 330                                 COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 331                         set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 332                                 COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 333                         set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 334                                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 335                         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 336                         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 337                         set(CMAKE_CXX_FLAGS_MINSIZEREL  "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 338                 endmacro(lyx_add_msvc_pch)
 339                 macro(lyx_add_gcc_pch name_)
 340                 endmacro()
 341         else()
 342                 macro(lyx_add_msvc_pch name_)
 343                 endmacro()
 344                 macro(lyx_add_gcc_pch name_)
 345                         add_definitions(-DLYX_PCH_STL -DLYX_PCH_BOOST -DLYX_PCH_QT4)
 346                         ADD_PRECOMPILED_HEADER(${name_} ${CMAKE_BINARY_DIR}/config_pch.cpp ${CMAKE_BINARY_DIR}/config.h.gch)
 347                 endmacro()
 348         endif()
 349 else()
 350         set(LYX_DISABLE_PCH TRUE CACHE TYPE STRING)
 351         macro(lyx_add_msvc_pch)
 352         endmacro(lyx_add_msvc_pch)
 353         macro(lyx_add_gcc_pch name_)
 354         endmacro()
 355 endif()
 356
 357 if(MSVC)
 358        if(LYX_VLD)
 359                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 360                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 361                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 362                include(${vld_path}/tools/cmake/vld.cmake)
 363        endif()
 364
 365         # TODO options
 366         if(WALL)
 367                 set(WALL 1 CACHE TYPE STRING FORCE)
 368
 369                 # Use the highest warning level
 370                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 371                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 372
 373                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 374                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 375                 else()
 376                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 377                 endif()
 378
 379                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 380                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 381                 else()
 382                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 383                 endif()
 384
 385                 # add here warnings which should produce an error /weXXXX
 386                 set(MSVC_W_ERROR   "/we4101 /we4189")
 387                 # add here warnings which should be disabled /wdXXXX
 388                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180 /wd4231")
 389
 390                 set(CMAKE_CXX_FLAGS_DEBUG
 391                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 392                 set(CMAKE_CXX_FLAGS_RELEASE
 393                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 394                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 395                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 396
 397         else()
 398                 set(WALL 0 CACHE TYPE STRING FORCE)
 399
 400                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 401                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 402
 403                 # add here warnings which should produce an error /weXXXX
 404                 set(MSVC_W_ERROR   "/we4101 /we4189")
 405                 # add here warnings which should be disabled /wdXXXX
 406                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180 /wd4231")
 407
 408                 set(CMAKE_CXX_FLAGS_DEBUG
 409                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 410                 set(CMAKE_CXX_FLAGS_RELEASE
 411                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 412                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 413                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 414
 415         endif()
 416         set(CMAKE_CXX_FLAGS_DEBUG
 417                 "${CMAKE_CXX_FLAGS_DEBUG} /Zc:wchar_t-")
 418         set(CMAKE_CXX_FLAGS_RELEASE
 419                 "${CMAKE_CXX_FLAGS_RELEASE} /Zc:wchar_t-")
 420         set(CMAKE_CXX_FLAGS_MINSIZEREL
 421                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /Zc:wchar_t-")
 422
 423         message(STATUS "----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 424         message(STATUS "----- Warnings as errors : ${MSVC_W_ERROR}")
 425         message(STATUS "----- Warnings disabled  : ${MSVC_W_DISABLE}")
 426         message(STATUS "")
 427
 428 endif()
 429
 430 FIND_PROGRAM(_PERL_EXECUTABLE perl)
 431 FIND_PROGRAM(_PYTHON_EXECUTABLE python)
 432 if((NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND") AND ( NOT ${_PYTHON_EXECUTABLE} MATCHES "-NOTFOUND"))
 433     if(LYX_NLS)
 434       find_package(LyXGettext REQUIRED)
 435       include_directories(${TOP_SRC_DIR}/po)
 436       add_subdirectory(po)
 437     endif()
 438 endif()
 439
 440 if(LYX_DEBUG_GLIBC)
 441   set(_GLIBCXX_DEBUG 1)
 442 endif()
 443
 444 if(LYX_DEBUG_GLIBC_PEDANTIC)
 445   set(_GLIBCXX_DEBUG_PEDANTIC 1)
 446 endif()
 447
 448 # compiler tests, config.h generation
 449 if(MSVC AND NOT CONFIGURECHECKS)
 450         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 451 else()
 452         include(ConfigureChecks.cmake)
 453         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 454 endif()
 455
 456 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 457
 458 find_package(ICONV REQUIRED)
 459 add_definitions(-DHAVE_ICONV=1)
 460
 461
 462 include_directories(
 463   ${CMAKE_BINARY_DIR}
 464   ${TOP_SRC_DIR}/src)
 465
 466
 467 if(LYX_USE_EXTERNAL_BOOST)
 468   message(STATUS "Searching for boost")
 469   find_package(Boost COMPONENTS signals regex)
 470   if(Boost_FOUND)
 471     message(STATUS "Boost found")
 472     message(STATUS "Boost-libs = ${Boost_LIBRARIES}")
 473     set(Lyx_Boost_Libraries ${Boost_LIBRARIES})
 474   else()
 475     message(FATAL_ERROR "Boost not found" ${Boost_ERROR_REASON})
 476   endif()
 477 else()
 478   if(LYX_USE_TR1_REGEX)
 479     set(Lyx_Boost_Libraries boost_signals)
 480   else()
 481     set(Lyx_Boost_Libraries boost_signals boost_regex)
 482   endif()
 483   add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 484   include_directories(${TOP_SRC_DIR}/boost)
 485   add_subdirectory(boost)
 486 endif()
 487
 488
 489 if(NOT LYX_USE_EXTERNAL_LIBINTL)
 490   add_subdirectory(intl)
 491 endif()
 492 add_subdirectory(src)
 493
 494 if(LYX_INSTALL)
 495         add_subdirectory(man)
 496         if(NOT ${_PERL_EXECUTABLE} MATCHES "-NOTFOUND")
 497                 add_subdirectory(doc)
 498         endif()
 499 endif()
 500 add_subdirectory(lyx2lyx)
 501 add_subdirectory(scripts)
 502
 503 if(LYX_INSTALL)
 504         include(../Install)
 505 endif()
 506
 507 SET(CPACK_PACKAGE_VERSION_MAJOR "${LYX_MAJOR_VERSION}")
 508 SET(CPACK_PACKAGE_VERSION_MINOR "${LYX_MINOR_VERSION}")
 509 FILE(STRINGS "${TOP_SRC_DIR}/development/cmake/LyX_summary.txt" CPACK_PACKAGE_DESCRIPTION_SUMMARY)
 510
 511 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "CMake ${LYX_INSTALL_SUFFIX}")
 512 #
 513 # needed by rpm
 514 SET(CPACK_SET_DESTDIR "ON")
 515 FILE(READ "${TOP_SRC_DIR}/development/cmake/LyX_license.txt" CPACK_RPM_PACKAGE_LICENSE)
 516 SET(CPACK_RPM_PACKAGE_GROUP "Applications/Publishing")
 517 SET(CPACK_RPM_PACKAGE_VENDOR "The LyX team")
 518 #
 519 # the next ones are needed by deb
 520 SET(CPACK_PACKAGE_CONTACT "${PACKAGE_BUGREPORT}")
 521 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "${project}-${LYX_INSTALL_SUFFIX}")
 522
 523 # This is experimental, valid on _my_ system (Kornel)
 524 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libqtgui4 (>= 4.4.3-0)")
 525 IF(ASPELL_FOUND)
 526   SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libaspell15 (>= 0.60.6-1),${CPACK_DEBIAN_PACKAGE_DEPENDS}")
 527 ENDIF()
 528 #
 529 # for the next ones, cpack insists on data with values in some file
 530 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${TOP_SRC_DIR}/development/cmake/LyX_description.txt")
 531 SET(CPACK_RESOURCE_FILE_LICENSE "${TOP_SRC_DIR}/development/cmake/LyX_license.txt")
 532
 533 # Find the revision number and use it as the release in rpm-package-build.
 534 # This way we may omit the otherwise needed "--force" parameter when
 535 # installing from that rpm package.
 536 FIND_PROGRAM(LYX_SVNVERSION svnversion)
 537 #message(STATUS "svnversion = ${LYX_SVNVERSION}")
 538 if(NOT ${LYX_SVNVERSION} MATCHES "-NOTFOUND")
 539   EXECUTE_PROCESS(COMMAND ${LYX_SVNVERSION} WORKING_DIRECTORY "${TOP_SRC_DIR}" OUTPUT_VARIABLE CPACK_RPM_PACKAGE_RELEASE OUTPUT_STRIP_TRAILING_WHITESPACE)
 540   # We use this value also to set the package-patch-value
 541   if(CPACK_RPM_PACKAGE_RELEASE MATCHES "^\([0-9]+\)")
 542     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_1})
 543   endif()
 544 endif()
 545
 546 # we do not have a readme or welcome data,
 547 # so we do not provide infofiles for
 548 # CPACK_RESOURCE_FILE_README and CPACK_RESOURCE_FILE_WELCOME
 549
 550 if(LYX_INSTALL)
 551         include(CPack)
 552 endif()
 553
 554 #Now it is possible to create some packages
 555 # cd <BuildDir>
 556 # make package
 557 #############################################################################################
 558 # So, e.g. for variables
 559 #    CMAKE_PROJECT_NAME                     : lyx
 560 #    CPACK_PACKAGE_VERSION_MAJOR            : 2
 561 #    CPACK_PACKAGE_VERSION_MINOR            : 0
 562 #    CPACK_PACKAGE_VERSION_PATCH            : 1
 563 #    CMAKE_SYSTEM_NAME                      : Linux
 564 #    CPACK_BINARY_DEB:BOOL                  : ON
 565 #
 566 # the package name builds as "lyx-2.0.1-Linux.deb"
 567 #
 568 ############################## rpm ################################### deb ##################
 569 # create    # cpack -G RPM --config CPackConfig.cmake   # cpack -G DEB --config CPackConfig.cmake
 570 # creates =># lyx-2.0.1-Linux.rpm                       # lyx-2.0.1-Linux.deb
 571 # list      # rpm -qlp lyx-2.0.1-Linux.rpm              # dpkg-deb -c lyx-2.0.1-Linux.deb
 572 # install   # rpm -U lyx-2.0.1-Linux.rpm                # dpkg -i lyx-2.0.1-Linux.deb
 573 #
 574 message(STATUS)