development/autotests/single-test.cmake

   1 # This script invokes the keytest.py script with the simple set-up needed
   2 # to re-run deterministic regression tests that one would like to have.
   3 #
   4 # AUTOTEST_ROOT   = ${LYX_ROOT}/development/autotests
   5 # KEYTEST_INFILE  = xxx-in.txt
   6 # KEYTEST_OUTFILE = xxx-out.txt
   7 # BINDIR          = ${BUILD_DIR}/bin
   8 # WORKDIR         = ${BUILD_DIR}/autotests/out-home
   9 # LYX_USERDIR_VER = ${LYX_USERDIR_VER}
  10 # LOCALE_DIR      = ${BUILD_DIR}/autotests/locale
  11 # PO_BUILD_DIR    = ${BUILD_DIR}/po
  12 # PACKAGE         = lyx2.1
  13 #
  14 # Script should be called like:
  15 # cmake -DAUTOTEST_ROOT=xxxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
  17 #       -DKEYTEST_INFILE=xxxx \
  18 #       -DKEYTEST_OUTFILE=xxx \
  19 #       -DBINDIR=xxx \
  20 #       -DLYX=xxx \
  21 #       -DWORKDIR=xxx \
  22 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  23 #       -DLOCALE_DIR=xxx \
  24 #       -DPO_BUILD_DIR=xxx \
  25 #       -DPACKAGE=xxx \
  26 #       -P ${AUTOTEST_ROOT}/single-test.cmake
  27
  28 set(KEYTEST "${AUTOTEST_ROOT}/keytest.py")
  29
  30 execute_process(COMMAND pidof ${LYX} OUTPUT_VARIABLE LYX_PID RESULT_VARIABLE pidstat OUTPUT_VARIABLE pidres)
  31 message(STATUS "pidres = ${pidres}")
  32 if (NOT pidstat)
  33   # lyx already running, remove trailing '\n' from pid
  34   string(REGEX REPLACE "\n" "" pidres ${pidres})
  35   execute_process(COMMAND wmctrl -l -p OUTPUT_VARIABLE _wmco)
  36   string(REGEX REPLACE "[\n]+" ";" _wmc ${_wmco})
  37   foreach(_w ${_wmc})
  38     string(REGEX MATCH "${pidres}" _wr ${_w})
  39     if (${_wr} MATCHES ${pidres})
  40       # this entry contains the pid, go search for X11-window-id
  41       string(REGEX REPLACE " .*" "" _wr ${_w})
  42       set(LYX_WINDOW_NAME ${_wr})
  43       message(STATUS "Set LYX_WINDOW_NAME to ${_wr}")
  44     endif()
  45   endforeach()
  46 else()
  47   set(pidres "")
  48   set(LYX_WINDOW_NAME "")
  49 endif()
  50
  51 set(LYX_EXE "${BINDIR}/${LYX}")
  52 set(use_hacked $ENV{XVKBD_HACKED})
  53 if(NOT use_hacked)
  54   if(use_hacked STREQUAL "")
  55     # ENV{XVKBD_HACKED} probably not set, so the default should be
  56     # to use the hacked
  57     set(use_hacked "1")
  58   else()
  59     set(use_hacked "0")
  60   endif()
  61 else()
  62   set(use_hacked "1")
  63 endif()
  64
  65 set(ENV{XVKBD_HACKED} ${use_hacked})
  66 if(use_hacked)
  67   set(XVKBD_EXE "${BINDIR}/xvkbd")
  68 else()
  69   set(XVKBD_EXE "/usr/bin/xvkbd")
  70 endif()
  71
  72 if(EXISTS "${LYX_TESTS_USERDIR}/session")
  73   execute_process(COMMAND ${CMAKE_COMMAND} -E remove -f "${LYX_TESTS_USERDIR}/session")
  74 endif()
  75 # Environments needed by keytest.py
  76 set(ENV{PACKAGE} ${PACKAGE})
  77 set(ENV{LOCALE_DIR} ${LOCALE_DIR})
  78 set(ENV{LYX_LOCALEDIR} "${WORKDIR}/../locale")
  79 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  80 set(ENV{LYX_PID} ${pidres})
  81 set(ENV{LYX_WINDOW_NAME} ${LYX_WINDOW_NAME})
  82 set(ENV{LYX_EXE} ${LYX_EXE})
  83 set(ENV{LYX} ${LYX})
  84 set(ENV{XVKBD_EXE} ${XVKBD_EXE})
  85 set(ENV{KEYTEST_INFILE} "${AUTOTEST_ROOT}/${KEYTEST_INFILE}")
  86 set(ENV{KEYTEST_OUTFILE} "${WORKDIR}/${KEYTEST_OUTFILE}")
  87 set(ENV{PO_BUILD_DIR} "${PO_BUILD_DIR}")
  88 set(ENV{MAX_DROP} 0)
  89 set(ENV{MAX_LOOPS} 1)
  90 string(REGEX REPLACE "-in\\.(txt|sh)$" "" _jj ${KEYTEST_INFILE})
  91 if(EXISTS "${WORKDIR}/../${_jj}.lyx.emergency")
  92   execute_process(
  93   COMMAND ${CMAKE_COMMAND} -E remove -f "${WORKDIR}/../${_jj}.lyx.emergency" )
  94 endif()
  95 file(GLOB _testfiles RELATIVE "${WORKDIR}" "test*.*" "#test*.*")
  96 if(_testfiles)
  97   # remove some leftover files from previous test
  98   execute_process(
  99   COMMAND ${CMAKE_COMMAND} -E remove -f ${_testfiles} )
 100 endif()
 101 if(EXISTS "${AUTOTEST_ROOT}/${_jj}.lyx")
 102   configure_file("${AUTOTEST_ROOT}/${_jj}.lyx" "${WORKDIR}/../${_jj}.lyx" COPYONLY)
 103 endif()
 104 execute_process(
 105   COMMAND python ${KEYTEST}
 106   RESULT_VARIABLE KEYTEST_RES)
 107 if(KEYTEST_RES)
 108   message(FATAL_ERROR "KEYTEST failed: KEYTEST_RES=${KEYTEST_RES}")
 109 endif()
 110