development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  15
  16 project(lyx)
  17
  18 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  19 # is checked
  20 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  21 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  22
  23 # Supress regeneration
  24 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  25
  26 set(VERSION_INFO "CMake Build")
  27
  28 # Try to get some informations from configure.ac
  29
  30 include(LyXPaths)               #called here to define the needed TOP_SRC_DIR-variable
  31 file(STRINGS "${TOP_SRC_DIR}/configure.ac" _config_lines)
  32
  33 macro(setstripped _varname _value)
  34   string(STRIP ${_value} _v)
  35   set(${_varname} ${_v})
  36 endmacro(setstripped)
  37
  38 foreach(_c_l ${_config_lines} )
  39   if(_c_l MATCHES "^AC_INIT\\(\([^,]+\),\([^,]+\),\([^,]+\)\(.*\)")
  40     setstripped(PACKAGE ${CMAKE_MATCH_1})
  41     setstripped(PACKAGE_VERSION ${CMAKE_MATCH_2})
  42     if(PACKAGE_VERSION MATCHES "^\([0-9]+\)\\.\([0-9]+\).*$")
  43       set(LYX_DIR_VER "LYX_DIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  44       set(LYX_USERDIR_VER "LYX_USERDIR_${CMAKE_MATCH_1}${CMAKE_MATCH_2}x")
  45       set(LYX_INSTALL_SUFFIX "${CMAKE_MATCH_1}.${CMAKE_MATCH_2}")
  46     endif()
  47   endif()
  48   if(_c_l MATCHES "^AC_SUBST\\( *LYX_DATE *, *\\[\\\"(.*)\\\"\\].*")
  49     set(LYX_DATE "${CMAKE_MATCH_1}")
  50   endif()
  51 endforeach(_c_l)
  52
  53 set(PROGRAM_SUFFIX "\"\"")
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  55   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  56   if (UNIX)
  57     # don't use the default "/usr/local"
  58     # but respect the user-choice on the command-line
  59     SET(CMAKE_INSTALL_PREFIX
  60       "/usr/local/share/lyx${LYX_INSTALL_SUFFIX}" CACHE PATH "LyX install prefix" FORCE)
  61   endif()
  62   if(WIN32)
  63     SET(CMAKE_INSTALL_PREFIX
  64       ${CMAKE_INSTALL_PREFIX}/${LYX_INSTALL_SUFFIX} CACHE PATH "LyX install prefix" FORCE)
  65   endif()
  66 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  67
  68 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
  69 set(LYX_LOCALEDIR "locale")
  70 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
  71 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
  72
  73
  74 if(WIN32)
  75         set(USE_WINDOWS_PACKAGING 1)
  76 elseif(APPLE)
  77         set(USE_MACOSX_PACKAGING 1)
  78 else()
  79         set(USE_POSIX_PACKAGING 1)
  80 endif()
  81
  82 if(NOT GROUP_CODE)
  83         #set(GROUP_CODE "The Golden Code")
  84         set(GROUP_CODE flat)
  85 endif()
  86
  87 # lyx's source files
  88 set(LYX_CPP_FILES *.cpp)
  89 set(LYX_HPP_FILES *.h)
  90
  91 include(LyXMacros)
  92 include(ProjectSourceGroup)
  93
  94 if(merge OR merge_rebuild)
  95         set(merge 1 CACHE TYPE STRING FORCE)
  96         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  97         message(STATUS "")
  98         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  99         message(STATUS "")
 100 else()
 101         set(merge 0 CACHE TYPE STRING FORCE)
 102         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
 103         message(STATUS "Enable merging files with -Dmerge=1")
 104 endif()
 105
 106
 107 set(CMAKE_BUILD_TYPE Release)
 108
 109 if(profile)
 110         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
 111         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
 112             CACHE TYPE STRING FORCE)
 113         set(profile)
 114 endif()
 115
 116 if(release)
 117         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 118         set(release TRUE CACHE TYPE STRING FORCE)
 119         set(release)
 120 endif()
 121
 122 if(debug)
 123         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 124         set(debug TRUE CACHE TYPE STRING FORCE)
 125         set(debug)
 126 endif()
 127
 128 if(shared)
 129         set(library_type SHARED)
 130         message(STATUS "building shared libraries")
 131 else()
 132         set(library_type STATIC)
 133 endif()
 134
 135 if(NOT MSVC)
 136         if(NOT quiet)
 137                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 138                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 139                 message(STATUS "")
 140         else()
 141                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 142         endif()
 143         set(LYX_CXX_FLAGS -Wall)
 144         if(stdlib-debug)
 145                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 146         endif()
 147         if(concept-checks)
 148                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 149         endif()
 150         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 151         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 152         if(MINGW)
 153                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 154         else()
 155                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 156         endif()
 157         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 158 endif()
 159
 160
 161 find_package(Qt4 REQUIRED)
 162 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 163
 164 find_package(ZLIB REQUIRED)
 165
 166 if(all OR aspell)
 167         set(aspell TRUE CACHE TYPE STRING)
 168         find_package(ASPELL REQUIRED)
 169 else()
 170         find_package(ASPELL)
 171 endif()
 172 set(aspell)
 173
 174 set(use_external_libintl TRUE)
 175
 176 if(use_external_libintl)
 177         find_package(Libintl REQUIRED)
 178         add_definitions(-DHAVE_GETTEXT)
 179 endif()
 180
 181 message("")
 182 if(nls OR all)
 183         set(nls TRUE CACHE TYPE STRING)
 184         add_definitions(-DENABLE_NLS=1)
 185         message("----- Building with ENABLE_NLS")
 186 else()
 187         message("----- No nls, to enable use -Dnls=1")
 188 endif()
 189 set(nls)
 190 if(ASPELL_FOUND)
 191         add_definitions(-DUSE_ASPELL=1)
 192         message("----- Building with USE_ASPELL")
 193 else()
 194         message("----- No aspell, to get more information use -Daspell=1")
 195 endif()
 196 set(all)
 197
 198 if(WIN32)
 199         if(noconsole)
 200                 set(noconsole TRUE CACHE TYPE STRING)
 201                 set(WIN32_CONSOLE WIN32)
 202                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 203                 message("----- Console disabled")
 204         else()
 205                 message("----- Console enabled, disable it with -Dnoconsole=1")
 206         endif()
 207         if(MSVC)
 208                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 209                 # disable checked iterators for msvc release builds to get maximum speed
 210                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 211         else()
 212                 add_definitions(-DWINVER=0x0500)
 213         endif()
 214 endif()
 215
 216 message("")
 217 foreach(_v PACKAGE PACKAGE_VERSION
 218     PROGRAM_SUFFIX LYX_DATE LYX_DIR_VER LYX_USERDIR_VER
 219     LYX_ABS_TOP_SRCDIR
 220     LYX_ABS_INSTALLED_DATADIR LYX_ABS_INSTALLED_LOCALEDIR LYX_INSTALL_SUFFIX)
 221   if(NOT DEFINED ${_v})
 222     message(FATAL_ERROR "${_v} not defined")
 223   endif()
 224   string(SUBSTRING "${_v}                            " 0 28 _v1)
 225   message("----- ${_v1}: ${${_v}}")
 226 endforeach(_v)
 227 message("")
 228
 229
 230 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 231
 232 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 233         message("-----")
 234         message("----- using precompiled headers, disable with -Ddisable-pch=1")
 235         message("-----")
 236         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 237                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 238         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 239                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 240         macro(lyx_add_msvc_pch name_)
 241                 set_source_files_properties(${${name_}_sources} PROPERTIES
 242                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 243                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 244                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 245                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 246                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 247                 add_definitions(/DLYX_ENABLE_PCH)
 248         endmacro(lyx_add_msvc_pch)
 249         set(CMAKE_CXX_FLAGS_DEBUG
 250                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 251         set(CMAKE_CXX_FLAGS_RELEASE
 252                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 253         set(CMAKE_CXX_FLAGS_MINSIZEREL
 254                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 255 else()
 256         if(MSVC)
 257                 message("-----")
 258                 message("----- precompiled headers disabled, enable with -Ddisable-pch=0")
 259                 message("-----")
 260         endif()
 261         set(disable-pch TRUE CACHE TYPE STRING)
 262         macro(lyx_add_msvc_pch)
 263         endmacro(lyx_add_msvc_pch)
 264 endif()
 265
 266 if(MSVC)
 267        if(vld)
 268                set(vld 1 CACHE TYPE STRING FORCE)
 269                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 270                message(STATUS "")
 271                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 272                message(STATUS "")
 273                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 274                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 275                include(${vld_path}/tools/cmake/vld.cmake)
 276        else()
 277                set(vld 0 CACHE TYPE STRING FORCE)
 278                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 279                message(STATUS "")
 280                message(STATUS "Enable leak detection with -Dvld=1")
 281                message(STATUS "")
 282        endif()
 283
 284         if(WALL)
 285                 set(WALL 1 CACHE TYPE STRING FORCE)
 286
 287                 # Use the highest warning level
 288                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 289                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 290
 291                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 292                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 293                 else()
 294                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 295                 endif()
 296
 297                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 298                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 299                 else()
 300                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 301                 endif()
 302
 303                 # add here warnings which should produce an error /weXXXX
 304                 set(MSVC_W_ERROR   "/we4101 /we4189")
 305                 # add here warnings which should be disabled /wdXXXX
 306                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 307
 308                 set(CMAKE_CXX_FLAGS_DEBUG
 309                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 310                 set(CMAKE_CXX_FLAGS_RELEASEs
 311                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 312                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 313                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 314
 315         else()
 316                 set(WALL 0 CACHE TYPE STRING FORCE)
 317
 318                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 319                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 320
 321                 # add here warnings which should produce an error /weXXXX
 322                 set(MSVC_W_ERROR   "/we4101 /we4189")
 323                 # add here warnings which should be disabled /wdXXXX
 324                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 325
 326                 set(CMAKE_CXX_FLAGS_DEBUG
 327                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 328                 set(CMAKE_CXX_FLAGS_RELEASE
 329                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 330                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 331                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 332
 333         endif()
 334
 335         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 336         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 337         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 338         message("")
 339
 340 endif()
 341
 342
 343 if(nls OR all)
 344   find_package(LyXGettext REQUIRED)
 345   include_directories(${TOP_SRC_DIR}/po)
 346   add_subdirectory(po)
 347 endif()
 348
 349 # compiler tests, config.h generation
 350 if(MSVC AND NOT CONFIGURECHECKS)
 351         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 352 else()
 353         include(ConfigureChecks.cmake)
 354         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 355 endif()
 356 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 357
 358
 359 find_package(ICONV REQUIRED)
 360 add_definitions(-DHAVE_ICONV=1)
 361
 362 include_directories(
 363         ${CMAKE_BINARY_DIR}
 364         ${TOP_SRC_DIR}/src
 365         ${TOP_SRC_DIR}/boost)
 366
 367 add_subdirectory(boost)
 368 if(NOT use_external_libintl)
 369         add_subdirectory(intl)
 370 endif()
 371 add_subdirectory(src)
 372
 373 add_subdirectory(man)
 374 add_subdirectory(doc)
 375 add_subdirectory(lyx2lyx)
 376 add_subdirectory(scripts)
 377
 378 include(../Install)
 379