development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|lyx22x|xhtml
  11 # extension = 16.lyx|21.lyx|22.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR} \
  27 #       -DIgnoreErrorMessage=(ON/OFF) \
  28 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE} \
  29 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE} \
  30 #       -DENCODING=xxx \
  31 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  32 #
  33
  34 message(STATUS "IgnoreErrorMessage = \"${IgnoreErrorMessage}\"")
  35 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  36 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  37 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  38 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  39 set(_ft ${fonttype})
  40 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  41 message(STATUS "using fonttype = ${_ft}")
  42 if(NOT ENCODING)
  43   set(ENCODING "default")
  44 endif()
  45 if(ENCODING STREQUAL "default")
  46   set(_enc)
  47 else()
  48   set(_enc "_${ENCODING}")
  49 endif()
  50 if(format MATCHES "dvi|pdf")
  51   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  52   message(STATUS "Converting with perl ${Perl_Script}")
  53   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}${_enc}.lyx")
  54   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  55   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  56   if(NOT "${ENCODING}" STREQUAL "default")
  57     # message(STATUS "ENCODING = ${ENCODING}")
  58   endif()
  59   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${ENCODING} ${LanguageFile}
  60     RESULT_VARIABLE _err)
  61   string(COMPARE EQUAL  ${_err} 0 _erg)
  62   if(NOT _erg)
  63     message(FATAL_ERROR "Export failed while converting")
  64   endif()
  65   set(result_file_name ${file}_${_ft}.${extension})
  66 else()
  67   message(STATUS "Not converting")
  68   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  69   if(extension MATCHES "\\.lyx$")
  70     # Font-type not relevant for lyx16/lyx21 exports
  71     set(result_file_base ${file})
  72   else()
  73     set(result_file_name ${file}.${extension})
  74   endif()
  75 endif()
  76
  77 function(get_md5sum msource mresult mreserr)
  78   execute_process(
  79     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  80     OUTPUT_VARIABLE msource_md5sum_x
  81     RESULT_VARIABLE mres_err)
  82   if (NOT mres_err)
  83     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  84     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  85     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  86   else()
  87     set(${mresult} "xx" PARENT_SCOPE)
  88     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  89   endif()
  90   set(${mreserr} ${mres_err} PARENT_SCOPE)
  91 endfunction()
  92
  93 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  94 set(ENV{LANG} "en_US.UTF-8") # to get all error-messages in english
  95 #set(ENV{LC_ALL} "C")
  96 if (extension MATCHES "\\.lyx$")
  97   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  98   get_md5sum(LYX_SOURCE source_md5sum _err)
  99   foreach(_lv RANGE 1 5)
 100     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
 101     set(result_file_name "${result_file_base}.lyx")
 102     message(STATUS "check structures of ${LYX_SOURCE}")
 103     execute_process(
 104       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
 105       RESULT_VARIABLE _err)
 106     if(_err)
 107       break()
 108     endif()
 109     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
 110     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 111     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
 112     execute_process(
 113       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 114       RESULT_VARIABLE _err
 115       ERROR_VARIABLE lyxerr)
 116     if(_err)
 117       break()
 118     elseif(NOT EXISTS "${result_file_name}")
 119       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 120       set(_err -1)
 121       break()
 122     else()
 123       message(STATUS "Expected result file \"${result_file_name}\" exists")
 124       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 125       if(_err)
 126         break()
 127       endif()
 128     endif()
 129     get_md5sum(result_file_name result_md5sum _err)
 130     if(_err)
 131       # Somehow the created file is not readable?
 132       break()
 133     endif()
 134     # Check if result file identical to source file
 135     if(result_md5sum STREQUAL ${source_md5sum})
 136       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 137       break()
 138     endif()
 139     set(source_md5sum ${result_md5sum})
 140     set(LYX_SOURCE ${result_file_name})
 141   endforeach()
 142 else()
 143   if ($ENV{LYX_DEBUG_LATEX})
 144     set(LyXExtraParams -dbg latex)
 145   else()
 146     set(LyXExtraParams)
 147   endif()
 148   if(IgnoreErrorMessage)
 149     foreach (_em ${IgnoreErrorMessage})
 150       list(APPEND LyXExtraParams --ignore-error-message ${_em})
 151     endforeach()
 152   endif()
 153   string(REGEX REPLACE ";" " " _LyXExtraParams "${LyXExtraParams}")
 154   message(STATUS "Executing ${lyx} ${_LyXExtraParams} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 155   file(REMOVE ${result_file_name})
 156   execute_process(
 157     COMMAND ${lyx} ${LyXExtraParams} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 158     RESULT_VARIABLE _err)
 159
 160   #check if result file created
 161   if (NOT _err)
 162     if (NOT EXISTS "${result_file_name}")
 163       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 164       set(_err -1)
 165     else()
 166       message(STATUS "Expected result file \"${result_file_name}\" exists")
 167       if (format MATCHES "xhtml")
 168         if (XMLLINT_EXECUTABLE)
 169           message(STATUS "Calling: ${XMLLINT_EXECUTABLE} --sax --html --valid")
 170           # check the created xhtml file
 171           execute_process(
 172             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 173             OUTPUT_VARIABLE xmlout
 174             ERROR_VARIABLE xmlerr
 175             RESULT_VARIABLE _err)
 176           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 177           if (NOT _err)
 178             # check if sax-parser output contains error messages
 179             message(STATUS "Check the output: ${PERL_EXECUTABLE} ${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl")
 180             execute_process(
 181               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 182               OUTPUT_VARIABLE xmlout
 183               RESULT_VARIABLE _err)
 184           endif()
 185           if (NOT _err)
 186             if (NOT "${xmlout}" STREQUAL "")
 187               message(STATUS "${xmlout}")
 188               set(_err -1)
 189             endif()
 190           endif()
 191         endif()
 192       endif()
 193     endif()
 194   endif()
 195 endif()
 196
 197 if(inverted)
 198   string(COMPARE EQUAL  ${_err} 0 _erg)
 199 else()
 200   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 201 endif()
 202 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 203 if(_erg)
 204   message(STATUS "Exporting ${file}.lyx to ${format}")
 205   message(FATAL_ERROR "Export failed")
 206 endif()