development/autotests/export.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6 #
   7 # LYX_ROOT  = ${TOP_SRC_DIR}/lib/{doc,examples,templates}
   8 # LYX_USERDIR_VER = Name of environment variable for the user directory
   9 # lyx       =
  10 # format    = lyx16x|lyx21x|lyx22x|xhtml
  11 # extension = 16.lyx|21.lyx|22.lyx|xhtml
  12 # file      = xxx
  13 #
  14 # Script should be called like:
  15 # cmake -DLYX_ROOT=xxx \
  16 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  17 #       -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  18 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  19 #       -Dlyx=xxx \
  20 #       -Dformat=xxx \
  21 #       -Dfonttype=xxx \
  22 #       -Dextension=xxx \
  23 #       -DLYX_FORMAT_NUM=${_lyx_format_num} \
  24 #       -Dfile=xxx \
  25 #       -Dinverted=[01] \
  26 #       -DTOP_SRC_DIR=${TOP_SRC_DIR} \
  27 #       -DPERL_EXECUTABLE=${PERL_EXECUTABLE} \
  28 #       -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE} \
  29 #       -DENCODING=xxx \
  30 #       -P "${TOP_SRC_DIR}/development/autotests/export.cmake"
  31 #
  32
  33 set(Perl_Script "${TOP_SRC_DIR}/development/autotests/useSystemFonts.pl")
  34 set(Structure_Script "${TOP_SRC_DIR}/development/autotests/beginEndStructureCheck.pl")
  35 set(LanguageFile "${TOP_SRC_DIR}/lib/languages")
  36 set(GetTempDir "${TOP_SRC_DIR}/development/autotests/getTempDir.pl")
  37 set(_ft ${fonttype})
  38 execute_process(COMMAND ${PERL_EXECUTABLE} "${GetTempDir}" "${WORKDIR}" OUTPUT_VARIABLE TempDir)
  39 message(STATUS "using fonttype = ${_ft}")
  40 if(NOT ENCODING)
  41   set(ENCODING "default")
  42 endif()
  43 if(ENCODING STREQUAL "default")
  44   set(_enc)
  45 else()
  46   set(_enc "_${ENCODING}")
  47 endif()
  48 if(format MATCHES "dvi|pdf")
  49   message(STATUS "LYX_TESTS_USERDIR = ${LYX_TESTS_USERDIR}")
  50   message(STATUS "Converting with perl ${Perl_Script}")
  51   set(LYX_SOURCE "${TempDir}/${file}_${format}_${_ft}${_enc}.lyx")
  52   message(STATUS "Using source \"${LYX_ROOT}/${file}.lyx\"")
  53   message(STATUS "Using dest \"${LYX_SOURCE}\"")
  54   if(NOT "${ENCODING}" STREQUAL "default")
  55     # message(STATUS "ENCODING = ${ENCODING}")
  56   endif()
  57   execute_process(COMMAND ${PERL_EXECUTABLE} "${Perl_Script}" "${LYX_ROOT}/${file}.lyx" "${LYX_SOURCE}" ${format} ${_ft} ${ENCODING} ${LanguageFile}
  58     RESULT_VARIABLE _err)
  59   string(COMPARE EQUAL  ${_err} 0 _erg)
  60   if(NOT _erg)
  61     message(FATAL_ERROR "Export failed while converting")
  62   endif()
  63   set(result_file_name ${file}_${_ft}.${extension})
  64 else()
  65   message(STATUS "Not converting")
  66   set(LYX_SOURCE "${LYX_ROOT}/${file}.lyx")
  67   if(extension MATCHES "\\.lyx$")
  68     # Font-type not relevant for lyx16/lyx21 exports
  69     set(result_file_base ${file})
  70   else()
  71     set(result_file_name ${file}.${extension})
  72   endif()
  73 endif()
  74
  75 function(get_md5sum msource mresult mreserr)
  76   execute_process(
  77     COMMAND ${CMAKE_COMMAND} -E md5sum ${${msource}}
  78     OUTPUT_VARIABLE msource_md5sum_x
  79     RESULT_VARIABLE mres_err)
  80   if (NOT mres_err)
  81     string(REGEX REPLACE " .*" "" msource_md5sum ${msource_md5sum_x})
  82     set(${mresult} ${msource_md5sum} PARENT_SCOPE)
  83     message(STATUS "MD5SUM of \"${${msource}}\" is ${msource_md5sum}")
  84   else()
  85     set(${mresult} "xx" PARENT_SCOPE)
  86     message(STATUS "Error getting MD5SUM of \"${${msource}}\"")
  87   endif()
  88   set(${mreserr} ${mres_err} PARENT_SCOPE)
  89 endfunction()
  90
  91 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  92 set(ENV{LANG} "en") # to get all error-messages in english
  93 set(ENV{LC_ALL} "C")
  94 if (extension MATCHES "\\.lyx$")
  95   include(${TOP_SRC_DIR}/development/autotests/CheckLoadErrors.cmake)
  96   get_md5sum(LYX_SOURCE source_md5sum _err)
  97   foreach(_lv RANGE 1 5)
  98     set(result_file_base "${result_file_base}.${LYX_FORMAT_NUM}")
  99     set(result_file_name "${result_file_base}.lyx")
 100     message(STATUS "check structures of ${LYX_SOURCE}")
 101     execute_process(
 102       COMMAND ${PERL_EXECUTABLE} ${Structure_Script} "${WORKDIR}/${result_file_name}"
 103       RESULT_VARIABLE _err)
 104     if(_err)
 105       break()
 106     endif()
 107     file(REMOVE "${result_file_name}" "${result_file_name}.emergency" )
 108     message(STATUS "Executing ${lyx} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 109     message(STATUS "This implicitly checks load of ${LYX_SOURCE}")
 110     execute_process(
 111       COMMAND ${lyx} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 112       RESULT_VARIABLE _err
 113       ERROR_VARIABLE lyxerr)
 114     if(_err)
 115       break()
 116     elseif(NOT EXISTS "${result_file_name}")
 117       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 118       set(_err -1)
 119       break()
 120     else()
 121       message(STATUS "Expected result file \"${result_file_name}\" exists")
 122       checkLoadErrors(lyxerr "${TOP_SRC_DIR}/development/autotests" _err)
 123       if(_err)
 124         break()
 125       endif()
 126     endif()
 127     get_md5sum(result_file_name result_md5sum _err)
 128     if(_err)
 129       # Somehow the created file is not readable?
 130       break()
 131     endif()
 132     # Check if result file identical to source file
 133     if(result_md5sum STREQUAL ${source_md5sum})
 134       message(STATUS "Source(${LYX_SOURCE}) and dest(${result_file_name}) are equal")
 135       break()
 136     endif()
 137     set(source_md5sum ${result_md5sum})
 138     set(LYX_SOURCE ${result_file_name})
 139   endforeach()
 140 else()
 141   if ($ENV{LYX_DEBUG_LATEX})
 142     set(LatexDebugParam -dbg latex)
 143   else()
 144     set(LatexDebugParam)
 145   endif()
 146   message(STATUS "Executing ${lyx} ${LatexDebugParam} -userdir \"${LYX_TESTS_USERDIR}\" -E ${format} ${result_file_name} \"${LYX_SOURCE}\"")
 147   file(REMOVE ${result_file_name})
 148   execute_process(
 149     COMMAND ${lyx} ${LatexDebugParam} -userdir "${LYX_TESTS_USERDIR}" -E ${format} ${result_file_name} "${LYX_SOURCE}"
 150     RESULT_VARIABLE _err)
 151
 152   #check if result file created
 153   if (NOT _err)
 154     if (NOT EXISTS "${result_file_name}")
 155       message(STATUS "Expected result file \"${result_file_name}\" does not exist")
 156       set(_err -1)
 157     else()
 158       message(STATUS "Expected result file \"${result_file_name}\" exists")
 159       if (format MATCHES "xhtml")
 160         if (XMLLINT_EXECUTABLE)
 161           message(STATUS "Calling: ${XMLLINT_EXECUTABLE} --sax --html --valid")
 162           # check the created xhtml file
 163           execute_process(
 164             COMMAND ${XMLLINT_EXECUTABLE} --sax --html --valid  "${result_file_name}"
 165             OUTPUT_VARIABLE xmlout
 166             ERROR_VARIABLE xmlerr
 167             RESULT_VARIABLE _err)
 168           file(WRITE "${result_file_name}.sax_out" ${xmlout})
 169           if (NOT _err)
 170             # check if sax-parser output contains error messages
 171             message(STATUS "Check the output: ${PERL_EXECUTABLE} ${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl")
 172             execute_process(
 173               COMMAND ${PERL_EXECUTABLE} "${TOP_SRC_DIR}/development/autotests/examineXmllintOutput.pl" "${result_file_name}.sax_out"
 174               OUTPUT_VARIABLE xmlout
 175               RESULT_VARIABLE _err)
 176           endif()
 177           if (NOT _err)
 178             if (NOT "${xmlout}" STREQUAL "")
 179               message(STATUS "${xmlout}")
 180               set(_err -1)
 181             endif()
 182           endif()
 183         endif()
 184       endif()
 185     endif()
 186   endif()
 187 endif()
 188
 189 if(inverted)
 190   string(COMPARE EQUAL  ${_err} 0 _erg)
 191 else()
 192   string(COMPARE NOTEQUAL  ${_err} 0 _erg)
 193 endif()
 194 execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${TempDir}")
 195 if(_erg)
 196   message(STATUS "Exporting ${file}.lyx to ${format}")
 197   message(FATAL_ERROR "Export failed")
 198 endif()