development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|xhtml
  11 # extension = 16.lyx|21.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -Dfile=xxx \
  24 #       -Dinverted=[01] \
  25 #       -DTOP_SRC_DIR=${TOP_SRC_DIR}
  26 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
  27 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  28 #
  29
  30 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  31 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  32 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  33 set(_ft ${fonttype})
  34 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  35 message(STATUS "using fonttype = ${_ft}")
  36 if(format MATCHES "dvi|pdf")
  37   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  38   message(STATUS "Converting with perl ${Perl_Script}")
  39   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}.lyx")
  40   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  41   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  42   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${LanguageFile}
  43     RESULT_VARIABLE _err)
  44   string(COMPARE EQUAL  ${_err} 0 _erg)
  45   if(NOT _erg)
  46     message(FATAL_ERROR "Export failed while converting")
  47   endif()
  48   set(result_file_name ${file}_${_ft}.${extension})
  49 else()
  50   message(STATUS "Not converting")
  51   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  52   # Font-type not relevant for lyx16/lyx21 exports
  53   set(result_file_name ${file}.${extension})
  54 endif()
  55
  56 message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
  57 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  58 execute_process(COMMAND ${CMAKE_COMMAND} -E remove ${result_file_name} ${result_file_name}.emergency)
  59 execute_process(
  60   COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
  61   RESULT_VARIABLE _err)
  62
  63 #check if result file created
  64 if (NOT _err)
  65   if (NOT EXISTS "${result_file_name}")
  66     message(STATUS "Expected result file \"${result_file_name}\" does not exist")
  67     set(_err -1)
  68   else()
  69     message(STATUS "Expected result file \"${result_file_name}\" exists")
  70   endif()
  71 endif()
  72
  73 include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  74 # If no error, and extension matches '\.lyx$', try to load the created lyx file
  75 if (NOT _err)
  76   if (result_file_name MATCHES "\\.lyx$")
  77     message(STATUS "check load of ${result_file_name}")
  78     set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  79     set(ENV{LANG} "en") # to get all error-messages in english
  80     execute_process(
  81       COMMAND ${lyx} -batch -userdir "${LYX_TESTS_USERDIR}" ${result_file_name}
  82       RESULT_VARIABLE _err
  83       ERROR_VARIABLE lyxerr)
  84     if (NOT _err)
  85       CheckLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
  86     endif()
  87   else()
  88     message(STATUS "\"${result_file_name}\" is not a lyx file, do not check load")
  89   endif()
  90 endif()
  91
  92 if(inverted)
  93   string(COMPARE EQUAL  ${_err} 0 _erg)
  94 else()
  95   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
  96 endif()
  97 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
  98 if(_erg)
  99   message(STATUS "Exporting ${file}.lyx to ${format}")
 100   message(FATAL_ERROR "Export failed")
 101 endif()