development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|lyx22x|xhtml
  11 # extension = 16.lyx|21.lyx|22.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR} \
  27 #       -DIgnoreErrorMessage=(ON/OFF) \
  28 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE} \
  29 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE} \
  30 #       -DENCODING=xxx \
  31 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  32 #
  33
  34 message(STATUS "IgnoreErrorMessage = \"${IgnoreErrorMessage}\"")
  35 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  36 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  37 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  38 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  39 set(_ft ${fonttype})
  40 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  41 message(STATUS "using fonttype = ${_ft}")
  42 if(NOT ENCODING)
  43   set(ENCODING "default")
  44 endif()
  45 if(ENCODING STREQUAL "default")
  46   set(_enc)
  47 else()
  48   set(_enc "_${ENCODING}")
  49 endif()
  50 if(format MATCHES "dvi|pdf")
  51   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  52   message(STATUS "Converting with perl ${Perl_Script}")
  53   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}${_enc}.lyx")
  54   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  55   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  56   if(NOT "${ENCODING}" STREQUAL "default")
  57     # message(STATUS "ENCODING = ${ENCODING}")
  58   endif()
  59   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${ENCODING} ${LanguageFile}
  60     RESULT_VARIABLE _err)
  61   string(COMPARE EQUAL  ${_err} 0 _erg)
  62   if(NOT _erg)
  63     message(FATAL_ERROR "Export failed while converting")
  64   endif()
  65   set(result_file_name ${file}_${_ft}.${extension})
  66 else()
  67   message(STATUS "Converting with perl ${Perl_Script}")
  68   set(LYX_SOURCE "${TempDir}/${file}.lyx")
  69   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  70   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  71   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} "dontChange" "default" ${LanguageFile}
  72     RESULT_VARIABLE _err)
  73   string(COMPARE EQUAL  ${_err} 0 _erg)
  74   if(NOT _erg)
  75     message(FATAL_ERROR "Export failed while converting")
  76     endif()
  77   if(extension MATCHES "\\.lyx$")
  78     # Font-type not relevant for lyx16/lyx21 exports
  79     set(result_file_base "${TempDir}/${file}")
  80   else()
  81     set(result_file_name ${file}.${extension})
  82   endif()
  83 endif()
  84
  85 function(get_md5sum msource mresult mreserr)
  86   execute_process(
  87     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  88     OUTPUT_VARIABLE msource_md5sum_x
  89     RESULT_VARIABLE mres_err)
  90   if (NOT mres_err)
  91     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  92     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  93     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  94   else()
  95     set(${mresult} "xx" PARENT_SCOPE)
  96     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  97   endif()
  98   set(${mreserr} ${mres_err} PARENT_SCOPE)
  99 endfunction()
 100
 101 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
 102 set(ENV{LANG} "en_US.UTF-8") # to get all error-messages in english
 103 #set(ENV{LC_ALL} "C")
 104 if (extension MATCHES "\\.lyx$")
 105   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
 106   get_md5sum(LYX_SOURCE source_md5sum _err)
 107   foreach(_lv RANGE 1 5)
 108     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
 109     set(result_file_name "${result_file_base}.lyx")
 110     message(STATUS "check structures of ${LYX_SOURCE}")
 111     execute_process(
 112       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
 113       RESULT_VARIABLE _err)
 114     if(_err)
 115       break()
 116     endif()
 117     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
 118     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 119     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
 120     execute_process(
 121       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 122       RESULT_VARIABLE _err
 123       ERROR_VARIABLE lyxerr)
 124     if(_err)
 125       break()
 126     elseif(NOT EXISTS "${result_file_name}")
 127       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 128       set(_err -1)
 129       break()
 130     else()
 131       message(STATUS "Expected result file \"${result_file_name}\" exists")
 132       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 133       if(_err)
 134         break()
 135       endif()
 136     endif()
 137     get_md5sum(result_file_name result_md5sum _err)
 138     if(_err)
 139       # Somehow the created file is not readable?
 140       break()
 141     endif()
 142     # Check if result file identical to source file
 143     if(result_md5sum STREQUAL ${source_md5sum})
 144       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 145       break()
 146     endif()
 147     set(source_md5sum ${result_md5sum})
 148     set(LYX_SOURCE ${result_file_name})
 149   endforeach()
 150 else()
 151   if ($ENV{LYX_DEBUG_LATEX})
 152     set(LyXExtraParams -dbg latex)
 153   else()
 154     set(LyXExtraParams)
 155   endif()
 156   if(IgnoreErrorMessage)
 157     foreach (_em ${IgnoreErrorMessage})
 158       list(APPEND LyXExtraParams --ignore-error-message ${_em})
 159     endforeach()
 160   endif()
 161   string(REGEX REPLACE ";" " " _LyXExtraParams "${LyXExtraParams}")
 162   message(STATUS "Executing ${lyx} ${_LyXExtraParams} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 163   file(REMOVE ${result_file_name})
 164   execute_process(
 165     COMMAND ${lyx} ${LyXExtraParams} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 166     RESULT_VARIABLE _err)
 167
 168   #check if result file created
 169   if (NOT _err)
 170     if (NOT EXISTS "${result_file_name}")
 171       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 172       set(_err -1)
 173     else()
 174       message(STATUS "Expected result file \"${result_file_name}\" exists")
 175       if (format MATCHES "xhtml")
 176         if (XMLLINT_EXECUTABLE)
 177           message(STATUS "Calling: ${XMLLINT_EXECUTABLE} --sax --html --valid")
 178           # check the created xhtml file
 179           execute_process(
 180             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 181             OUTPUT_VARIABLE xmlout
 182             ERROR_VARIABLE xmlerr
 183             RESULT_VARIABLE _err)
 184           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 185           if (NOT _err)
 186             # check if sax-parser output contains error messages
 187             message(STATUS "Check the output: ${PERL_EXECUTABLE} ${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl")
 188             execute_process(
 189               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 190               OUTPUT_VARIABLE xmlout
 191               RESULT_VARIABLE _err)
 192           endif()
 193           if (NOT _err)
 194             if (NOT "${xmlout}" STREQUAL "")
 195               message(STATUS "${xmlout}")
 196               set(_err -1)
 197             endif()
 198           endif()
 199         endif()
 200       endif()
 201     endif()
 202   endif()
 203 endif()
 204
 205 if(inverted)
 206   string(COMPARE EQUAL  ${_err} 0 _erg)
 207 else()
 208   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 209 endif()
 210 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 211 if(_erg)
 212   message(STATUS "Exporting ${file}.lyx to ${format}")
 213   message(FATAL_ERROR "Export failed")
 214 endif()