development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|xhtml
  11 # extension = 16.lyx|21.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR}
  27 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
  28 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  29 #
  30
  31 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  32 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  33 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  34 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  35 set(_ft ${fonttype})
  36 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  37 message(STATUS "using fonttype = ${_ft}")
  38 if(format MATCHES "dvi|pdf")
  39   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  40   message(STATUS "Converting with perl ${Perl_Script}")
  41   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}.lyx")
  42   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  43   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  44   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${LanguageFile}
  45     RESULT_VARIABLE _err)
  46   string(COMPARE EQUAL  ${_err} 0 _erg)
  47   if(NOT _erg)
  48     message(FATAL_ERROR "Export failed while converting")
  49   endif()
  50   set(result_file_name ${file}_${_ft}.${extension})
  51 else()
  52   message(STATUS "Not converting")
  53   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  54   if(extension MATCHES "\\.lyx$")
  55     # Font-type not relevant for lyx16/lyx21 exports
  56     set(result_file_base ${file})
  57   else()
  58     set(result_file_name ${file}.${extension})
  59   endif()
  60 endif()
  61
  62 function(get_md5sum msource mresult mreserr)
  63   execute_process(
  64     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  65     OUTPUT_VARIABLE msource_md5sum_x
  66     RESULT_VARIABLE mres_err)
  67   if (NOT mres_err)
  68     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  69     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  70     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  71   else()
  72     set(${mresult} "xx" PARENT_SCOPE)
  73     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  74   endif()
  75   set(${mreserr} ${mres_err} PARENT_SCOPE)
  76 endfunction()
  77
  78 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  79 set(ENV{LANG} "en") # to get all error-messages in english
  80 set(ENV{LC_ALL} "C")
  81 if (extension MATCHES "\\.lyx$")
  82   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  83   get_md5sum(LYX_SOURCE source_md5sum _err)
  84   foreach(_lv RANGE 1 5)
  85     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
  86     set(result_file_name "${result_file_base}.lyx")
  87     message(STATUS "check structures of ${LYX_SOURCE}")
  88     execute_process(
  89       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
  90       RESULT_VARIABLE _err)
  91     if(_err)
  92       break()
  93     endif()
  94     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
  95     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
  96     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
  97     execute_process(
  98       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
  99       RESULT_VARIABLE _err
 100       ERROR_VARIABLE lyxerr)
 101     if(_err)
 102       break()
 103     elseif(NOT EXISTS "${result_file_name}")
 104       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 105       set(_err -1)
 106       break()
 107     else()
 108       message(STATUS "Expected result file \"${result_file_name}\" exists")
 109       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 110       if(_err)
 111         break()
 112       endif()
 113     endif()
 114     get_md5sum(result_file_name result_md5sum _err)
 115     if(_err)
 116       # Somehow the created file is not readable?
 117       break()
 118     endif()
 119     # Check if result file identical to source file
 120     if(result_md5sum STREQUAL ${source_md5sum})
 121       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 122       break()
 123     endif()
 124     set(source_md5sum ${result_md5sum})
 125     set(LYX_SOURCE ${result_file_name})
 126   endforeach()
 127 else()
 128   message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 129   file(REMOVE ${result_file_name})
 130   execute_process(
 131     COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 132     RESULT_VARIABLE _err)
 133
 134   #check if result file created
 135   if (NOT _err)
 136     if (NOT EXISTS "${result_file_name}")
 137       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 138       set(_err -1)
 139     else()
 140       message(STATUS "Expected result file \"${result_file_name}\" exists")
 141     endif()
 142   endif()
 143 endif()
 144
 145 if(inverted)
 146   string(COMPARE EQUAL  ${_err} 0 _erg)
 147 else()
 148   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 149 endif()
 150 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 151 if(_erg)
 152   message(STATUS "Exporting ${file}.lyx to ${format}")
 153   message(FATAL_ERROR "Export failed")
 154 endif()