development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|xhtml
  11 # extension = 16.lyx|21.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -Dfile=xxx \
  24 #       -Dinverted=[01] \
  25 #       -DTOP_SRC_DIR=${TOP_SRC_DIR}
  26 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
  27 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  28 #
  29
  30 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  31 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  32 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  33 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  34 set(_ft ${fonttype})
  35 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  36 message(STATUS "using fonttype = ${_ft}")
  37 if(format MATCHES "dvi|pdf")
  38   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  39   message(STATUS "Converting with perl ${Perl_Script}")
  40   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}.lyx")
  41   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  42   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  43   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${LanguageFile}
  44     RESULT_VARIABLE _err)
  45   string(COMPARE EQUAL  ${_err} 0 _erg)
  46   if(NOT _erg)
  47     message(FATAL_ERROR "Export failed while converting")
  48   endif()
  49   set(result_file_name ${file}_${_ft}.${extension})
  50 else()
  51   message(STATUS "Not converting")
  52   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  53   # Font-type not relevant for lyx16/lyx21 exports
  54   set(result_file_name ${file}.${extension})
  55 endif()
  56
  57 message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
  58 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  59 execute_process(COMMAND ${CMAKE_COMMAND} -E remove ${result_file_name} ${result_file_name}.emergency)
  60 execute_process(
  61   COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
  62   RESULT_VARIABLE _err)
  63
  64 #check if result file created
  65 if (NOT _err)
  66   if (NOT EXISTS "${result_file_name}")
  67     message(STATUS "Expected result file \"${result_file_name}\" does not exist")
  68     set(_err -1)
  69   else()
  70     message(STATUS "Expected result file \"${result_file_name}\" exists")
  71   endif()
  72 endif()
  73
  74 include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  75 # If no error, and extension matches '\.lyx$', try to load the created lyx file
  76 if (NOT _err)
  77   if (result_file_name MATCHES "\\.lyx$")
  78     message(STATUS "check load of ${result_file_name}")
  79     set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  80     set(ENV{LANG} "en") # to get all error-messages in english
  81     execute_process(
  82       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
  83       RESULT_VARIABLE _err
  84       ERROR_VARIABLE lyxerr)
  85     if (NOT _err)
  86       execute_process(
  87         COMMAND ${lyx} -batch -userdir "${LYX_TESTS_USERDIR}" ${result_file_name}
  88         RESULT_VARIABLE _err
  89         ERROR_VARIABLE lyxerr)
  90     endif()
  91     if (NOT _err)
  92       CheckLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
  93     endif()
  94   else()
  95     message(STATUS "\"${result_file_name}\" is not a lyx file, do not check load")
  96   endif()
  97 endif()
  98
  99 if(inverted)
 100   string(COMPARE EQUAL  ${_err} 0 _erg)
 101 else()
 102   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 103 endif()
 104 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 105 if(_erg)
 106   message(STATUS "Exporting ${file}.lyx to ${format}")
 107   message(FATAL_ERROR "Export failed")
 108 endif()