development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|lyx22x|xhtml
  11 # extension = 16.lyx|21.lyx|22.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR} \
  27 #       -DIgnoreErrorMessage=(ON/OFF) \
  28 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE} \
  29 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE} \
  30 #       -DENCODING=xxx \
  31 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  32 #
  33
  34 message(STATUS "IgnoreErrorMessage = \"${IgnoreErrorMessage}\"")
  35 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  36 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  37 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  38 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  39 set(_ft ${fonttype})
  40 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  41 message(STATUS "using fonttype = ${_ft}")
  42 if(NOT ENCODING)
  43   set(ENCODING "default")
  44 endif()
  45 if(ENCODING STREQUAL "default")
  46   set(_enc)
  47 else()
  48   set(_enc "_${ENCODING}")
  49 endif()
  50 if(format MATCHES "dvi|pdf")
  51   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  52   message(STATUS "Converting with perl ${Perl_Script}")
  53   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}${_enc}.lyx")
  54   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  55   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  56   if(NOT "${ENCODING}" STREQUAL "default")
  57     # message(STATUS "ENCODING = ${ENCODING}")
  58   endif()
  59   message(STATUS "Executing ${PERL_EXECUTABLE} \"${Perl_Script}\" \"${LYX_ROOT}/${file}.lyx\" \"${LYX_SOURCE}\" ${format} ${_ft} ${ENCODING} ${LanguageFile}")
  60   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${ENCODING} ${LanguageFile}
  61     RESULT_VARIABLE _err)
  62   string(COMPARE EQUAL  ${_err} 0 _erg)
  63   if(NOT _erg)
  64     message(FATAL_ERROR "Export failed while converting")
  65   endif()
  66   set(result_file_name ${file}_${_ft}.${extension})
  67 else()
  68   message(STATUS "Not converting")
  69   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  70   if(extension MATCHES "\\.lyx$")
  71     # Font-type not relevant for lyx16/lyx21 exports
  72     set(result_file_base ${file})
  73   else()
  74     set(result_file_name ${file}.${extension})
  75   endif()
  76 endif()
  77
  78 function(get_md5sum msource mresult mreserr)
  79   execute_process(
  80     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  81     OUTPUT_VARIABLE msource_md5sum_x
  82     RESULT_VARIABLE mres_err)
  83   if (NOT mres_err)
  84     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  85     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  86     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  87   else()
  88     set(${mresult} "xx" PARENT_SCOPE)
  89     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  90   endif()
  91   set(${mreserr} ${mres_err} PARENT_SCOPE)
  92 endfunction()
  93
  94 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  95 set(ENV{LANG} "en_US.UTF-8") # to get all error-messages in english
  96 #set(ENV{LC_ALL} "C")
  97 if (extension MATCHES "\\.lyx$")
  98   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  99   get_md5sum(LYX_SOURCE source_md5sum _err)
 100   foreach(_lv RANGE 1 20)
 101     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
 102     set(result_file_name "${result_file_base}.lyx")
 103     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
 104     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 105     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
 106     execute_process(
 107       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 108       RESULT_VARIABLE _err
 109       ERROR_VARIABLE lyxerr)
 110     if(_err)
 111       break()
 112     elseif(NOT EXISTS "${result_file_name}")
 113       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 114       set(_err -1)
 115       break()
 116     else()
 117       message(STATUS "Expected result file \"${result_file_name}\" exists")
 118       execute_process(
 119         COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
 120         RESULT_VARIABLE _err)
 121       if(_err)
 122         break()
 123       endif()
 124       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 125       if(_err)
 126         break()
 127       endif()
 128     endif()
 129     get_md5sum(result_file_name result_md5sum _err)
 130     if(_err)
 131       # Somehow the created file is not readable?
 132       break()
 133     endif()
 134     # Check if result file identical to source file
 135     if(result_md5sum STREQUAL ${source_md5sum})
 136       if (format MATCHES "lyx(1[0-9]|2[01])x")
 137         # Do not compile, missing \origin statement prevents inclusion of
 138         # files with relative path
 139         message(STATUS "Not exporting due to missing \\origin statement")
 140         break()
 141       endif()
 142       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 143       message(STATUS "Now try to export the lyx2lyx created file")
 144       message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E default \"${result_file_name}.default\" \"${result_file_name}\"")
 145       execute_process(
 146         COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E default "${result_file_name}.default" "${result_file_name}"
 147         RESULT_VARIABLE _err
 148         ERROR_VARIABLE lyxerr)
 149       break()
 150     else()
 151       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are still different")
 152       if (_lv GREATER 10)
 153         set(_err 1)
 154         message(STATUS "Possible endless loop encountered")
 155         break()
 156       endif()
 157     endif()
 158     set(source_md5sum ${result_md5sum})
 159     set(LYX_SOURCE ${result_file_name})
 160   endforeach()
 161 else()
 162   if ($ENV{LYX_DEBUG_LATEX})
 163     set(LyXExtraParams -dbg latex)
 164   else()
 165     set(LyXExtraParams)
 166   endif()
 167   if(IgnoreErrorMessage)
 168     foreach (_em ${IgnoreErrorMessage})
 169       list(APPEND LyXExtraParams --ignore-error-message ${_em})
 170     endforeach()
 171   endif()
 172   string(REGEX REPLACE ";" " " _LyXExtraParams "${LyXExtraParams}")
 173   message(STATUS "Executing ${lyx} ${_LyXExtraParams} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 174   file(REMOVE ${result_file_name})
 175   execute_process(
 176     COMMAND ${lyx} ${LyXExtraParams} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 177     RESULT_VARIABLE _err)
 178
 179   #check if result file created
 180   if (NOT _err)
 181     if (NOT EXISTS "${result_file_name}")
 182       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 183       set(_err -1)
 184     else()
 185       message(STATUS "Expected result file \"${result_file_name}\" exists")
 186       if (format MATCHES "xhtml")
 187         if (XMLLINT_EXECUTABLE)
 188           message(STATUS "Calling: ${XMLLINT_EXECUTABLE} --sax --html --valid")
 189           # check the created xhtml file
 190           execute_process(
 191             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 192             OUTPUT_VARIABLE xmlout
 193             ERROR_VARIABLE xmlerr
 194             RESULT_VARIABLE _err)
 195           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 196           if (NOT _err)
 197             # check if sax-parser output contains error messages
 198             message(STATUS "Check the output: ${PERL_EXECUTABLE} ${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl")
 199             execute_process(
 200               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 201               OUTPUT_VARIABLE xmlout
 202               RESULT_VARIABLE _err)
 203           endif()
 204           if (NOT _err)
 205             if (NOT "${xmlout}" STREQUAL "")
 206               message(STATUS "${xmlout}")
 207               set(_err -1)
 208             endif()
 209           endif()
 210         endif()
 211       endif()
 212     endif()
 213   endif()
 214 endif()
 215
 216 if(inverted)
 217   string(COMPARE EQUAL  ${_err} 0 _erg)
 218 else()
 219   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 220 endif()
 221 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 222 if(_erg)
 223   message(STATUS "Exporting ${file}.lyx to ${format}")
 224   message(FATAL_ERROR "Export failed")
 225 endif()