development/autotests/single-test.cmake

   1 # This script invokes the keytest.py script with the simple set-up needed
   2 # to re-run deterministic regression tests that one would like to have.
   3 #
   4 # AUTOTEST_ROOT   = ${LYX_ROOT}/development/autotests
   5 # KEYTEST_INFILE  = xxx-in.txt
   6 # KEYTEST_OUTFILE = xxx-out.txt
   7 # BINDIR          = ${BUILD_DIR}/bin
   8 # WORKDIR         = ${BUILD_DIR}/autotests/out-home
   9 # LYX_USERDIR_VER = ${LYX_USERDIR_VER}
  10 # LOCALE_DIR      = ${BUILD_DIR}/autotests/locale
  11 # PO_BUILD_DIR    = ${BUILD_DIR}/po
  12 # PACKAGE         = lyx2.1
  13 #
  14 # Script should be called like:
  15 # cmake -DAUTOTEST_ROOT=xxxx \
  16 #       -DKEYTEST_INFILE=xxxx \
  17 #       -DKEYTEST_OUTFILE=xxx \
  18 #       -DBINDIR=xxx \
  19 #       -DLYX=xxx \
  20 #       -DWORKDIR=xxx \
  21 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  22 #       -DLOCALE_DIR=xxx \
  23 #       -DPO_BUILD_DIR=xxx \
  24 #       -DPACKAGE=xxx \
  25 #       -P ${AUTOTEST_ROOT}/single-test.cmake
  26
  27 set(KEYTEST "${AUTOTEST_ROOT}/keytest.py")
  28
  29 execute_process(COMMAND pidof ${LYX} OUTPUT_VARIABLE LYX_PID RESULT_VARIABLE pidstat OUTPUT_VARIABLE pidres)
  30 message(STATUS "pidres = ${pidres}")
  31 if (NOT pidstat)
  32   # lyx already running, remove trailing '\n' from pid
  33   string(REGEX REPLACE "\n" "" pidres ${pidres})
  34   execute_process(COMMAND wmctrl -l -p OUTPUT_VARIABLE _wmco)
  35   string(REGEX REPLACE "[\n]+" ";" _wmc ${_wmco})
  36   foreach(_w ${_wmc})
  37     string(REGEX MATCH "${pidres}" _wr ${_w})
  38     if (${_wr} MATCHES ${pidres})
  39       # this entry contains the pid, go search for X11-window-id
  40       string(REGEX REPLACE " .*" "" _wr ${_w})
  41       set(LYX_WINDOW_NAME ${_wr})
  42       message(STATUS "Set LYX_WINDOW_NAME to ${_wr}")
  43     endif()
  44   endforeach()
  45 else()
  46   set(pidres "")
  47   set(LYX_WINDOW_NAME "")
  48 endif()
  49
  50 set(LYX_EXE "${BINDIR}/${LYX}")
  51 set(use_hacked $ENV{XVKBD_HACKED})
  52 if(NOT use_hacked)
  53   if(use_hacked STREQUAL "")
  54     # ENV{XVKBD_HACKED} probably not set, so the default should be
  55     # to use the hacked
  56     set(use_hacked "1")
  57   else()
  58     set(use_hacked "0")
  59   endif()
  60 else()
  61   set(use_hacked "1")
  62 endif()
  63
  64 set(ENV{XVKBD_HACKED} ${use_hacked})
  65 if(use_hacked)
  66   set(XVKBD_EXE "${BINDIR}/xvkbd")
  67 else()
  68   set(XVKBD_EXE "/usr/bin/xvkbd")
  69 endif()
  70
  71 if(EXISTS "${WORKDIR}/.lyx/session")
  72   execute_process(COMMAND ${CMAKE_COMMAND} -E remove -f "${WORKDIR}/.lyx/session")
  73 endif()
  74 # Environments needed by keytest.py
  75 set(ENV{PACKAGE} ${PACKAGE})
  76 set(ENV{LOCALE_DIR} ${LOCALE_DIR})
  77 set(ENV{LYX_LOCALEDIR} "${WORKDIR}/../locale")
  78 set(ENV{${LYX_USERDIR_VER}} "${WORKDIR}/.lyx")
  79 set(ENV{LYX_PID} ${pidres})
  80 set(ENV{LYX_WINDOW_NAME} ${LYX_WINDOW_NAME})
  81 set(ENV{LYX_EXE} ${LYX_EXE})
  82 set(ENV{LYX} ${LYX})
  83 set(ENV{XVKBD_EXE} ${XVKBD_EXE})
  84 set(ENV{KEYTEST_INFILE} "${AUTOTEST_ROOT}/${KEYTEST_INFILE}")
  85 set(ENV{KEYTEST_OUTFILE} "${WORKDIR}/${KEYTEST_OUTFILE}")
  86 set(ENV{PO_BUILD_DIR} "${PO_BUILD_DIR}")
  87 set(ENV{MAX_DROP} 0)
  88 set(ENV{MAX_LOOPS} 1)
  89 string(REGEX REPLACE "-in\\.(txt|sh)$" "" _jj ${KEYTEST_INFILE})
  90 if(EXISTS "${WORKDIR}/../${_jj}.lyx.emergency")
  91   execute_process(
  92   COMMAND ${CMAKE_COMMAND} -E remove -f "${WORKDIR}/../${_jj}.lyx.emergency" )
  93 endif()
  94 file(GLOB _testfiles RELATIVE "${WORKDIR}" "test*.*" "#test*.*")
  95 if(_testfiles)
  96   # remove some leftover files from previous test
  97   execute_process(
  98   COMMAND ${CMAKE_COMMAND} -E remove -f ${_testfiles} )
  99 endif()
 100 if(EXISTS "${AUTOTEST_ROOT}/${_jj}.lyx")
 101   configure_file("${AUTOTEST_ROOT}/${_jj}.lyx" "${WORKDIR}/../${_jj}.lyx" COPYONLY)
 102 endif()
 103 execute_process(
 104   COMMAND python ${KEYTEST}
 105   RESULT_VARIABLE KEYTEST_RES)
 106 if(KEYTEST_RES)
 107   message(FATAL_ERROR "KEYTEST failed: KEYTEST_RES=${KEYTEST_RES}")
 108 endif()
 109