development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|xhtml
  11 # extension = 16.lyx|21.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -Dfile=xxx \
  24 #       -Dinverted=[01] \
  25 #       -DTOP_SRC_DIR=${TOP_SRC_DIR}
  26 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
  27 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  28 #
  29
  30 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  31 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  32 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  33 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  34 set(_ft ${fonttype})
  35 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  36 message(STATUS "using fonttype = ${_ft}")
  37 if(format MATCHES "dvi|pdf")
  38   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  39   message(STATUS "Converting with perl ${Perl_Script}")
  40   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}.lyx")
  41   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  42   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  43   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${LanguageFile}
  44     RESULT_VARIABLE _err)
  45   string(COMPARE EQUAL  ${_err} 0 _erg)
  46   if(NOT _erg)
  47     message(FATAL_ERROR "Export failed while converting")
  48   endif()
  49   set(result_file_name ${file}_${_ft}.${extension})
  50 else()
  51   message(STATUS "Not converting")
  52   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  53   # Font-type not relevant for lyx16/lyx21 exports
  54   set(result_file_name ${file}.${extension})
  55   set(result_file_name2 ${file}.${extension2})
  56 endif()
  57
  58 message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
  59 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  60 execute_process(COMMAND ${CMAKE_COMMAND} -E remove ${result_file_name} ${result_file_name}.emergency)
  61 execute_process(
  62   COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
  63   RESULT_VARIABLE _err)
  64
  65 #check if result file created
  66 if (NOT _err)
  67   if (NOT EXISTS "${result_file_name}")
  68     message(STATUS "Expected result file \"${result_file_name}\" does not exist")
  69     set(_err -1)
  70   else()
  71     message(STATUS "Expected result file \"${result_file_name}\" exists")
  72   endif()
  73 endif()
  74
  75 include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  76 # If no error, and extension matches '\.lyx$', try to load the created lyx file
  77 if (NOT _err)
  78   if (result_file_name MATCHES "\\.lyx$")
  79     set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  80     set(ENV{LANG} "en") # to get all error-messages in english
  81     message(STATUS "check structures of ${result_file_name}")
  82     execute_process(
  83       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
  84       RESULT_VARIABLE _err
  85       ERROR_VARIABLE lyxerr)
  86     if (NOT _err)
  87       message(STATUS "check load of ${result_file_name}")
  88       execute_process(
  89         COMMAND ${lyx} -batch -userdir "${LYX_TESTS_USERDIR}" ${result_file_name}
  90         RESULT_VARIABLE _err
  91         ERROR_VARIABLE lyxerr)
  92       if (NOT _err)
  93         CheckLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
  94         if (NOT _err)
  95           execute_process(
  96             COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name2} ${result_file_name}
  97             RESULT_VARIABLE _err
  98             ERROR_VARIABLE lyxerr)
  99           if (NOT _err)
 100             message(STATUS "check load of ${result_file_name2}")
 101             CheckLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 102           endif()
 103         endif()
 104       endif()
 105     endif()
 106   else()
 107     message(STATUS "\"${result_file_name}\" is not a lyx file, do not check load")
 108   endif()
 109 endif()
 110
 111 if(inverted)
 112   string(COMPARE EQUAL  ${_err} 0 _erg)
 113 else()
 114   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 115 endif()
 116 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 117 if(_erg)
 118   message(STATUS "Exporting ${file}.lyx to ${format}")
 119   message(FATAL_ERROR "Export failed")
 120 endif()