development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx20x|lyx21x|lyx22x|xhtml
  11 # extension = 16.lyx|20.lyx|21.lyx|22.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR} \
  27 #       -DIgnoreErrorMessage=(ON/OFF) \
  28 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE} \
  29 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE} \
  30 #       -DENCODING=xxx \
  31 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  32 #
  33
  34 set(_TestResultMessage "")
  35 message(STATUS "IgnoreErrorMessage = \"${IgnoreErrorMessage}\"")
  36 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  37 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  38 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  39 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  40 set(_ft ${fonttype})
  41 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  42 message(STATUS "using fonttype = ${_ft}")
  43 if(NOT ENCODING)
  44   set(ENCODING "default")
  45 endif()
  46 if(ENCODING STREQUAL "default")
  47   set(_enc)
  48 else()
  49   set(_enc "_${ENCODING}")
  50 endif()
  51 if(format MATCHES "dvi|pdf")
  52   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  53   message(STATUS "Converting with perl ${Perl_Script}")
  54   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}${_enc}.lyx")
  55   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  56   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  57   if(NOT "${ENCODING}" STREQUAL "default")
  58     # message(STATUS "ENCODING = ${ENCODING}")
  59   endif()
  60   message(STATUS "Executing ${PERL_EXECUTABLE} \"${Perl_Script}\" \"${LYX_ROOT}/${file}.lyx\" \"${LYX_SOURCE}\" ${format} ${_ft} ${ENCODING} ${LanguageFile}")
  61   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${ENCODING} ${LanguageFile}
  62     RESULT_VARIABLE _err)
  63   string(COMPARE EQUAL  ${_err} 0 _erg)
  64   if(NOT _erg)
  65     message(FATAL_ERROR "Export failed while converting")
  66   endif()
  67   set(result_file_name ${file}_${_ft}.${extension})
  68 else()
  69   message(STATUS "Converting with perl ${Perl_Script}")
  70   set(LYX_SOURCE "${TempDir}/${file}.lyx")
  71   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  72   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  73   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} "dontChange" "default" ${LanguageFile}
  74     RESULT_VARIABLE _err)
  75   string(COMPARE EQUAL  ${_err} 0 _erg)
  76   if(NOT _erg)
  77     message(FATAL_ERROR "Export failed while converting")
  78     endif()
  79   if(extension MATCHES "\\.lyx$")
  80     # Font-type not relevant for lyx16/lyx2[0123] exports
  81     set(result_file_base "${TempDir}/${file}")
  82   else()
  83     set(result_file_name ${file}.${extension})
  84   endif()
  85 endif()
  86
  87 function(get_md5sum msource mresult mreserr)
  88   execute_process(
  89     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  90     OUTPUT_VARIABLE msource_md5sum_x
  91     RESULT_VARIABLE mres_err)
  92   if (NOT mres_err)
  93     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  94     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  95     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  96   else()
  97     set(${mresult} "xx" PARENT_SCOPE)
  98     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  99   endif()
 100   set(${mreserr} ${mres_err} PARENT_SCOPE)
 101 endfunction()
 102
 103 macro(Summary _err _msg)
 104   if (${_err})
 105     list(APPEND _TestResultMessage "Error: ${_msg}")
 106   else()
 107     list(APPEND _TestResultMessage "OK: ${_msg}")
 108   endif()
 109 endmacro()
 110
 111 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
 112 set(ENV{LANG} "en_US.UTF-8") # to get all error-messages in english
 113 #set(ENV{LC_ALL} "C")
 114 if (extension MATCHES "\\.lyx$")
 115   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
 116   get_md5sum(LYX_SOURCE source_md5sum _err)
 117   foreach(_lv RANGE 1 20)
 118     set(used_tex_file "${result_file_base}.tex")
 119     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
 120     set(result_file_name "${result_file_base}.lyx")
 121     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
 122     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 123     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
 124     execute_process(
 125       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 126       RESULT_VARIABLE _err
 127       ERROR_VARIABLE lyxerr)
 128     Summary(_err "Converting \"${LYX_SOURCE}\" to format ${format}")
 129     if(_err)
 130       break()
 131     else()
 132       if(NOT EXISTS "${result_file_name}")
 133         set(_err -1)
 134         Summary(_err "Expected result file \"${result_file_name}\" does not exist")
 135         break()
 136       else()
 137         message(STATUS "Expected result file \"${result_file_name}\" exists")
 138         execute_process(
 139           COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${result_file_name}"
 140           RESULT_VARIABLE _err)
 141         Summary(_err "Structure of the intermediate file \"${result_file_name}\"")
 142         if(_err)
 143           break()
 144         endif()
 145         checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 146         Summary(_err "Examination of error/warning messages of the conversion of \"${LYX_SOURCE}\" to format ${format}")
 147         if(_err)
 148           break()
 149         endif()
 150         message(STATUS "Create the corresponding .tex file \"${used_tex_file}\"")
 151         execute_process(
 152           COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E pdflatex ${used_tex_file} "${LYX_SOURCE}"
 153           RESULT_VARIABLE _errx)
 154       endif()
 155     endif()
 156     get_md5sum(result_file_name result_md5sum _err)
 157     Summary(_err "Getting md5sum of \"${result_file_name}\"")
 158     if(_err)
 159       # Somehow the created file is not readable?
 160       break()
 161     endif()
 162     # Check if result file identical to source file
 163     if(result_md5sum STREQUAL ${source_md5sum})
 164       if (format MATCHES "lyx(1[0-9]|2[01])x")
 165         # Do not compile, missing \origin statement prevents inclusion of
 166         # files with relative path
 167         message(STATUS "Not exporting due to missing \\origin statement")
 168         break()
 169       endif()
 170       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 171       message(STATUS "Now try to export the lyx2lyx created file")
 172       message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E default \"${result_file_name}.default\" \"${result_file_name}\"")
 173       execute_process(
 174         COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E default "${result_file_name}.default" "${result_file_name}"
 175         RESULT_VARIABLE _err
 176         ERROR_VARIABLE lyxerr)
 177       Summary(_err "Test-compilation of \"${result_file_name}\" to format default")
 178       break()
 179     else()
 180       list(APPEND _TestResultMessage "Warning: \"${LYX_SOURCE}\" and \"${result_file_name}\" differ")
 181       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are still different")
 182       if (_lv GREATER 10)
 183         set(_err 1)
 184         message(STATUS "Possible endless loop encountered")
 185         Summary(_err "Test-Loop exceeded the count of 10, Possible endless loop")
 186         break()
 187       endif()
 188     endif()
 189     set(source_md5sum ${result_md5sum})
 190     set(LYX_SOURCE ${result_file_name})
 191   endforeach()
 192 else()
 193   if ($ENV{LYX_DEBUG_LATEX})
 194     set(LyXExtraParams -dbg latex)
 195   else()
 196     set(LyXExtraParams)
 197   endif()
 198   if(IgnoreErrorMessage)
 199     foreach (_em ${IgnoreErrorMessage})
 200       list(APPEND LyXExtraParams --ignore-error-message ${_em})
 201     endforeach()
 202   endif()
 203   string(REGEX REPLACE ";" " " _LyXExtraParams "${LyXExtraParams}")
 204   message(STATUS "Executing ${lyx} ${_LyXExtraParams} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 205   file(REMOVE ${result_file_name})
 206   execute_process(
 207     COMMAND ${lyx} ${LyXExtraParams} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 208     RESULT_VARIABLE _err)
 209   Summary(_err "Exporting \"${LYX_SOURCE}\" to format ${format}")
 210   if (NOT _err)
 211     #check if result file created
 212     if (NOT EXISTS "${result_file_name}")
 213       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 214       set(_err -1)
 215       Summary(_err "Expected result file \"${result_file_name}\" does not exists")
 216     else()
 217       message(STATUS "Expected result file \"${result_file_name}\" exists")
 218       if (format MATCHES "xhtml")
 219         if (XMLLINT_EXECUTABLE)
 220           message(STATUS "Calling: ${XMLLINT_EXECUTABLE} --sax --html --valid")
 221           # check the created xhtml file
 222           execute_process(
 223             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 224             OUTPUT_VARIABLE xmlout
 225             ERROR_VARIABLE xmlerr
 226             RESULT_VARIABLE _err)
 227           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 228           Summary(_err "Checking \"${result_file_name}\" with ${XMLLINT_EXECUTABLE}")
 229           if (NOT _err)
 230             # check if sax-parser output contains error messages
 231             message(STATUS "Check the output: ${PERL_EXECUTABLE} ${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl")
 232             execute_process(
 233               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 234               OUTPUT_VARIABLE xmlout
 235               RESULT_VARIABLE _err)
 236             Summary(_err "Parse messages of ${XMLLINT_EXECUTABLE} for errors")
 237           endif()
 238           if (NOT _err)
 239             if (NOT "${xmlout}" STREQUAL "")
 240               message(STATUS "${xmlout}")
 241               set(_err -1)
 242               Summary(_err "Non empty output of \"${XMLLINT_EXECUTABLE}\"")
 243             endif()
 244           endif()
 245         endif()
 246       endif()
 247     endif()
 248   endif()
 249 endif()
 250
 251 if(inverted)
 252   string(COMPARE EQUAL  ${_err} 0 _erg)
 253 else()
 254   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 255 endif()
 256 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 257 if(_TestResultMessage)
 258   message(STATUS "Msg Summary:")
 259   foreach(_l ${_TestResultMessage})
 260     message(STATUS "\t${_l}")
 261   endforeach()
 262 endif()
 263 if(_erg)
 264   message(STATUS "Exporting ${file}.lyx to ${format}")
 265   message(FATAL_ERROR "Export failed")
 266 endif()