development/checkurls/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2013 Kornel Benko <kornel@lyx.org>
   5 #           (c) 2013 Scott Kostyshak <skotysh@lyx.org>
   6 #
   7 # Needed, because of perl scripts here
   8 find_package(Perl REQUIRED)
   9
  10 # create file the lyx-files-list
  11 set(TOP_SEARCH_PATH "${TOP_SRC_DIR}")
  12 set(LYXFILES_FILE "${CMAKE_CURRENT_BINARY_DIR}/filesToScan")
  13 file(WRITE "${LYXFILES_FILE}")
  14 file(GLOB_RECURSE lyx_files RELATIVE "${TOP_SEARCH_PATH}" "${TOP_SEARCH_PATH}/*.lyx")
  15
  16 set(NO_SEARCH_PATHS "/attic/" "src/tex2lyx/test" "/autotests/" "development/" "/Obsolete/")
  17 foreach(_f ${lyx_files})
  18   set(found OFF)
  19   foreach(_p ${NO_SEARCH_PATHS})
  20     if (_f MATCHES "${_p}")
  21       set(found ON)
  22     endif()
  23   endforeach()
  24   if (NOT found)
  25     file(APPEND "${LYXFILES_FILE}" "${_f}\n")
  26   endif()
  27 endforeach()
  28
  29 # Define the perl-script running the actual test
  30 set(SEARCH_URL_SCRIPT "${CMAKE_CURRENT_SOURCE_DIR}/search_url.pl")
  31 set(GET_TRANSLATORS_SCRIPT "${CMAKE_CURRENT_SOURCE_DIR}/getTranslators.pl")
  32
  33 # Test used and as accessible expected urls
  34 add_test(NAME "check_accessible_urls"
  35   WORKING_DIRECTORY "${TOP_SEARCH_PATH}"
  36   COMMAND ${PERL_EXECUTABLE} "${SEARCH_URL_SCRIPT}"
  37     "filesToScan=${LYXFILES_FILE}"
  38     "ignoredURLS=${CMAKE_CURRENT_SOURCE_DIR}/inaccessibleURLS"
  39     "ignoredURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownInvalidURLS"
  40     "knownToRegisterURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownToRegisterURLS"
  41     "summaryFile=${TOP_BINARY_DIR}/Testing/Temporary/LastFailedAccessibleURLS.log")
  42
  43 # Test inaccessible, but revert the error marker (failed <=> passed)
  44 # if this fails, then some url is accessible and does not belong
  45 # to file inaccessibleURLS
  46 add_test(NAME "check_inaccessible_urls"
  47   WORKING_DIRECTORY "${TOP_SEARCH_PATH}"
  48   COMMAND ${PERL_EXECUTABLE} "${SEARCH_URL_SCRIPT}"
  49     "filesToScan=${LYXFILES_FILE}"
  50     "selectedURLS=${CMAKE_CURRENT_SOURCE_DIR}/inaccessibleURLS"
  51     "revertedURLS=${CMAKE_CURRENT_SOURCE_DIR}/inaccessibleURLS"
  52     "knownToRegisterURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownToRegisterURLS"
  53     "summaryFile=${TOP_BINARY_DIR}/Testing/Temporary/LastFailedInaccessibleURLS.log")
  54
  55 #
  56 # Test our own bad urls
  57 # and urls used in examples which should not match valid urls
  58 # if this test fails, then our testtool contains errors
  59 add_test(NAME "check_invalid_urls"
  60   WORKING_DIRECTORY "${TOP_SEARCH_PATH}"
  61   COMMAND ${PERL_EXECUTABLE} "${SEARCH_URL_SCRIPT}"
  62     "extraURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownInvalidURLS"
  63     "revertedURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownInvalidURLS"
  64     "knownToRegisterURLS=${CMAKE_CURRENT_SOURCE_DIR}/knownToRegisterURLS"
  65     "summaryFile=${TOP_BINARY_DIR}/Testing/Temporary/LastFailedKnownInvalidURLS.log")
  66
  67 set(URL_TEST_NAMES "check_accessible_urls" "check_inaccessible_urls" "check_invalid_urls")
  68 set_tests_properties(${URL_TEST_NAMES}
  69         PROPERTIES RESOURCE_LOCK "url.lock" LABELS "url")
  70
  71 find_file(PHANTOMJS_EXE NAME phantomjs PATHS ENV PATH)
  72 message(STATUS "PHANTOMJS_EXE = ${PHANTOMJS_EXE}")
  73 if (PHANTOMJS_EXE)
  74   add_test(NAME "check_translators"
  75     WORKING_DIRECTORY "${TOP_BINARY_DIR}"
  76     COMMAND ${PERL_EXECUTABLE} "${GET_TRANSLATORS_SCRIPT}")
  77
  78   set_tests_properties("check_translators"
  79           PROPERTIES RESOURCE_LOCK "url.lock")
  80
  81 else()
  82   message(STATUS "Cannot check translators, missing required program phantomjs")
  83 endif()
  84
  85 settestlabel("check_inaccessible_urls" "inverted")
  86 settestlabel("check_invalid_urls" "inverted")