development/autotests/check_load.cmake

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2013 Kornel Benko kornel@lyx.org
   5 # Copyright (c) 2013 Scott Kostyshak skotysh@lyx.org
   6 #
   7 #
   8 # LYXFILE  = xxx
   9 # lyx      =
  10 #
  11 # Script should be called like:
  12 # cmake -DWORKDIR=${BUILD_DIR}/autotests/out-home \
  13 #       -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR} \
  14 #       -DLYXFILE=xxx \
  15 #       -DLYX_USERDIR_VER=${LYX_USERDIR_VER} \
  16 #       -DPARAMS_DIR="${TOP_SRC_DIR}/development/autotests" \
  17 #       -P "${TOP_SRC_DIR}/development/autotests/check_load.cmake"
  18 #
  19
  20 message(STATUS "Executing ${lyx} -batch ${LYXFILE}")
  21 set(ENV{${LYX_USERDIR_VER}} "${LYX_TESTS_USERDIR}")
  22 set(ENV{LANG} "en") # to get all error-messages in english
  23
  24 execute_process(
  25   COMMAND ${lyx} -batch -userdir "${LYX_TESTS_USERDIR}" ${LYXFILE}
  26   RESULT_VARIABLE _err
  27   ERROR_VARIABLE lyxerr)
  28
  29 message(STATUS "Error code of lyx = ${_err}")
  30 string(COMPARE NOTEQUAL  ${_err} 0 _erg)
  31
  32 if(lyxerr)
  33   file(STRINGS "${PARAMS_DIR}/filterCheckWarnings" ignoreRegexp)
  34   # Split lyxerr into lines
  35   string(REGEX REPLACE "[\n]+" ";" foundErrors ${lyxerr})
  36   foreach(_l ${foundErrors})
  37     message(STATUS "Checking line: \"${_l}\"")
  38     set(found 0)
  39     foreach(_r ${ignoreRegexp})
  40       string(REGEX MATCHALL "${_r}" _match ${_l})
  41       if(_match)
  42         set(found 1)
  43         break()
  44       endif()
  45     endforeach()
  46     if(NOT found)
  47       # It is error, because the error-line does not match
  48       # any ignoring expression
  49       set(_erg 1)
  50     endif()
  51   endforeach()
  52 endif()
  53
  54 if(_erg)
  55   # We print here the whole error output, even the ignored part
  56   message(FATAL_ERROR "lyx gave warnings/errors:\n${lyxerr}")
  57 endif()