development/autotests/single-test.cmake

   1 # This script invokes the keytest.py script with the simple set-up needed
   2 # to re-run deterministic regression tests that one would like to have.
   3 #
   4 # AUTOTEST_ROOT   = ${LYX_ROOT}/development/autotests
   5 # KEYTEST_INFILE  = xxx-in.txt
   6 # KEYTEST_OUTFILE = xxx-out.txt
   7 # BINDIR          = ${BUILD_DIR}/bin
   8 # WORKDIR         = ${BUILD_DIR}/autotests/out-home
   9 # LOCALE_DIR      = ${BUILD_DIR}/autotests/locale
  10 # PO_BUILD_DIR    = ${BUILD_DIR}/po
  11 # PACKAGE         = lyx2.1
  12 #
  13 # Script should be called like:
  14 # cmake -DAUTOTEST_ROOT=xxxx \
  15 #       -DKEYTEST_INFILE=xxxx \
  16 #       -DKEYTEST_OUTFILE=xxx \
  17 #       -DBINDIR=xxx \
  18 #       -DWORKDIR=xxx \
  19 #       -DLOCALE_DIR=xxx \
  20 #       -DPO_BUILD_DIR=xxx \
  21 #       -DPACKAGE=xxx \
  22 #       -P ${AUTOTEST_ROOT}/single-test.cmake
  23
  24 set(KEYTEST "${AUTOTEST_ROOT}/keytest.py")
  25
  26 execute_process(COMMAND pidof lyx OUTPUT_VARIABLE LYX_PID RESULT_VARIABLE pidstat OUTPUT_VARIABLE pidres)
  27 message(STATUS "pidres = ${pidres}")
  28 if (NOT pidstat)
  29   # lyx already running, remove trailing '\n' from pid
  30   string(REGEX REPLACE "\n" "" pidres ${pidres})
  31   execute_process(COMMAND wmctrl -l -p OUTPUT_VARIABLE _wmco)
  32   string(REGEX REPLACE "[\n]+" ";" _wmc ${_wmco})
  33   foreach(_w ${_wmc})
  34     string(REGEX MATCH "${pidres}" _wr ${_w})
  35     if (${_wr} MATCHES ${pidres})
  36       # this entry contains the pid, go search for X11-window-id
  37       string(REGEX REPLACE " .*" "" _wr ${_w})
  38       set(LYX_WINDOW_NAME ${_wr})
  39       message(STATUS "Set LYX_WINDOW_NAME to ${_wr}")
  40     endif()
  41   endforeach()
  42 else()
  43   set(pidres "")
  44   set(LYX_WINDOW_NAME "")
  45 endif()
  46
  47 set(LYX_EXE "${BINDIR}/lyx")
  48 set(XVKBD_EXE "${BINDIR}/xvkbd")
  49
  50 # Environments needed by keytest.py
  51 set(ENV{PACKAGE} ${PACKAGE})
  52 set(ENV{LOCALE_DIR} ${LOCALE_DIR})
  53 set(ENV{LYX_LOCALEDIR} "${WORKDIR}/../locale")
  54 set(ENV{LYX_USERDIR} ${LYX_USERDIR})
  55 set(ENV{LYX_PID} ${pidres})
  56 set(ENV{LYX_WINDOW_NAME} ${LYX_WINDOW_NAME})
  57 set(ENV{LYX_EXE} ${LYX_EXE})
  58 set(ENV{XVKBD_EXE} ${XVKBD_EXE})
  59 set(ENV{KEYTEST_INFILE} "${AUTOTEST_ROOT}/${KEYTEST_INFILE}")
  60 set(ENV{KEYTEST_OUTFILE} "${WORKDIR}/${KEYTEST_OUTFILE}")
  61 set(ENV{PO_BUILD_DIR} "${PO_BUILD_DIR}")
  62 set(ENV{MAX_DROP} 1)
  63 file(GLOB _testfiles RELATIVE "${WORKDIR}" "test*.*" "#test*.*")
  64 if(_testfiles)
  65   # remove some leftover files from previous test
  66   execute_process(
  67   COMMAND ${CMAKE_COMMAND} -E remove -f ${_testfiles} )
  68 endif()
  69 execute_process(
  70   COMMAND python ${KEYTEST}
  71   RESULT_VARIABLE KEYTEST_RES)
  72 if(KEYTEST_RES)
  73   message(FATAL_ERROR "KEYTEST failed: KEYTEST_RES=${KEYTEST_RES}")
  74 endif()
  75