development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|lyx22x|xhtml
  11 # extension = 16.lyx|21.lyx|22.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR} \
  27 #       -DIgnoreErrorMessage=(ON/OFF) \
  28 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE} \
  29 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE} \
  30 #       -DENCODING=xxx \
  31 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  32 #
  33
  34 message(STATUS "IgnoreErrorMessage = \"${IgnoreErrorMessage}\"")
  35 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  36 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  37 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  38 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  39 set(_ft ${fonttype})
  40 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  41 message(STATUS "using fonttype = ${_ft}")
  42 if(NOT ENCODING)
  43   set(ENCODING "default")
  44 endif()
  45 if(ENCODING STREQUAL "default")
  46   set(_enc)
  47 else()
  48   set(_enc "_${ENCODING}")
  49 endif()
  50 if(format MATCHES "dvi|pdf")
  51   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  52   message(STATUS "Converting with perl ${Perl_Script}")
  53   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}${_enc}.lyx")
  54   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  55   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  56   if(NOT "${ENCODING}" STREQUAL "default")
  57     # message(STATUS "ENCODING = ${ENCODING}")
  58   endif()
  59   message(STATUS "Executing ${PERL_EXECUTABLE} \"${Perl_Script}\" \"${LYX_ROOT}/${file}.lyx\" \"${LYX_SOURCE}\" ${format} ${_ft} ${ENCODING} ${LanguageFile}")
  60   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${ENCODING} ${LanguageFile}
  61     RESULT_VARIABLE _err)
  62   string(COMPARE EQUAL  ${_err} 0 _erg)
  63   if(NOT _erg)
  64     message(FATAL_ERROR "Export failed while converting")
  65   endif()
  66   set(result_file_name ${file}_${_ft}.${extension})
  67 else()
  68   message(STATUS "Converting with perl ${Perl_Script}")
  69   set(LYX_SOURCE "${TempDir}/${file}.lyx")
  70   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  71   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  72   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} "default" "default" ${LanguageFile}
  73     RESULT_VARIABLE _err)
  74   string(COMPARE EQUAL  ${_err} 0 _erg)
  75   if(NOT _erg)
  76     message(FATAL_ERROR "Export failed while converting")
  77     endif()
  78   if(extension MATCHES "\\.lyx$")
  79     # Font-type not relevant for lyx16/lyx21 exports
  80     set(result_file_base "${TempDir}/${file}")
  81   else()
  82     set(result_file_name ${file}.${extension})
  83   endif()
  84 endif()
  85
  86 function(get_md5sum msource mresult mreserr)
  87   execute_process(
  88     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  89     OUTPUT_VARIABLE msource_md5sum_x
  90     RESULT_VARIABLE mres_err)
  91   if (NOT mres_err)
  92     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  93     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  94     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  95   else()
  96     set(${mresult} "xx" PARENT_SCOPE)
  97     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  98   endif()
  99   set(${mreserr} ${mres_err} PARENT_SCOPE)
 100 endfunction()
 101
 102 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
 103 set(ENV{LANG} "en_US.UTF-8") # to get all error-messages in english
 104 #set(ENV{LC_ALL} "C")
 105 if (extension MATCHES "\\.lyx$")
 106   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
 107   get_md5sum(LYX_SOURCE source_md5sum _err)
 108   foreach(_lv RANGE 1 20)
 109     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
 110     set(result_file_name "${result_file_base}.lyx")
 111     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
 112     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 113     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
 114     execute_process(
 115       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 116       RESULT_VARIABLE _err
 117       ERROR_VARIABLE lyxerr)
 118     if(_err)
 119       break()
 120     elseif(NOT EXISTS "${result_file_name}")
 121       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 122       set(_err -1)
 123       break()
 124     else()
 125       message(STATUS "Expected result file \"${result_file_name}\" exists")
 126       execute_process(
 127         COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
 128         RESULT_VARIABLE _err)
 129       if(_err)
 130         break()
 131       endif()
 132       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 133       if(_err)
 134         break()
 135       endif()
 136     endif()
 137     get_md5sum(result_file_name result_md5sum _err)
 138     if(_err)
 139       # Somehow the created file is not readable?
 140       break()
 141     endif()
 142     # Check if result file identical to source file
 143     if(result_md5sum STREQUAL ${source_md5sum})
 144       if (format MATCHES "lyx(1[0-9]|2[01])x")
 145         # Do not compile, missing \origin statement prevents inclusion of
 146         # files with relative path
 147         message(STATUS "Not exporting due to missing \\origin statement")
 148         break()
 149       endif()
 150       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 151       message(STATUS "Now try to export the lyx2lyx created file")
 152       message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E default \"${result_file_name}.default\" \"${result_file_name}\"")
 153       execute_process(
 154         COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E default "${result_file_name}.default" "${result_file_name}"
 155         RESULT_VARIABLE _err
 156         ERROR_VARIABLE lyxerr)
 157       break()
 158     else()
 159       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are still different")
 160       if (_lv GREATER 10)
 161         set(_err 1)
 162         message(STATUS "Possible endless loop encountered")
 163         break()
 164       endif()
 165     endif()
 166     set(source_md5sum ${result_md5sum})
 167     set(LYX_SOURCE ${result_file_name})
 168   endforeach()
 169 else()
 170   if ($ENV{LYX_DEBUG_LATEX})
 171     set(LyXExtraParams -dbg latex)
 172   else()
 173     set(LyXExtraParams)
 174   endif()
 175   if(IgnoreErrorMessage)
 176     foreach (_em ${IgnoreErrorMessage})
 177       list(APPEND LyXExtraParams --ignore-error-message ${_em})
 178     endforeach()
 179   endif()
 180   string(REGEX REPLACE ";" " " _LyXExtraParams "${LyXExtraParams}")
 181   message(STATUS "Executing ${lyx} ${_LyXExtraParams} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 182   file(REMOVE ${result_file_name})
 183   execute_process(
 184     COMMAND ${lyx} ${LyXExtraParams} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 185     RESULT_VARIABLE _err)
 186
 187   #check if result file created
 188   if (NOT _err)
 189     if (NOT EXISTS "${result_file_name}")
 190       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 191       set(_err -1)
 192     else()
 193       message(STATUS "Expected result file \"${result_file_name}\" exists")
 194       if (format MATCHES "xhtml")
 195         if (XMLLINT_EXECUTABLE)
 196           message(STATUS "Calling: ${XMLLINT_EXECUTABLE} --sax --html --valid")
 197           # check the created xhtml file
 198           execute_process(
 199             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 200             OUTPUT_VARIABLE xmlout
 201             ERROR_VARIABLE xmlerr
 202             RESULT_VARIABLE _err)
 203           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 204           if (NOT _err)
 205             # check if sax-parser output contains error messages
 206             message(STATUS "Check the output: ${PERL_EXECUTABLE} ${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl")
 207             execute_process(
 208               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 209               OUTPUT_VARIABLE xmlout
 210               RESULT_VARIABLE _err)
 211           endif()
 212           if (NOT _err)
 213             if (NOT "${xmlout}" STREQUAL "")
 214               message(STATUS "${xmlout}")
 215               set(_err -1)
 216             endif()
 217           endif()
 218         endif()
 219       endif()
 220     endif()
 221   endif()
 222 endif()
 223
 224 if(inverted)
 225   string(COMPARE EQUAL  ${_err} 0 _erg)
 226 else()
 227   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 228 endif()
 229 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 230 if(_erg)
 231   message(STATUS "Exporting ${file}.lyx to ${format}")
 232   message(FATAL_ERROR "Export failed")
 233 endif()