development/cmake/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2006, Peter Kümmel, <syntheticpp@gmx.net>
   5 #
   6
   7 cmake_minimum_required(VERSION 2.4)
   8
   9 if(COMMAND cmake_policy)
  10         cmake_policy(SET CMP0003 OLD)
  11         cmake_policy(SET CMP0005 OLD)
  12 endif(COMMAND cmake_policy)
  13
  14 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  15
  16 project(lyx)
  17
  18 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/
  19 # is checked
  20 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/modules")
  21 set(EXECUTABLE_OUTPUT_PATH  ${CMAKE_BINARY_DIR}/bin)
  22
  23 # Supress regeneration
  24 set(CMAKE_SUPPRESS_REGENERATION TRUE)
  25
  26 set(PACKAGE lyx)
  27 set(PACKAGE_VERSION 2.0svn)
  28 set(LYX_DATE "2008/2009")
  29 #TODO
  30 set(VERSION_INFO "CMake Build")
  31 set(LYX_DIR_VER "LYX_DIR_20x")
  32 set(LYX_USERDIR_VER "LYX_USERDIR_20x")
  33
  34 set(PROGRAM_SUFFIX "\"\"")
  35 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  36   # see http://www.cmake.org/pipermail/cmake/2006-October/011559.html
  37   if (UNIX)
  38     # don't use the default "/usr/local"
  39     # but respect the user-choice on the command-line
  40     SET(CMAKE_INSTALL_PREFIX
  41       "/usr/local/share/lyx2.0" CACHE PATH "LyX install prefix" FORCE)
  42   endif()
  43   if(WIN32)
  44     SET(CMAKE_INSTALL_PREFIX
  45       ${CMAKE_INSTALL_PREFIX}/2.0 CACHE PATH "LyX install prefix" FORCE)
  46   endif()
  47 endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  48
  49 set(LYX_ABS_INSTALLED_DATADIR "${CMAKE_INSTALL_PREFIX}")
  50 set(LYX_LOCALEDIR "locale")
  51 set(LYX_ABS_INSTALLED_LOCALEDIR "${LYX_ABS_INSTALLED_DATADIR}/${LYX_LOCALEDIR}")
  52 set(LYX_ABS_TOP_SRCDIR "${TOP_SRC_DIR}")
  53
  54
  55 if(WIN32)
  56         set(USE_WINDOWS_PACKAGING 1)
  57 elseif(APPLE)
  58         set(USE_MACOSX_PACKAGING 1)
  59 else()
  60         set(USE_POSIX_PACKAGING 1)
  61 endif()
  62
  63 if(NOT GROUP_CODE)
  64         #set(GROUP_CODE "The Golden Code")
  65         set(GROUP_CODE flat)
  66 endif()
  67
  68 # lyx's source files
  69 set(LYX_CPP_FILES *.cpp)
  70 set(LYX_HPP_FILES *.h)
  71
  72 include(LyXPaths)
  73 include(LyXMacros)
  74 include(ProjectSourceGroup)
  75
  76 if(merge OR merge_rebuild)
  77         set(merge 1 CACHE TYPE STRING FORCE)
  78         set(MERGE_FILES 1 CACHE TYPE STRING FORCE)
  79         message(STATUS "")
  80         message(STATUS "All *.cpp files of a project are merged into two files, disable with -Dmerge=0")
  81         message(STATUS "")
  82 else()
  83         set(merge 0 CACHE TYPE STRING FORCE)
  84         set(MERGE_FILES 0 CACHE TYPE STRING FORCE)
  85         message(STATUS "Enable merging files with -Dmerge=1")
  86 endif()
  87
  88
  89 set(CMAKE_BUILD_TYPE Release)
  90
  91 if(profile)
  92         set(CMAKE_BUILD_TYPE Profile CACHE TYPE STRING FORCE)
  93         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pg"
  94             CACHE TYPE STRING FORCE)
  95         set(profile)
  96 endif()
  97
  98 if(release)
  99         set(CMAKE_BUILD_TYPE Release CACHE TYPE STRING FORCE)
 100         set(release TRUE CACHE TYPE STRING FORCE)
 101         set(release)
 102 endif()
 103
 104 if(debug)
 105         set(CMAKE_BUILD_TYPE Debug CACHE TYPE STRING FORCE)
 106         set(debug TRUE CACHE TYPE STRING FORCE)
 107         set(debug)
 108 endif()
 109
 110 if(shared)
 111         set(library_type SHARED)
 112         message(STATUS "building shared libraries")
 113 else()
 114         set(library_type STATIC)
 115 endif()
 116
 117 if(NOT MSVC)
 118         if(NOT quiet)
 119                 set(CMAKE_VERBOSE_MAKEFILE ON CACHE TYPE STRING FORCE)
 120                 message(STATUS "verbose Makefile, disable with -Dquiet=1")
 121                 message(STATUS "")
 122         else()
 123                 set(CMAKE_VERBOSE_MAKEFILE OFF CACHE TYPE STRING FORCE)
 124         endif()
 125         set(LYX_CXX_FLAGS -Wall)
 126         if(stdlib-debug)
 127                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCXX_DEBUG -D_GLIBCXX_DEBUG_PEDANTIC")
 128         endif()
 129         if(concept-checks)
 130                 set(LYX_CXX_FLAGS "${LYX_CXX_FLAGS} -D_GLIBCPP_CONCEPT_CHECKS")
 131         endif()
 132         set(CMAKE_CXX_FLAGS          "${LYX_CXX_FLAGS}" CACHE TYPE STRING FORCE)
 133         set(CMAKE_CXX_FLAGS_DEBUG    "${LYX_CXX_FLAGS} -O -g -D_DEBUG" CACHE TYPE STRING FORCE)
 134         if(MINGW)
 135                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O2 -DNDEBUG" CACHE TYPE STRING FORCE)
 136         else()
 137                 set(CMAKE_CXX_FLAGS_RELEASE  "${LYX_CXX_FLAGS} -O3 -DNDEBUG" CACHE TYPE STRING FORCE)
 138         endif()
 139         set(CMAKE_CXX_FLAGS_PROFILE  "${CMAKE_CXX_FLAGS_RELEASE} -pg" CACHE TYPE STRING FORCE)
 140 endif()
 141
 142
 143 find_package(Qt4 REQUIRED)
 144 add_definitions(-DQT_NO_STL -DQT_NO_KEYWORDS)
 145
 146 find_package(ZLIB REQUIRED)
 147
 148 if(all OR aspell)
 149         set(aspell TRUE CACHE TYPE STRING)
 150         find_package(ASPELL REQUIRED)
 151 else()
 152         find_package(ASPELL)
 153 endif()
 154 set(aspell)
 155
 156 set(use_external_libintl TRUE)
 157
 158 if(use_external_libintl)
 159         find_package(Libintl REQUIRED)
 160         add_definitions(-DHAVE_GETTEXT)
 161 endif()
 162
 163 message("")
 164 if(nls OR all)
 165         set(nls TRUE CACHE TYPE STRING)
 166         add_definitions(-DENABLE_NLS=1)
 167         message("----- Building with ENABLE_NLS")
 168 else()
 169         message("----- No nls, to enable use -Dnls=1")
 170 endif()
 171 set(nls)
 172 if(ASPELL_FOUND)
 173         add_definitions(-DUSE_ASPELL=1)
 174         message("----- Building with USE_ASPELL")
 175 else()
 176         message("----- No aspell, to get more information use -Daspell=1")
 177 endif()
 178 set(all)
 179
 180 if(WIN32)
 181         if(noconsole)
 182                 set(noconsole TRUE CACHE TYPE STRING)
 183                 set(WIN32_CONSOLE WIN32)
 184                 set(LYX_QTMAIN_LIBRARY ${QT_QTMAIN_LIBRARY})
 185                 message("----- Console disabled")
 186         else()
 187                 message("----- Console enabled, disable it with -Dnoconsole=1")
 188         endif()
 189         if(MSVC)
 190                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -DNOMINMAX)
 191                 # disable checked iterators for msvc release builds to get maximum speed
 192                 set(CMAKE_CXX_FLAGS_RELEASE  "${CMAKE_CXX_FLAGS_RELEASE} /D_SECURE_SCL=0")
 193         else()
 194                 add_definitions(-DWINVER=0x0500)
 195         endif()
 196 endif()
 197
 198 message("")
 199 message("----- PROGRAM_SUFFIX              : ${PROGRAM_SUFFIX}")
 200 message("----- LYX_ABS_TOP_SRCDIR          : ${LYX_ABS_TOP_SRCDIR}")
 201 message("----- LYX_ABS_INSTALLED_DATADIR   : ${LYX_ABS_INSTALLED_DATADIR}")
 202 message("----- LYX_ABS_INSTALLED_LOCALEDIR : ${LYX_ABS_INSTALLED_LOCALEDIR}")
 203 message("")
 204
 205
 206 add_definitions(-DBOOST_USER_CONFIG="<config.h>")
 207
 208 if(MSVC AND NOT disable-pch AND NOT MERGE_FILES)
 209         message("-----")
 210         message("----- using precompiled headers, disable with -Ddisable-pch=1")
 211         message("-----")
 212         configure_file(${CMAKE_SOURCE_DIR}/pcheaders.h
 213                 ${CMAKE_BINARY_DIR}/pcheaders.h)
 214         configure_file(${CMAKE_SOURCE_DIR}/config.cpp.cmake
 215                 ${CMAKE_BINARY_DIR}/config_pch.cpp)
 216         macro(lyx_add_msvc_pch name_)
 217                 set_source_files_properties(${${name_}_sources} PROPERTIES
 218                         COMPILE_FLAGS "/Yuconfig.h /Fp\$(IntDir)/config.pch")
 219                 set_source_files_properties(${CMAKE_BINARY_DIR}/config_pch.cpp PROPERTIES
 220                         COMPILE_FLAGS "/Ycconfig.h /Fp\$(IntDir)/config.pch")
 221                 set(${name_}_sources ${${name_}_sources} ${CMAKE_BINARY_DIR}/config_pch.cpp
 222                         ${CMAKE_BINARY_DIR}/pcheaders.h)
 223                 add_definitions(/DLYX_ENABLE_PCH)
 224         endmacro(lyx_add_msvc_pch)
 225         set(CMAKE_CXX_FLAGS_DEBUG
 226                 "${CMAKE_CXX_FLAGS_DEBUG} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 227         set(CMAKE_CXX_FLAGS_RELEASE
 228                 "${CMAKE_CXX_FLAGS_RELEASE} /DLYX_PCH_STL /DLYX_PCH_BOOST /DLYX_PCH_QT4")
 229         set(CMAKE_CXX_FLAGS_MINSIZEREL
 230                 "${CMAKE_CXX_FLAGS_MINSIZEREL} /DLYX_PCH_STL /DLYX_PCH_BOOST")
 231 else()
 232         if(MSVC)
 233                 message("-----")
 234                 message("----- precompiled headers disabled, enable with -Ddisable-pch=0")
 235                 message("-----")
 236         endif()
 237         set(disable-pch TRUE CACHE TYPE STRING)
 238         macro(lyx_add_msvc_pch)
 239         endmacro(lyx_add_msvc_pch)
 240 endif()
 241
 242 if(MSVC)
 243        if(vld)
 244                set(vld 1 CACHE TYPE STRING FORCE)
 245                set(LYX_LEAK_DETECTION 1 CACHE TYPE STRING FORCE)
 246                message(STATUS "")
 247                message(STATUS "Leak detection enabled, disable with -Dvld=0")
 248                message(STATUS "")
 249                set(LIBRARY_OUTPUT_PATH  ${EXECUTABLE_OUTPUT_PATH})
 250                set(vld_path ${CMAKE_CURRENT_SOURCE_DIR}/../Win32/vld)
 251                include(${vld_path}/tools/cmake/vld.cmake)
 252        else()
 253                set(vld 0 CACHE TYPE STRING FORCE)
 254                set(LYX_LEAK_DETECTION 0 CACHE TYPE STRING FORCE)
 255                message(STATUS "")
 256                message(STATUS "Enable leak detection with -Dvld=1")
 257                message(STATUS "")
 258        endif()
 259
 260         if(WALL)
 261                 set(WALL 1 CACHE TYPE STRING FORCE)
 262
 263                 # Use the highest warning level
 264                 set(CMAKE_CXX_WARNING_LEVEL 4 CACHE TYPE STRING FORCE)
 265                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 3 with -DWALL=0)")
 266
 267                 if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
 268                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 269                 else()
 270                         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
 271                 endif()
 272
 273                 if(CMAKE_C_FLAGS MATCHES "/W[0-4]")
 274                         string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 275                 else()
 276                         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W4")
 277                 endif()
 278
 279                 # add here warnings which should produce an error /weXXXX
 280                 set(MSVC_W_ERROR   "/we4101 /we4189")
 281                 # add here warnings which should be disabled /wdXXXX
 282                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4311 /wd4312 /wd4505 /wd4267 /wd4512 /wd4245 /wd4127 /wd4180")
 283
 284                 set(CMAKE_CXX_FLAGS_DEBUG
 285                         "${CMAKE_CXX_FLAGS_DEBUG} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 286                 set(CMAKE_CXX_FLAGS_RELEASEs
 287                         "${CMAKE_CXX_FLAGS_RELEASE} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 288                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 289                         "${CMAKE_CXX_FLAGS_MINSIZEREL} /Wp64 ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 290
 291         else()
 292                 set(WALL 0 CACHE TYPE STRING FORCE)
 293
 294                 set(CMAKE_CXX_WARNING_LEVEL 3 CACHE TYPE STRING FORCE)
 295                 set(WARNING_LEVEL_MESSAGE "(switch to warning level 4 with -DWALL=1)")
 296
 297                 # add here warnings which should produce an error /weXXXX
 298                 set(MSVC_W_ERROR   "/we4101 /we4189")
 299                 # add here warnings which should be disabled /wdXXXX
 300                 set(MSVC_W_DISABLE "/wd4288 /wd4355 /wd4800 /wd4996 /wd4267 /wd4180")
 301
 302                 set(CMAKE_CXX_FLAGS_DEBUG
 303                         "${CMAKE_CXX_FLAGS_DEBUG} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 304                 set(CMAKE_CXX_FLAGS_RELEASE
 305                         "${CMAKE_CXX_FLAGS_RELEASE} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 306                 set(CMAKE_CXX_FLAGS_MINSIZEREL
 307                         "${CMAKE_CXX_FLAGS_MINSIZEREL} ${MSVC_W_ERROR} ${MSVC_W_DISABLE}")
 308
 309         endif()
 310
 311         message("----- Warning level      : ${CMAKE_CXX_WARNING_LEVEL}  ${WARNING_LEVEL_MESSAGE}")
 312         message("----- Warnings as errors : ${MSVC_W_ERROR}")
 313         message("----- Warnings disabled  : ${MSVC_W_DISABLE}")
 314         message("")
 315
 316 endif()
 317
 318
 319 if(nls OR all)
 320   find_package(LyXGettext REQUIRED)
 321   include_directories(${TOP_SRC_DIR}/po)
 322   add_subdirectory(po)
 323 endif()
 324
 325 # compiler tests, config.h generation
 326 if(MSVC AND NOT CONFIGURECHECKS)
 327         configure_file(configCompiler.h.msvc ${CMAKE_BINARY_DIR}/configCompiler.h)
 328 else()
 329         include(ConfigureChecks.cmake)
 330         configure_file(configCompiler.h.cmake ${CMAKE_BINARY_DIR}/configCompiler.h)
 331 endif()
 332 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h)
 333
 334
 335 find_package(ICONV REQUIRED)
 336 add_definitions(-DHAVE_ICONV=1)
 337
 338 #TODO: insource is not the best place
 339 configure_file(${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py.in
 340                ${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx_version.py)
 341
 342 include_directories(
 343         ${CMAKE_BINARY_DIR}
 344         ${TOP_SRC_DIR}/src
 345         ${TOP_SRC_DIR}/boost)
 346
 347 add_subdirectory(boost)
 348 if(NOT use_external_libintl)
 349         add_subdirectory(intl)
 350 endif()
 351 add_subdirectory(src)
 352
 353 add_subdirectory(man)
 354 add_subdirectory(doc)
 355 if (UNIX)
 356     add_subdirectory(lyx2lyx)
 357 endif()
 358
 359 include(../Install)
 360