development/checkurls/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2013 Kornel Benko <kornel@lyx.org>
   5 #           (c) 2013 Scott Kostyshak <skotysh@lyx.org>
   6 #
   7 # Needed, because of perl scripts here
   8 find_package(Perl REQUIRED)
   9
  10 # create file the lyx-files-list
  11 set(TOP_SEARCH_PATH "${TOP_SRC_DIR}")
  12 set(LYXFILES_FILE "${CMAKE_CURRENT_BINARY_DIR}/filesToScan")
  13 file(WRITE "${LYXFILES_FILE}")
  14 file(GLOB_RECURSE lyx_files RELATIVE "${TOP_SEARCH_PATH}" "${TOP_SEARCH_PATH}/*.lyx")
  15
  16 foreach(_f ${lyx_files})
  17   file(APPEND "${LYXFILES_FILE}" "${_f}\n")
  18 endforeach()
  19
  20 # Define the perl-script running the actual test
  21 set(SEARCH_URL_SCRIPT "${CMAKE_CURRENT_SOURCE_DIR}/search_url.pl")
  22 set(GET_TRANSLATORS_SCRIPT "${CMAKE_CURRENT_SOURCE_DIR}/getTranslators.pl")
  23
  24 # Test used and as accessible expected urls
  25 add_test(NAME "check_accessible_urls"
  26   WORKING_DIRECTORY "${TOP_SEARCH_PATH}"
  27   COMMAND ${PERL_EXECUTABLE} "${SEARCH_URL_SCRIPT}"
  28     "filesToScan=${LYXFILES_FILE}"
  29     "ignoredURLS=${CMAKE_CURRENT_SOURCE_DIR}/inaccessibleURLS"
  30     "ignoredURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownInvalidURLS"
  31     "summaryFile=${TOP_BINARY_DIR}/Testing/Temporary/LastFailedAccessibleURLS.log")
  32
  33 # Test inaccessible, but revert the error marker (failed <=> passed)
  34 # if this fails, then some url is accessible and does not belong
  35 # to file inaccessibleURLS
  36 add_test(NAME "check_inaccessible_urls"
  37   WORKING_DIRECTORY "${TOP_SEARCH_PATH}"
  38   COMMAND ${PERL_EXECUTABLE} "${SEARCH_URL_SCRIPT}"
  39     "filesToScan=${LYXFILES_FILE}"
  40     "selectedURLS=${CMAKE_CURRENT_SOURCE_DIR}/inaccessibleURLS"
  41     "revertedURLS=${CMAKE_CURRENT_SOURCE_DIR}/inaccessibleURLS"
  42     "summaryFile=${TOP_BINARY_DIR}/Testing/Temporary/LastFailedInaccessibleURLS.log")
  43
  44 #
  45 # Test our own bad urls
  46 # and urls used in examples which should not match valid urls
  47 # if this test fails, then our testtool contains errors
  48 add_test(NAME "check_invalid_urls"
  49   WORKING_DIRECTORY "${TOP_SEARCH_PATH}"
  50   COMMAND ${PERL_EXECUTABLE} "${SEARCH_URL_SCRIPT}"
  51     "extraURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownInvalidURLS"
  52     "revertedURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownInvalidURLS"
  53     "summaryFile=${TOP_BINARY_DIR}/Testing/Temporary/LastFailedKnownInvalidURLS.log")
  54
  55 set(URL_TEST_NAMES "check_accessible_urls" "check_inaccessible_urls" "check_invalid_urls")
  56 add_test(NAME "check_translators"
  57   WORKING_DIRECTORY "${TOP_BINARY_DIR}"
  58   COMMAND ${PERL_EXECUTABLE} "${GET_TRANSLATORS_SCRIPT}")
  59
  60 set_tests_properties(${URL_TEST_NAMES}
  61         PROPERTIES RESOURCE_LOCK "url.lock" LABELS "url")
  62 set_tests_properties("check_translators"
  63         PROPERTIES RESOURCE_LOCK "url.lock")
  64
  65 settestlabel("check_inaccessible_urls" "reverted")
  66 settestlabel("check_invalid_urls" "reverted")