development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|xhtml
  11 # extension = 16.lyx|21.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR}
  27 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
  28 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE}
  29 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  30 #
  31
  32 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  33 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  34 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  35 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  36 set(_ft ${fonttype})
  37 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  38 message(STATUS "using fonttype = ${_ft}")
  39 if(format MATCHES "dvi|pdf")
  40   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  41   message(STATUS "Converting with perl ${Perl_Script}")
  42   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}.lyx")
  43   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  44   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  45   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${LanguageFile}
  46     RESULT_VARIABLE _err)
  47   string(COMPARE EQUAL  ${_err} 0 _erg)
  48   if(NOT _erg)
  49     message(FATAL_ERROR "Export failed while converting")
  50   endif()
  51   set(result_file_name ${file}_${_ft}.${extension})
  52 else()
  53   message(STATUS "Not converting")
  54   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  55   if(extension MATCHES "\\.lyx$")
  56     # Font-type not relevant for lyx16/lyx21 exports
  57     set(result_file_base ${file})
  58   else()
  59     set(result_file_name ${file}.${extension})
  60   endif()
  61 endif()
  62
  63 function(get_md5sum msource mresult mreserr)
  64   execute_process(
  65     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  66     OUTPUT_VARIABLE msource_md5sum_x
  67     RESULT_VARIABLE mres_err)
  68   if (NOT mres_err)
  69     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  70     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  71     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  72   else()
  73     set(${mresult} "xx" PARENT_SCOPE)
  74     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  75   endif()
  76   set(${mreserr} ${mres_err} PARENT_SCOPE)
  77 endfunction()
  78
  79 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  80 set(ENV{LANG} "en") # to get all error-messages in english
  81 set(ENV{LC_ALL} "C")
  82 if (extension MATCHES "\\.lyx$")
  83   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  84   get_md5sum(LYX_SOURCE source_md5sum _err)
  85   foreach(_lv RANGE 1 5)
  86     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
  87     set(result_file_name "${result_file_base}.lyx")
  88     message(STATUS "check structures of ${LYX_SOURCE}")
  89     execute_process(
  90       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
  91       RESULT_VARIABLE _err)
  92     if(_err)
  93       break()
  94     endif()
  95     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
  96     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
  97     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
  98     execute_process(
  99       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 100       RESULT_VARIABLE _err
 101       ERROR_VARIABLE lyxerr)
 102     if(_err)
 103       break()
 104     elseif(NOT EXISTS "${result_file_name}")
 105       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 106       set(_err -1)
 107       break()
 108     else()
 109       message(STATUS "Expected result file \"${result_file_name}\" exists")
 110       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 111       if(_err)
 112         break()
 113       endif()
 114     endif()
 115     get_md5sum(result_file_name result_md5sum _err)
 116     if(_err)
 117       # Somehow the created file is not readable?
 118       break()
 119     endif()
 120     # Check if result file identical to source file
 121     if(result_md5sum STREQUAL ${source_md5sum})
 122       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 123       break()
 124     endif()
 125     set(source_md5sum ${result_md5sum})
 126     set(LYX_SOURCE ${result_file_name})
 127   endforeach()
 128 else()
 129   message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 130   file(REMOVE ${result_file_name})
 131   execute_process(
 132     COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 133     RESULT_VARIABLE _err)
 134
 135   #check if result file created
 136   if (NOT _err)
 137     if (NOT EXISTS "${result_file_name}")
 138       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 139       set(_err -1)
 140     else()
 141       message(STATUS "Expected result file \"${result_file_name}\" exists")
 142       if (format MATCHES "xhtml")
 143         if (XMLLINT_EXECUTABLE)
 144           # check the created xhtml file
 145           execute_process(
 146             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 147             OUTPUT_VARIABLE xmlout
 148             ERROR_VARIABLE xmlerr
 149             RESULT_VARIABLE _err)
 150           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 151           if (NOT _err)
 152             # check if sax-parser output contains error messages
 153             execute_process(
 154               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 155               OUTPUT_VARIABLE xmlout
 156               RESULT_VARIABLE _err)
 157           endif()
 158           if (NOT _err)
 159             if (NOT "${xmlout}" STREQUAL "")
 160               message(STATUS "${xmlout}")
 161               set(_err -1)
 162             endif()
 163           endif()
 164         endif()
 165       endif()
 166     endif()
 167   endif()
 168 endif()
 169
 170 if(inverted)
 171   string(COMPARE EQUAL  ${_err} 0 _erg)
 172 else()
 173   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 174 endif()
 175 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 176 if(_erg)
 177   message(STATUS "Exporting ${file}.lyx to ${format}")
 178   message(FATAL_ERROR "Export failed")
 179 endif()